uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/audio/csound/csound-manual/default.nix

@@ -0,0 +1,44 @@
+{
+  lib, stdenv, fetchFromGitHub, docbook_xsl,
+  docbook_xml_dtd_45, python, pygments,
+  libxslt
+}:
+
+stdenv.mkDerivation {
+  pname = "csound-manual";
+  version = "unstable-2019-02-22";
+
+  src = fetchFromGitHub {
+    owner = "csound";
+    repo = "manual";
+    rev = "3b0bdc83f9245261b4b85a57c3ed636d5d924a4f";
+    sha256 = "074byjhaxraapyg54dxgg7hi1d4978aa9c1rmyi50p970nsxnacn";
+  };
+
+  prePatch = ''
+    substituteInPlace manual.xml \
+      --replace "http://www.oasis-open.org/docbook/xml/4.5/docbookx.dtd" \
+                "${docbook_xml_dtd_45}/xml/dtd/docbook/docbookx.dtd"
+  '';
+
+  nativeBuildInputs = [ libxslt.bin ];
+
+  buildInputs = [ docbook_xsl python pygments ];
+
+  buildPhase = ''
+    make XSL_BASE_PATH=${docbook_xsl}/share/xml/docbook-xsl html-dist
+  '';
+
+  installPhase = ''
+    mkdir -p $out/share/doc/csound
+    cp -r ./html $out/share/doc/csound
+  '';
+
+  meta = {
+    description = "The Csound Canonical Reference Manual";
+    homepage = "https://github.com/csound/manual";
+    license = lib.licenses.fdl12Plus;
+    maintainers = [ lib.maintainers.hlolli ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/applications/audio/csound/csound-qt/default.nix

@@ -0,0 +1,52 @@
+{ lib, stdenv, csound, desktop-file-utils,
+  fetchFromGitHub, python, python-qt, qmake,
+  qtwebengine, qtxmlpatterns, rtmidi, fetchpatch }:
+
+stdenv.mkDerivation rec {
+  pname = "csound-qt";
+  version = "0.9.6-beta3";
+
+  src = fetchFromGitHub {
+    owner = "CsoundQt";
+    repo = "CsoundQt";
+    rev = version;
+    sha256 = "007jhkh0k6qk52r77i067999dwdiimazix6ggp2hvyc4pj6n5dip";
+  };
+
+  patches = [
+    (fetchpatch {
+      name = "examplepath.patch";
+      url = "https://github.com/CsoundQt/CsoundQt/commit/09f2d515bff638cbcacb450979d66e273a59fdec.diff";
+      sha256 = "0y23kf8m1mh9mklsvf908b2b8m2w2rji8qvws44paf1kpwnwdmgm";
+    })
+    ./rtmidipath.patch
+  ];
+
+  nativeBuildInputs = [ qmake qtwebengine qtxmlpatterns ];
+
+  buildInputs = [ csound desktop-file-utils rtmidi ];
+
+  qmakeFlags = [ "qcs.pro" "CONFIG+=rtmidi" "CONFIG+=pythonqt"
+                 "CONFIG+=record_support" "CONFIG+=html_webengine"
+                 "CSOUND_INCLUDE_DIR=${csound}/include/csound"
+                 "CSOUND_LIBRARY_DIR=${csound}/lib"
+                 "RTMIDI_DIR=${rtmidi.src}"
+                 "PYTHONQT_SRC_DIR=${python-qt}/include/PythonQt"
+                 "PYTHONQT_LIB_DIR=${python-qt}/lib"
+                 "LIBS+=-L${python-qt}/lib"
+                 "INCLUDEPATH+=${python-qt}/include/PythonQt"
+                 "INCLUDEPATH+=${python}/include/python2.7"
+                 "INSTALL_DIR=${placeholder "out"}"
+                 "SHARE_DIR=${placeholder "out"}/share"
+                 ];
+
+  dontWrapQtApps = true;
+
+  meta = with lib; {
+    description = "CsoundQt is a frontend for Csound with editor, integrated help, widgets and other features";
+    homepage = "https://csoundqt.github.io/";
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ hlolli ];
+  };
+}

pkgs/applications/audio/csound/csound-qt/rtmidipath.patch

@@ -0,0 +1,17 @@
+diff --git a/src/src.pri b/src/src.pri
+index e5e0c896..9a9fa513 100644
+--- a/src/src.pri
++++ b/src/src.pri
+@@ -155,9 +155,9 @@ pythonqt {
+         "src/pyqcsobject.cpp"
+ }
+ rtmidi {
+-    HEADERS += "src/../$${RTMIDI_DIR}/RtMidi.h"
+-    SOURCES += "src/../$${RTMIDI_DIR}/RtMidi.cpp"
+-    INCLUDEPATH += src/../$${RTMIDI_DIR}
++    HEADERS += "$${RTMIDI_DIR}/RtMidi.h"
++    SOURCES += "$${RTMIDI_DIR}/RtMidi.cpp"
++    INCLUDEPATH += $${RTMIDI_DIR}
+ }
+ 
+ perfThread_build {

pkgs/applications/audio/csound/default.nix

@@ -0,0 +1,58 @@
+{ lib, stdenv, fetchFromGitHub, cmake, libsndfile, libsamplerate, flex, bison, boost, gettext
+, Accelerate
+, AudioUnit
+, CoreAudio
+, CoreMIDI
+, alsa-lib ? null
+, libpulseaudio ? null
+, libjack2 ? null
+, liblo ? null
+, ladspa-sdk ? null
+, fluidsynth ? null
+# , gmm ? null  # opcodes don't build with gmm 5.1
+, eigen ? null
+, curl ? null
+, tcltk ? null
+, fltk ? null
+}:
+
+stdenv.mkDerivation rec {
+  pname = "csound";
+  version = "6.17.0";
+
+  hardeningDisable = [ "format" ];
+
+  src = fetchFromGitHub {
+    owner = "csound";
+    repo = "csound";
+    rev = version;
+    sha256 = "sha256-O19jm3JxHg4TcQzWQZu1uFjfYN2FR41fCRq5YGnTGD0=";
+  };
+
+  cmakeFlags = [ "-DBUILD_CSOUND_AC=0" ] # fails to find Score.hpp
+    ++ lib.optional stdenv.isDarwin "-DCS_FRAMEWORK_DEST=${placeholder "out"}/lib"
+    ++ lib.optional (libjack2 != null) "-DJACK_HEADER=${libjack2}/include/jack/jack.h";
+
+  nativeBuildInputs = [ cmake flex bison gettext ];
+  buildInputs = [ libsndfile libsamplerate boost ]
+    ++ lib.optionals stdenv.isDarwin [
+      Accelerate AudioUnit CoreAudio CoreMIDI
+    ] ++ lib.optionals stdenv.isLinux (builtins.filter (optional: optional != null) [
+      alsa-lib libpulseaudio libjack2
+      liblo ladspa-sdk fluidsynth eigen
+      curl tcltk fltk
+    ]);
+
+  postInstall = lib.optional stdenv.isDarwin ''
+    mkdir -p $out/Library/Frameworks
+    ln -s $out/lib/CsoundLib64.framework $out/Library/Frameworks
+  '';
+
+  meta = with lib; {
+    description = "Sound design, audio synthesis, and signal processing system, providing facilities for music composition and performance on all major operating systems and platforms";
+    homepage = "https://csound.com/";
+    license = licenses.lgpl21Plus;
+    maintainers = [maintainers.marcweber];
+    platforms = platforms.unix;
+  };
+}