uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/audio/deadbeef/default.nix

@@ -0,0 +1,95 @@
+{ config, lib, stdenv, fetchFromGitHub
+, autoconf
+, automake
+, libtool
+, intltool
+, pkg-config
+, jansson
+# deadbeef can use either gtk2 or gtk3
+, gtk2Support ? false, gtk2
+, gtk3Support ? true, gtk3, gsettings-desktop-schemas, wrapGAppsHook
+# input plugins
+, vorbisSupport ? true, libvorbis
+, mp123Support ? true, libmad
+, flacSupport ? true, flac
+, wavSupport ? true, libsndfile
+, cdaSupport ? true, libcdio, libcddb
+, aacSupport ? true, faad2
+, opusSupport ? true, opusfile
+, wavpackSupport ? false, wavpack
+, ffmpegSupport ? false, ffmpeg
+, apeSupport ? true, yasm
+# misc plugins
+, zipSupport ? true, libzip
+, artworkSupport ? true, imlib2
+, hotkeysSupport ? true, libX11
+, osdSupport ? true, dbus
+# output plugins
+, alsaSupport ? true, alsa-lib
+, pulseSupport ? config.pulseaudio or stdenv.isLinux, libpulseaudio
+# effect plugins
+, resamplerSupport ? true, libsamplerate
+, overloadSupport ? true, zlib
+# transports
+, remoteSupport ? true, curl
+}:
+
+assert gtk2Support || gtk3Support;
+
+stdenv.mkDerivation rec {
+  pname = "deadbeef";
+  version = "1.8.4";
+
+  src = fetchFromGitHub {
+    owner = "DeaDBeeF-Player";
+    repo = "deadbeef";
+    rev = version;
+    sha256 = "161b0ll8v4cjgwwmk137hzvh0jidlkx56vjkpnr70f0x4jzv2nll";
+  };
+
+  buildInputs = with lib; [ jansson ]
+    ++ optional gtk2Support gtk2
+    ++ optionals gtk3Support [ gtk3 gsettings-desktop-schemas ]
+    ++ optional vorbisSupport libvorbis
+    ++ optional mp123Support libmad
+    ++ optional flacSupport flac
+    ++ optional wavSupport libsndfile
+    ++ optionals cdaSupport [ libcdio libcddb ]
+    ++ optional aacSupport faad2
+    ++ optional opusSupport opusfile
+    ++ optional zipSupport libzip
+    ++ optional ffmpegSupport ffmpeg
+    ++ optional apeSupport yasm
+    ++ optional artworkSupport imlib2
+    ++ optional hotkeysSupport libX11
+    ++ optional osdSupport dbus
+    ++ optional alsaSupport alsa-lib
+    ++ optional pulseSupport libpulseaudio
+    ++ optional resamplerSupport libsamplerate
+    ++ optional overloadSupport zlib
+    ++ optional wavpackSupport wavpack
+    ++ optional remoteSupport curl
+    ;
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    intltool
+    libtool
+    pkg-config
+  ] ++ lib.optional gtk3Support wrapGAppsHook;
+
+  enableParallelBuilding = true;
+
+  preConfigure = ''
+    ./autogen.sh
+  '';
+
+  meta = with lib; {
+    description = "Ultimate Music Player for GNU/Linux";
+    homepage = "http://deadbeef.sourceforge.net/";
+    license = licenses.gpl2;
+    platforms = [ "x86_64-linux" "i686-linux" ];
+    maintainers = [ maintainers.abbradar ];
+  };
+}

pkgs/applications/audio/deadbeef/plugins/headerbar-gtk3.nix

@@ -0,0 +1,30 @@
+{ lib, stdenv, fetchFromGitHub, autoconf, automake, libtool, pkg-config, libxml2, deadbeef, glib, gtk3 }:
+
+stdenv.mkDerivation rec {
+  pname = "deadbeef-headerbar-gtk3-plugin";
+  version = "1.2";
+
+  src = fetchFromGitHub {
+    owner = "saivert";
+    repo = "ddb_misc_headerbar_GTK3";
+    rev = "v${version}";
+    sha256 = "1v1schvnps7ypjqgcbqi74a45w8r2gbhrawz7filym22h1qr9wn0";
+  };
+
+  nativeBuildInputs = [ autoconf automake libtool pkg-config libxml2 ];
+  buildInputs = [ deadbeef glib gtk3 ];
+
+  # Choose correct installation path
+  # https://github.com/saivert/ddb_misc_headerbar_GTK3/commit/50ff75f76aa9d40761e352311670a894bfcd5cf6#r30319680
+  makeFlags = [ "pkglibdir=$(out)/lib/deadbeef" ];
+
+  preConfigure = "./autogen.sh";
+
+  meta = with lib; {
+    description = "Plug-in that adds GTK 3 header bar to the DeaDBeeF music player";
+    homepage = "https://github.com/saivert/ddb_misc_headerbar_GTK3";
+    license = licenses.gpl2Plus;
+    maintainers = [ maintainers.jtojnar ];
+    platforms = platforms.linux;
+  };
+}

pkgs/applications/audio/deadbeef/plugins/lyricbar.nix

@@ -0,0 +1,26 @@
+{ lib, stdenv, fetchFromGitHub, pkg-config, deadbeef, gtkmm3, libxmlxx3 }:
+
+stdenv.mkDerivation {
+  pname = "deadbeef-lyricbar-plugin";
+  version = "unstable-2019-01-29";
+
+  src = fetchFromGitHub {
+    owner = "C0rn3j";
+    repo = "deadbeef-lyricbar";
+    rev = "8f99b92ef827c451c43fc7dff38ae4f15c355e8e";
+    sha256 = "108hx5530f4xm8p9m2bk79nq7jkhcj39ad3vmxb2y6h6l2zv5kwl";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ deadbeef gtkmm3 libxmlxx3 ];
+
+  buildFlags = [ "gtk3" ];
+
+  meta = with lib; {
+    description = "Plugin for DeaDBeeF audio player that fetches and shows the song’s lyrics";
+    homepage = "https://github.com/C0rn3j/deadbeef-lyricbar";
+    license = licenses.mit;
+    maintainers = [ maintainers.jtojnar ];
+    platforms = platforms.linux;
+  };
+}

pkgs/applications/audio/deadbeef/plugins/mpris2.nix

@@ -0,0 +1,23 @@
+{ lib, stdenv, fetchurl, pkg-config, deadbeef, glib }:
+
+stdenv.mkDerivation rec {
+  pname = "deadbeef-mpris2-plugin";
+  version = "1.12";
+
+  src = fetchurl {
+    url = "https://github.com/Serranya/deadbeef-mpris2-plugin/releases/download/v${version}/${pname}-${version}.tar.xz";
+    sha256 = "0s3y4ka4qf38cypc0xspy79q0g5y1kqx6ldad7yr6a45nw6j95jh";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [ deadbeef glib ];
+
+  meta = with lib; {
+    description = "MPRISv2 plugin for the DeaDBeeF music player";
+    homepage = "https://github.com/Serranya/deadbeef-mpris2-plugin/";
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.abbradar ];
+  };
+}

pkgs/applications/audio/deadbeef/plugins/statusnotifier.nix

@@ -0,0 +1,39 @@
+{ lib, stdenv, fetchFromGitHub, pkg-config, deadbeef, gtk3, perl
+, libdbusmenu }:
+
+stdenv.mkDerivation rec {
+  pname = "deadbeef-statusnotifier-plugin";
+  version = "1.6";
+
+  src = fetchFromGitHub {
+    owner = "vovochka404";
+    repo = "deadbeef-statusnotifier-plugin";
+    rev = "v${version}";
+    sha256 = "sha256-6WEbY59vPNrL3W5GUwFQJimmSS+td8Ob+G46fPAxfV4=";
+  };
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ deadbeef gtk3 libdbusmenu ];
+
+  buildFlags = [ "gtk3" ];
+
+  postPatch = ''
+    substituteInPlace tools/glib-mkenums \
+      --replace /usr/bin/perl "${perl}/bin/perl"
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/lib/deadbeef
+    cp build/sni_gtk3.so $out/lib/deadbeef
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "DeaDBeeF StatusNotifier Plugin";
+    homepage = "https://github.com/vovochka404/deadbeef-statusnotifier-plugin";
+    license = licenses.gpl3Plus;
+    maintainers = [ maintainers.kurnevsky ];
+    platforms = platforms.linux;
+  };
+}

pkgs/applications/audio/deadbeef/wrapper.nix

@@ -0,0 +1,14 @@
+{ symlinkJoin, deadbeef, makeWrapper, plugins }:
+
+symlinkJoin {
+  name = "deadbeef-with-plugins-${deadbeef.version}";
+
+  paths = [ deadbeef ] ++ plugins;
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  postBuild = ''
+    wrapProgram $out/bin/deadbeef \
+      --set DEADBEEF_PLUGIN_DIR "$out/lib/deadbeef"
+  '';
+}