uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/audio/helio-workstation/default.nix

@@ -0,0 +1,49 @@
+{ lib, stdenv, fetchFromGitHub
+, alsa-lib, freetype, xorg, curl, libGL, libjack2, gnome
+, pkg-config, makeWrapper
+}:
+
+stdenv.mkDerivation rec {
+  pname = "helio-workstation";
+  version = "3.9";
+
+  src = fetchFromGitHub {
+    owner = "helio-fm";
+    repo = pname;
+    rev = version;
+    fetchSubmodules = true;
+    sha256 = "sha256-AtgKgw+F5lc0Ma3zOxmk3iaZQp2KZb2FP5F8QvvYTT4=";
+  };
+
+  buildInputs = [
+    alsa-lib freetype xorg.libX11 xorg.libXext xorg.libXinerama xorg.libXrandr
+    xorg.libXcursor xorg.libXcomposite curl libGL libjack2 gnome.zenity
+  ];
+
+  nativeBuildInputs = [ pkg-config makeWrapper ];
+
+  preBuild = ''
+    cd Projects/LinuxMakefile
+    substituteInPlace Makefile --replace alsa "alsa jack"
+  '';
+  buildFlags = [ "CONFIG=Release64" ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    install -Dm755 build/helio $out/bin
+    wrapProgram $out/bin/helio --prefix PATH ":" ${gnome.zenity}/bin
+
+    mkdir -p $out/share
+    cp -r ../Deployment/Linux/Debian/x64/usr/share/* $out/share
+    substituteInPlace $out/share/applications/Helio.desktop \
+      --replace "/usr/bin/helio" "$out/bin/helio"
+  '';
+
+  meta = with lib; {
+    description = "One music sequencer for all major platforms, both desktop and mobile";
+    homepage = "https://helio.fm/";
+    license = licenses.gpl3Only;
+    maintainers = [ maintainers.suhr ];
+    platforms = [ "x86_64-linux" ];
+  };
+}