uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/audio/mopidy/default.nix

@@ -0,0 +1,43 @@
+{ lib, newScope, python }:
+
+# Create a custom scope so we are consistent in which python version is used
+lib.makeScope newScope (self: with self; {
+  inherit python;
+  pythonPackages = python.pkgs;
+
+  mopidy = callPackage ./mopidy.nix { };
+
+  mopidy-iris = callPackage ./iris.nix { };
+
+  mopidy-jellyfin = callPackage ./jellyfin.nix { };
+
+  mopidy-local = callPackage ./local.nix { };
+
+  mopidy-moped = callPackage ./moped.nix { };
+
+  mopidy-mopify = callPackage ./mopify.nix { };
+
+  mopidy-mpd = callPackage ./mpd.nix { };
+
+  mopidy-mpris = callPackage ./mpris.nix { };
+
+  mopidy-muse = callPackage ./muse.nix { };
+
+  mopidy-musicbox-webclient = callPackage ./musicbox-webclient.nix { };
+
+  mopidy-podcast = callPackage ./podcast.nix { };
+
+  mopidy-scrobbler = callPackage ./scrobbler.nix { };
+
+  mopidy-somafm = callPackage ./somafm.nix { };
+
+  mopidy-soundcloud = callPackage ./soundcloud.nix { };
+
+  mopidy-tunein = callPackage ./tunein.nix { };
+
+  mopidy-youtube = callPackage ./youtube.nix { };
+
+  mopidy-ytmusic = callPackage ./ytmusic.nix { };
+
+  mopidy-subidy = callPackage ./subidy.nix { };
+})

pkgs/applications/audio/mopidy/iris.nix

@@ -0,0 +1,29 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "Mopidy-Iris";
+  version = "3.60.0";
+
+  src = python3Packages.fetchPypi {
+    inherit pname version;
+    sha256 = "18w6qqmxzn8psiacybryxailm826f3j1wgiv0c03fbdsy6kr5f7l";
+  };
+
+  propagatedBuildInputs = [
+    mopidy
+  ] ++ (with python3Packages; [
+    configobj
+    requests
+    tornado
+  ]);
+
+  # no tests implemented
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://github.com/jaedb/Iris";
+    description = "A fully-functional Mopidy web client encompassing Spotify and many other backends";
+    license = licenses.asl20;
+    maintainers = [ maintainers.rvolosatovs ];
+  };
+}

pkgs/applications/audio/mopidy/jellyfin.nix

@@ -0,0 +1,25 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mopidy-jellyfin";
+  version = "1.0.2";
+
+  src = python3Packages.fetchPypi {
+    inherit version;
+    pname = "Mopidy-Jellyfin";
+    sha256 = "0j7v5xx3c401r5dw1sqm1n2263chjga1d3ml85rg79hjhhhacy75";
+  };
+
+  propagatedBuildInputs = [ mopidy python3Packages.unidecode python3Packages.websocket-client ];
+
+  # no tests implemented
+  doCheck = false;
+  pythonImportsCheck = [ "mopidy_jellyfin" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/jellyfin/mopidy-jellyfin";
+    description = "Mopidy extension for playing audio files from Jellyfin";
+    license = licenses.asl20;
+    maintainers = [ maintainers.pstn ];
+  };
+}

pkgs/applications/audio/mopidy/local.nix

@@ -0,0 +1,32 @@
+{ stdenv
+, lib
+, mopidy
+, python3Packages
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "Mopidy-Local";
+  version = "3.2.1";
+
+  src = python3Packages.fetchPypi {
+    inherit pname version;
+    sha256 = "18w39mxpv8p17whd6zfw5653d21q138f8xd6ili6ks2g2dbm25i9";
+  };
+
+  propagatedBuildInputs = [
+    mopidy
+    python3Packages.uritools
+  ];
+
+  checkInputs = [
+    python3Packages.pytestCheckHook
+  ];
+
+  meta = with lib; {
+    broken = stdenv.isDarwin;
+    homepage = "https://github.com/mopidy/mopidy-local";
+    description = "Mopidy extension for playing music from your local music archive";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ ruuda ];
+  };
+}

pkgs/applications/audio/mopidy/moped.nix

@@ -0,0 +1,26 @@
+{ lib, pythonPackages, mopidy, glibcLocales }:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "Mopidy-Moped";
+  version = "0.7.1";
+
+  src = pythonPackages.fetchPypi {
+    inherit pname version;
+    sha256 = "15461174037d87af93dd59a236d4275c5abf71cea0670ffff24a7d0399a8a2e4";
+  };
+
+  LC_ALL = "en_US.UTF-8";
+  buildInputs = [ glibcLocales ];
+  propagatedBuildInputs = [ mopidy ];
+
+  # no tests implemented
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://github.com/martijnboland/moped";
+    description = "A web client for Mopidy";
+    license = licenses.mit;
+    maintainers = [];
+    hydraPlatforms = [];
+  };
+}

pkgs/applications/audio/mopidy/mopidy.nix

@@ -0,0 +1,51 @@
+{ lib, stdenv, fetchFromGitHub, pythonPackages, wrapGAppsHook
+, gst_all_1, glib-networking, gobject-introspection
+}:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "mopidy";
+  version = "3.3.0";
+
+  src = fetchFromGitHub {
+    owner = "mopidy";
+    repo = "mopidy";
+    rev = "refs/tags/v${version}";
+    sha256 = "sha256-F0fIl9DrludZZdzsrl/xsp7TLMgTPbVGtGvMHyD52Yw=";
+  };
+
+  nativeBuildInputs = [ wrapGAppsHook ];
+
+  buildInputs = with gst_all_1; [
+    glib-networking
+    gst-plugins-bad
+    gst-plugins-base
+    gst-plugins-good
+    gst-plugins-ugly
+  ];
+
+  propagatedBuildInputs = [
+    gobject-introspection
+  ] ++ (with pythonPackages; [
+      gst-python
+      pygobject3
+      pykka
+      requests
+      setuptools
+      tornado
+    ] ++ lib.optional (!stdenv.isDarwin) dbus-python
+  );
+
+  # There are no tests
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://www.mopidy.com/";
+    description = ''
+      An extensible music server that plays music from local disk, Spotify,
+      SoundCloud, and more
+    '';
+    license = licenses.asl20;
+    maintainers = [ maintainers.fpletz ];
+    hydraPlatforms = [];
+  };
+}

pkgs/applications/audio/mopidy/mopify.nix

@@ -0,0 +1,23 @@
+{ lib, pythonPackages, mopidy }:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "Mopidy-Mopify";
+  version = "1.6.1";
+
+  src = pythonPackages.fetchPypi {
+    inherit pname version;
+    sha256 = "93ad2b3d38b1450c8f2698bb908b0b077a96b3f64cdd6486519e518132e23a5c";
+  };
+
+  propagatedBuildInputs = with pythonPackages; [ mopidy configobj ];
+
+  # no tests implemented
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://github.com/dirkgroenen/mopidy-mopify";
+    description = "A mopidy webclient based on the Spotify webbased interface";
+    license = licenses.gpl3;
+    maintainers = [ maintainers.Gonzih ];
+  };
+}

pkgs/applications/audio/mopidy/mpd.nix

@@ -0,0 +1,24 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "Mopidy-MPD";
+  version = "3.2.0";
+
+  src = python3Packages.fetchPypi {
+    inherit pname version;
+    sha256 = "sha256-oZvKr61lyu7CmXP2A/xtYng1FIUPyveVJMqUuv6UnaM=";
+  };
+
+  propagatedBuildInputs = [mopidy];
+
+  # no tests implemented
+  doCheck = false;
+  pythonImportsCheck = [ "mopidy_mpd" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/mopidy/mopidy-mpd";
+    description = "Mopidy extension for controlling playback from MPD clients";
+    license = licenses.asl20;
+    maintainers = [ maintainers.tomahna ];
+  };
+}

pkgs/applications/audio/mopidy/mpris.nix

@@ -0,0 +1,27 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mopidy-mpris";
+  version = "3.0.3";
+
+  src = python3Packages.fetchPypi {
+    inherit version;
+    pname = "Mopidy-MPRIS";
+    sha256 = "sha256-rHQgNIyludTEL7RDC8dIpyGTMOt1Tazn6i/orKlSP4U=";
+  };
+
+  propagatedBuildInputs = [
+    mopidy
+    python3Packages.pydbus
+  ];
+
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://www.mopidy.com/";
+    description = "Mopidy extension for controlling Mopidy through D-Bus using the MPRIS specification";
+    license = licenses.asl20;
+    maintainers = [ maintainers.nickhu ];
+  };
+}
+

pkgs/applications/audio/mopidy/muse.nix

@@ -0,0 +1,29 @@
+{ lib, pythonPackages, mopidy }:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "mopidy-muse";
+  version = "0.0.27";
+
+  src = pythonPackages.fetchPypi {
+    inherit version;
+    pname = "Mopidy-Muse";
+    sha256 = "0jx9dkgxr07avzz9zskzhqy98zsxkdrf7iid2ax5vygwf8qsx8ks";
+  };
+
+  propagatedBuildInputs = [
+    mopidy
+    pythonPackages.pykka
+  ];
+
+  pythonImportsCheck = [ "mopidy_muse" ];
+
+  # has no tests
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Mopidy web client with Snapcast support";
+    homepage = "https://github.com/cristianpb/muse";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ hexa ];
+  };
+}

pkgs/applications/audio/mopidy/musicbox-webclient.nix

@@ -0,0 +1,24 @@
+{ lib, stdenv, fetchFromGitHub, pythonPackages, mopidy }:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "mopidy-musicbox-webclient";
+  version = "3.1.0";
+
+  src = fetchFromGitHub {
+    owner = "pimusicbox";
+    repo = "mopidy-musicbox-webclient";
+    rev = "v${version}";
+    sha256 = "1lzarazq67gciyn6r8cdms0f7j0ayyfwhpf28z93ydb280mfrrb9";
+  };
+
+  propagatedBuildInputs = [ mopidy ];
+
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Mopidy extension for playing music from SoundCloud";
+    license = licenses.mit;
+    broken = stdenv.isDarwin;
+    maintainers = [ maintainers.spwhitt ];
+  };
+}

pkgs/applications/audio/mopidy/podcast.nix

@@ -0,0 +1,31 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mopidy-podcast";
+  version = "3.0.0";
+
+  src = python3Packages.fetchPypi {
+    inherit version;
+    pname = "Mopidy-Podcast";
+    sha256 = "1z2b523yvdpcf8p7m7kczrvaw045lmxzhq4qj00dflxa2yw61qxr";
+  };
+
+  propagatedBuildInputs = [
+    mopidy
+    python3Packages.cachetools
+    python3Packages.uritools
+  ];
+
+  checkInputs = with python3Packages; [
+    pytestCheckHook
+  ];
+
+  meta = with lib; {
+    homepage = "https://github.com/tkem/mopidy-podcast";
+    description = "Mopidy extension for browsing and playing podcasts";
+    license = licenses.asl20;
+    maintainers = [
+      maintainers.daneads
+    ];
+  };
+}

pkgs/applications/audio/mopidy/scrobbler.nix

@@ -0,0 +1,24 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "Mopidy-Scrobbler";
+  version = "2.0.1";
+
+  src = python3Packages.fetchPypi {
+    inherit pname version;
+    sha256 = "11vxgax4xgkggnq4fr1rh2rcvzspkkimck5p3h4phdj3qpnj0680";
+  };
+
+  propagatedBuildInputs = with python3Packages; [ mopidy pylast ];
+
+  # no tests implemented
+  doCheck = false;
+  pythonImportsCheck = [ "mopidy_scrobbler" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/mopidy/mopidy-scrobbler";
+    description = "Mopidy extension for scrobbling played tracks to Last.fm.";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ jakeisnt ];
+  };
+}

pkgs/applications/audio/mopidy/somafm.nix

@@ -0,0 +1,26 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mopidy-somafm";
+  version = "2.0.0";
+
+  src = python3Packages.fetchPypi {
+    inherit version;
+    pname = "Mopidy-SomaFM";
+    sha256 = "1j88rrliys8hqvnb35k1xqw88bvrllcb4rb53lgh82byhscsxlf3";
+  };
+
+  propagatedBuildInputs = [
+    mopidy
+  ];
+
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://www.mopidy.com/";
+    description = "Mopidy extension for playing music from SomaFM";
+    license = licenses.mit;
+    maintainers = [ maintainers.nickhu ];
+  };
+}
+

pkgs/applications/audio/mopidy/soundcloud.nix

@@ -0,0 +1,23 @@
+{ lib, fetchFromGitHub, pythonPackages, mopidy }:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "mopidy-soundcloud";
+  version = "3.0.1";
+
+  src = fetchFromGitHub {
+    owner = "mopidy";
+    repo = "mopidy-soundcloud";
+    rev = "v${version}";
+    sha256 = "18wiiv4rca9vibvnc27f3q4apf8n61kbp7mdbm2pmz86qwmd47pa";
+  };
+
+  propagatedBuildInputs = [ mopidy ];
+
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Mopidy extension for playing music from SoundCloud";
+    license = licenses.mit;
+    maintainers = [ maintainers.spwhitt ];
+  };
+}

pkgs/applications/audio/mopidy/subidy.nix

@@ -0,0 +1,24 @@
+{ lib, fetchFromGitHub, pythonPackages, mopidy }:
+
+pythonPackages.buildPythonApplication rec {
+  pname = "mopidy-subidy";
+  version = "1.0.0";
+
+  src = fetchFromGitHub {
+    owner = "Prior99";
+    repo = pname;
+    rev = version;
+    sha256 = "0c5ghhhrj5v3yp4zmll9ari6r5c6ha8c1izwqshvadn40b02q7xz";
+  };
+
+  propagatedBuildInputs = [ mopidy pythonPackages.py-sonic ];
+
+  checkInputs = with pythonPackages; [ pytestCheckHook ];
+
+  meta = with lib; {
+    homepage = "https://www.mopidy.com/";
+    description = "Mopidy extension for playing music from a Subsonic-compatible Music Server";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ wenngle ];
+  };
+}

pkgs/applications/audio/mopidy/tunein.nix

@@ -0,0 +1,25 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mopidy-tunein";
+  version = "1.1.0";
+
+  src = python3Packages.fetchPypi {
+    inherit version;
+    pname = "Mopidy-TuneIn";
+    sha256 = "01y1asylscr73yqx071imhrzfzlg07wmqqzkdvpgm6r35marc2li";
+  };
+
+  propagatedBuildInputs = [
+    mopidy
+  ];
+
+  pythonImportsCheck = [ "mopidy_tunein.tunein" ];
+
+  meta = with lib; {
+    description = "Mopidy extension for playing music from tunein";
+    homepage = "https://github.com/kingosticks/mopidy-tunein";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ hexa ];
+  };
+}

pkgs/applications/audio/mopidy/youtube.nix

@@ -0,0 +1,57 @@
+{ lib
+, fetchFromGitHub
+, python3
+, mopidy
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "mopidy-youtube";
+  version = "3.5";
+  format = "setuptools";
+
+  src = fetchFromGitHub {
+    owner = "natumbri";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-hlokysFFgZZYY7flghgRq6wVG824kpcLkXxk6nMhxn4=";
+  };
+
+  propagatedBuildInputs = with python3.pkgs; [
+    beautifulsoup4
+    cachetools
+    pykka
+    requests
+    youtube-dl
+    ytmusicapi
+  ] ++ [
+    mopidy
+  ];
+
+  checkInputs = with python3.pkgs; [
+    vcrpy
+    pytestCheckHook
+  ];
+
+  disabledTests = [
+    # Test requires a YouTube API key
+    "test_get_default_config"
+  ];
+
+  disabledTestPaths = [
+    # Disable tests which interact with Youtube
+    "tests/test_api.py"
+    "tests/test_backend.py"
+    "tests/test_youtube.py"
+  ];
+
+  pythonImportsCheck = [
+    "mopidy_youtube"
+  ];
+
+  meta = with lib; {
+    description = "Mopidy extension for playing music from YouTube";
+    homepage = "https://github.com/natumbri/mopidy-youtube";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ spwhitt ];
+  };
+}

pkgs/applications/audio/mopidy/ytmusic.nix

@@ -0,0 +1,35 @@
+{ lib, python3Packages, mopidy }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "mopidy-ytmusic";
+  version = "0.3.5";
+
+  src = python3Packages.fetchPypi {
+    inherit version;
+    pname = "Mopidy-YTMusic";
+    sha256 = "0pncyxfqxvznb9y4ksndbny1yf5mxh4089ak0yz86dp2qi5j99iv";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace 'ytmusicapi>=0.20.0,<0.21.0' 'ytmusicapi>=0.20.0'
+  '';
+
+  propagatedBuildInputs = [
+    mopidy
+    python3Packages.ytmusicapi
+    python3Packages.pytube
+  ];
+
+  pythonImportsCheck = [ "mopidy_ytmusic" ];
+
+  # has no tests
+  doCheck = false;
+
+  meta = with lib; {
+    description = "Mopidy extension for playing music from YouTube Music";
+    homepage = "https://github.com/OzymandiasTheGreat/mopidy-ytmusic";
+    license = licenses.asl20;
+    maintainers = [ maintainers.nickhu ];
+  };
+}