uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/audio/pd-plugins/cyclone/default.nix

@@ -0,0 +1,33 @@
+{ lib, stdenv, fetchFromGitHub, puredata }:
+
+stdenv.mkDerivation rec {
+  pname = "cyclone";
+  version = "0.3beta-2";
+
+  src = fetchFromGitHub {
+    owner = "porres";
+    repo = "pd-cyclone";
+    rev = "cyclone${version}";
+    sha256 = "192jrq3bdsv626js1ymq10gwp9wwcszjs63ys6ap9ig8xdkbhr3q";
+  };
+
+  buildInputs = [ puredata ];
+
+  makeFlags = [
+    "pdincludepath=${puredata}/include/pd"
+    "prefix=$(out)"
+  ];
+
+  postInstall = ''
+    mv "$out/lib/pd-externals/cyclone" "$out/"
+    rm -rf $out/lib
+  '';
+
+  meta = {
+    description = "A library of PureData classes, bringing some level of compatibility between Max/MSP and Pd environments";
+    homepage = "http://puredata.info/downloads/cyclone";
+    license = lib.licenses.tcltk;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/applications/audio/pd-plugins/gem/default.nix

@@ -0,0 +1,50 @@
+{ lib, stdenv
+, fetchFromGitHub
+, fetchpatch
+, autoreconfHook
+, pkg-config
+, puredata
+, libGL
+, libGLU
+, glew
+, freeglut
+, libv4l
+, libX11
+, file
+ }:
+
+stdenv.mkDerivation rec {
+  pname = "gem-unstable";
+  version = "2020-09-22";
+
+  src = fetchFromGitHub {
+    owner = "umlaeute";
+    repo = "Gem";
+    rev = "2edfde4f0587e72ef325e7f53681936dcc19655b";
+    sha256 = "0k5sq128wxi2qhaidspkw310pdgysxs47agv09pkjgvch2n4d5dq";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    file
+    pkg-config
+  ];
+
+  buildInputs = [
+    puredata
+    libGL
+    libGLU
+    glew
+    freeglut
+    libv4l
+    libX11
+  ];
+
+  meta = {
+    description = "Graphics Environment for Multimedia";
+    homepage = "http://puredata.info/downloads/gem";
+    license = lib.licenses.gpl2Plus;
+    maintainers = [ lib.maintainers.raboof ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/applications/audio/pd-plugins/helmholtz/default.nix

@@ -0,0 +1,48 @@
+{ lib, stdenv, fetchurl, unzip, puredata }:
+
+stdenv.mkDerivation {
+  name = "helmholtz";
+
+  src = fetchurl {
+    url = "https://www.katjaas.nl/helmholtz/helmholtz~.zip";
+    name = "helmholtz.zip";
+    curlOpts = "--user-agent ''";
+    sha256 = "0h1fj7lmvq9j6rmw33rb8k0byxb898bi2xhcwkqalb84avhywgvs";
+  };
+
+  nativeBuildInputs = [ unzip ];
+  buildInputs = [ puredata ];
+
+  unpackPhase = ''
+    unzip $src
+    mv helmholtz~/src/helmholtz\~.cpp .
+    mv helmholtz~/src/Helmholtz.cpp .
+    mv helmholtz~/src/include/ .
+    mv helmholtz~/src/Makefile .
+    rm -rf helmholtz~/src/
+    rm helmholtz~/helmholtz~.pd_darwin
+    rm helmholtz~/helmholtz~.pd_linux
+    rm helmholtz~/helmholtz~.dll
+    rm -rf __MACOSX
+  '';
+
+  patchPhase = ''
+    mkdir -p $out/helmholtz~
+    sed -i "s@current: pd_darwin@current: pd_linux@g" Makefile
+    sed -i "s@-Wl@@g" Makefile
+    sed -i "s@\$(NAME).pd_linux \.\./\$(NAME).pd_linux@helmholtz~.pd_linux $out/helmholtz~/@g" Makefile
+  '';
+
+  installPhase = ''
+    cp -r helmholtz~/ $out/
+  '';
+
+  meta = {
+    broken = (stdenv.isLinux && stdenv.isAarch64);
+    description = "Time domain pitch tracker for Pure Data";
+    homepage = "http://www.katjaas.nl/helmholtz/helmholtz.html";
+    license = lib.licenses.bsd3;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/applications/audio/pd-plugins/maxlib/default.nix

@@ -0,0 +1,33 @@
+{ lib, stdenv, fetchFromGitHub, puredata }:
+
+stdenv.mkDerivation rec {
+  pname = "maxlib";
+  version = "1.5.7";
+
+  src = fetchFromGitHub {
+    owner = "electrickery";
+    repo = "pd-maxlib";
+    rev = "v${version}";
+    sha256 = "10w9qfgn26lj3zqjksf2r1wsjpf5xy4dx22jay9l6idy9q62mxsn";
+  };
+
+  buildInputs = [ puredata ];
+
+  hardeningDisable = [ "format" ];
+
+  makeFlags = [ "prefix=$(out)" ];
+
+  postInstall = ''
+    mv $out/lib/pd-externals/maxlib/ $out
+    rm -rf $out/local/
+    rm -rf $out/lib/
+  '';
+
+  meta = {
+    description = "A library of non-tilde externals for puredata, by Miller Puckette";
+    homepage = "http://puredata.info/downloads/maxlib";
+    license = lib.licenses.gpl2;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/applications/audio/pd-plugins/mrpeach/default.nix

@@ -0,0 +1,62 @@
+{ lib, stdenv, fetchurl, puredata }:
+
+stdenv.mkDerivation {
+  pname = "mrpeach";
+  version = "1.1";
+
+  # this was to only usable url I could find:
+  # - The main url changes hash: http://pure-data.cvs.sourceforge.net/viewvc/pure-data/externals/mrpeach/?view=tar
+  # - There are lot's of places where this SW is available as part of a big pkg: pd-extended, pd-l2ork
+  # - It's just 211K
+
+  src = fetchurl {
+    url = "http://slackonly.com/pub/korgie/sources/pd_mrpeach-2011.10.21.tar.gz";
+    sha256 = "12jqba3jsdrk20ib9wc2wiivki88ypcd4mkzgsri9siywbbz9w8x";
+  };
+
+  buildInputs = [ puredata ];
+
+  hardeningDisable = [ "format" ];
+
+  patchPhase = ''
+    for D in net osc
+    do
+      sed -i "s@prefix = /usr/local@prefix = $out@g" $D/Makefile
+      for i in ${puredata}/include/pd/*; do
+        ln -s $i $D/
+      done
+    done
+  '';
+
+  buildPhase = ''
+    for D in net osc
+    do
+      cd $D
+      make
+      cd ..
+    done
+  '';
+
+  installPhase = ''
+    for D in net osc
+    do
+      cd $D
+      make install
+      cd ..
+    done
+  '';
+
+  fixupPhase = ''
+    mv $out/lib/pd-externals/net $out
+    mv $out/lib/pd-externals/osc $out
+    rm -rf $out/lib
+  '';
+
+  meta = {
+    description = "A collection of Pd objectclasses for OSC-messages";
+    homepage = "http://puredata.info/downloads/osc";
+    license = lib.licenses.gpl2;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/applications/audio/pd-plugins/puremapping/default.nix

@@ -0,0 +1,32 @@
+{ lib, stdenv, fetchurl, unzip, puredata }:
+
+stdenv.mkDerivation rec {
+  pname = "puremapping";
+  version = "20160130";
+
+  src = fetchurl {
+    url = "https://www.chnry.net/data/puremapping-${version}-generic.zip";
+    name = "puremapping";
+    sha256 = "1h7qgqd8srrxw2y1rkdw5js4k6f5vc8x6nlm2mq9mq9vjck7n1j7";
+  };
+
+  nativeBuildInputs = [ unzip ];
+  buildInputs = [ puredata ];
+
+  unpackPhase = ''
+    unzip $src
+  '';
+
+  installPhase = ''
+    mkdir -p $out/puremapping
+    mv puremapping/ $out
+  '';
+
+  meta = {
+    description = "Set of externals to facilitate the use of sensors within Pure Data and to create complex relations between input and output of a dynamic system";
+    homepage = "http://www.chnry.net/ch/?090-Pure-Mapping&lang=en";
+    license = lib.licenses.gpl1;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/applications/audio/pd-plugins/timbreid/default.nix

@@ -0,0 +1,46 @@
+{ lib, stdenv, fetchurl, unzip, puredata, fftw }:
+
+stdenv.mkDerivation rec {
+  version = "0.7.0";
+  pname = "timbreid";
+
+  src = fetchurl {
+    url = "http://williambrent.conflations.com/pd/timbreID-${version}-src.zip";
+    sha256 = "14k2xk5zrzrw1zprdbwx45hrlc7ck8vq4drpd3l455i5r8yk4y6b";
+  };
+
+  nativeBuildInputs = [ unzip ];
+  buildInputs = [ puredata fftw ];
+
+  unpackPhase = ''
+    mkdir source
+    cd source
+    unzip $src
+  '';
+
+  buildPhase = ''
+    make tIDLib.o all
+ '';
+
+  installPhase = ''
+    mkdir -p $out/
+    cp -r *.pd $out/
+    cp -r *.pd_linux $out/
+    cp -r audio/ $out/
+    cp -r data/ $out/
+    cp -r doc/ $out/
+  '';
+
+  postFixup = ''
+    mv $out/share/doc/ $out/
+    rm -rf $out/share/
+    '';
+
+  meta = {
+    description = "A collection of audio feature analysis externals for puredata";
+    homepage = "http://williambrent.conflations.com/pages/research.html";
+    license = lib.licenses.gpl3;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}

pkgs/applications/audio/pd-plugins/zexy/default.nix

@@ -0,0 +1,37 @@
+{ lib, stdenv, fetchurl, autoconf, automake, puredata }:
+
+stdenv.mkDerivation rec {
+  pname = "zexy";
+  version = "2.2.4";
+
+  src = fetchurl {
+    url = "https://puredata.info/downloads/zexy/releases/${version}/${pname}-${version}.tar.gz";
+    sha256 = "1xpgl82c2lc6zfswjsa7z10yhv5jb7a4znzh3nc7ffrzm1z8vylp";
+  };
+
+  nativeBuildInputs = [ autoconf automake  ];
+  buildInputs = [ puredata ];
+
+  preBuild = ''
+    export LD=$CXX
+    cd src/
+    for i in ${puredata}/include/pd/*; do
+      ln -s $i .
+    done
+    ./bootstrap.sh
+    ./configure --enable-lpt=no --prefix=$out
+  '';
+
+  postInstall = ''
+    mv $out/lib/pd/extra/zexy $out
+    rm -rf $out/lib
+  '';
+
+  meta = {
+    description = "The swiss army knife for puredata";
+    homepage = "http://puredata.info/downloads/zexy";
+    license = lib.licenses.gpl2;
+    maintainers = [ lib.maintainers.magnetophon ];
+    platforms = lib.platforms.linux;
+  };
+}