uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/blockchains/alfis/default.nix

@@ -0,0 +1,56 @@
+{ stdenv
+, lib
+, rustPlatform
+, fetchFromGitHub
+, pkg-config
+, makeWrapper
+, webkitgtk
+, zenity
+, Cocoa
+, Security
+, WebKit
+, withGui ? true
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "alfis";
+  version = "0.7.3";
+
+  src = fetchFromGitHub {
+    owner = "Revertron";
+    repo = "Alfis";
+    rev = "v${version}";
+    sha256 = "sha256-P+usJCzf92WZ46mdaDbej59/RUzmFcMvlYXVe2VpgY0=";
+  };
+
+  cargoSha256 = "sha256-N5qHu0sCmIWtDYerWqMlD3qr8QtXLvEC7VqPEvnW2cw=";
+
+  checkFlags = [
+    # these want internet access, disable them
+    "--skip=dns::client::tests::test_tcp_client"
+    "--skip=dns::client::tests::test_udp_client"
+  ];
+
+  nativeBuildInputs = [ pkg-config makeWrapper ];
+  buildInputs = lib.optional stdenv.isDarwin Security
+    ++ lib.optional (withGui && stdenv.isLinux) webkitgtk
+    ++ lib.optionals (withGui && stdenv.isDarwin) [ Cocoa WebKit ];
+
+  buildNoDefaultFeatures = true;
+  buildFeatures = [
+    "doh"
+  ] ++ lib.optional withGui "webgui";
+
+  postInstall = lib.optionalString (withGui && stdenv.isLinux) ''
+    wrapProgram $out/bin/alfis \
+      --prefix PATH : ${lib.makeBinPath [ zenity ]}
+  '';
+
+  meta = with lib; {
+    description = "Alternative Free Identity System";
+    homepage = "https://alfis.name";
+    license = licenses.agpl3Only;
+    maintainers = with maintainers; [ misuzu ];
+    platforms = platforms.unix;
+  };
+}