uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/editors/nano/default.nix

@@ -0,0 +1,81 @@
+{ lib, stdenv, fetchurl, fetchFromGitHub, ncurses, texinfo, writeScript
+, common-updater-scripts, git, nix, nixfmt, coreutils, gnused, callPackage
+, gettext ? null, enableNls ? true, enableTiny ? false }:
+
+assert enableNls -> (gettext != null);
+
+with lib;
+
+let
+  nixSyntaxHighlight = fetchFromGitHub {
+    owner = "seitz";
+    repo = "nanonix";
+    rev = "bf8d898efaa10dce3f7972ff765b58c353b4b4ab";
+    sha256 = "0773s5iz8aw9npgyasb0r2ybp6gvy2s9sq51az8w7h52bzn5blnn";
+  };
+
+in stdenv.mkDerivation rec {
+  pname = "nano";
+  version = "6.3";
+
+  src = fetchurl {
+    url = "mirror://gnu/nano/${pname}-${version}.tar.xz";
+    sha256 = "61MtpJhWcnMLUA9oXbqriFpGbQj7v3QVgyuVgF5vhoc=";
+  };
+
+  nativeBuildInputs = [ texinfo ] ++ optional enableNls gettext;
+  buildInputs = [ ncurses ];
+
+  outputs = [ "out" "info" ];
+
+  configureFlags = [
+    "--sysconfdir=/etc"
+    (lib.enableFeature enableNls "nls")
+    (lib.enableFeature enableTiny "tiny")
+  ];
+
+  postInstall = ''
+    cp ${nixSyntaxHighlight}/nix.nanorc $out/share/nano/
+  '';
+
+  enableParallelBuilding = true;
+
+  passthru = {
+    tests = { expect = callPackage ./test-with-expect.nix { }; };
+
+    updateScript = writeScript "update.sh" ''
+      #!${stdenv.shell}
+      set -o errexit
+      PATH=${
+        lib.makeBinPath [
+          common-updater-scripts
+          git
+          nixfmt
+          nix
+          coreutils
+          gnused
+        ]
+      }
+
+      oldVersion="$(nix-instantiate --eval -E "with import ./. {}; lib.getVersion ${pname}" | tr -d '"')"
+      latestTag="$(git -c 'versionsort.suffix=-' ls-remote --exit-code --refs --sort='version:refname' --tags git://git.savannah.gnu.org/nano.git '*' | tail --lines=1 | cut --delimiter='/' --fields=3 | sed 's|^v||g')"
+
+      if [ ! "$oldVersion" = "$latestTag" ]; then
+        update-source-version ${pname} "$latestTag" --version-key=version --print-changes
+        nixpkgs="$(git rev-parse --show-toplevel)"
+        default_nix="$nixpkgs/pkgs/applications/editors/nano/default.nix"
+        nixfmt "$default_nix"
+      else
+        echo "${pname} is already up-to-date"
+      fi
+    '';
+  };
+
+  meta = {
+    homepage = "https://www.nano-editor.org/";
+    description = "A small, user-friendly console text editor";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ joachifm nequissimus ];
+    platforms = platforms.all;
+  };
+}

pkgs/applications/editors/nano/nanorc/default.nix

@@ -0,0 +1,56 @@
+{ lib, stdenv, fetchFromGitHub, writeScript, nixosTests, common-updater-scripts
+, coreutils, git, gnused, nix, nixfmt }:
+
+let
+  owner = "scopatz";
+  repo = "nanorc";
+in stdenv.mkDerivation rec {
+  pname = "nanorc";
+  version = "2020-10-10";
+
+  src = fetchFromGitHub {
+    inherit owner repo;
+    rev = builtins.replaceStrings [ "-" ] [ "." ] version;
+    sha256 = "3B2nNFYkwYHCX6pQz/hMO/rnVqlCiw1BSNmGmJ6KCqE=";
+  };
+
+  dontBuild = true;
+
+  installPhase = ''
+    mkdir -p $out/share
+
+    install *.nanorc $out/share/
+  '';
+
+  passthru.updateScript = writeScript "update.sh" ''
+    #!${stdenv.shell}
+    set -o errexit
+    PATH=${
+      lib.makeBinPath [
+        common-updater-scripts
+        coreutils
+        git
+        gnused
+        nix
+      ]
+    }
+    oldVersion="$(nix-instantiate --eval -E "with import ./. {}; lib.getVersion ${pname}" | tr -d '"' | sed 's|\\.|-|g')"
+    latestTag="$(git -c 'versionsort.suffix=-' ls-remote --exit-code --refs --sort='version:refname' --tags git@github.com:${owner}/${repo} '*.*.*' | tail --lines=1 | cut --delimiter='/' --fields=3)"
+    if [ "$oldVersion" != "$latestTag" ]; then
+      nixpkgs="$(git rev-parse --show-toplevel)"
+      default_nix="$nixpkgs/pkgs/applications/editors/nano/nanorc/default.nix"
+      newTag=$(echo $latestTag | sed 's|\.|-|g')
+      update-source-version ${pname} "$newTag" --version-key=version --print-changes
+    else
+      echo "${pname} is already up-to-date"
+    fi
+  '';
+
+  meta = {
+    description = "Improved Nano Syntax Highlighting Files";
+    homepage = "https://github.com/scopatz/nanorc";
+    license = lib.licenses.gpl3;
+    maintainers = with lib.maintainers; [ nequissimus ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/applications/editors/nano/test-with-expect.nix

@@ -0,0 +1,35 @@
+{ nano, expect, runCommand, writeScriptBin, runtimeShell }:
+
+let expect-script = writeScriptBin "expect-script" ''
+  #!${expect}/bin/expect -f
+
+  # Load nano
+  spawn nano file.txt
+  expect "GNU nano ${nano.version}"
+
+  # Add some text to the buffer
+  send "Hello world!"
+  expect "Hello world!"
+
+  # Send ctrl-x (exit)
+  send "\030"
+  expect "Save modified buffer?"
+
+  # Answer "yes"
+  send "y"
+  expect "File Name to Write"
+
+  # Send "return" to accept the file path.
+  send "\r"
+  sleep 1
+  exit
+''; in
+runCommand "nano-test-expect"
+{
+  nativeBuildInputs = [ nano expect ];
+  passthru = { inherit expect-script; };
+} ''
+  expect -f ${expect-script}/bin/expect-script
+  grep "Hello world!" file.txt
+  touch $out
+''