uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/emulators/cdemu/analyzer.nix

@@ -0,0 +1,21 @@
+{ callPackage, makeWrapper, gobject-introspection, cmake
+, python3Packages, gtk3, glib, libxml2, gnuplot, gnome, gdk-pixbuf, librsvg, intltool, libmirage }:
+let pkg = import ./base.nix {
+  version = "3.2.5";
+  pname = "image-analyzer";
+  pkgSha256 = "00906lky0z1m0bdqnjmzxgcb19dzvljhddhh42lixyr53sjp94cc";
+};
+in callPackage pkg {
+  buildInputs = [ glib gtk3 libxml2 gnuplot libmirage makeWrapper
+                  gnome.adwaita-icon-theme gdk-pixbuf librsvg intltool
+                  python3Packages.python python3Packages.pygobject3 python3Packages.matplotlib ];
+  drvParams = {
+    nativeBuildInputs = [ gobject-introspection cmake ];
+    postFixup = ''
+      wrapProgram $out/bin/image-analyzer \
+        --set PYTHONPATH "$PYTHONPATH" \
+        --set GI_TYPELIB_PATH "$GI_TYPELIB_PATH" \
+        --prefix XDG_DATA_DIRS : "$out/share:$XDG_ICON_DIRS:$GSETTINGS_SCHEMAS_PATH"
+    '';
+  };
+}

pkgs/applications/emulators/cdemu/base.nix

@@ -0,0 +1,36 @@
+{ pname, version, pkgSha256 }:
+{ lib, stdenv, fetchurl, cmake, pkg-config, buildInputs, drvParams ? {} }:
+stdenv.mkDerivation ( rec {
+  inherit pname version buildInputs;
+  src = fetchurl {
+    url = "mirror://sourceforge/cdemu/${pname}-${version}.tar.xz";
+    sha256 = pkgSha256;
+  };
+  nativeBuildInputs = [ pkg-config cmake ];
+  setSourceRoot = ''
+    mkdir build
+    cd build
+    sourceRoot="`pwd`"
+  '';
+  configurePhase = ''
+    cmake ../${pname}-${version} -DCMAKE_INSTALL_PREFIX=$out -DCMAKE_BUILD_TYPE=Release -DCMAKE_SKIP_RPATH=ON
+  '';
+  meta = with lib; {
+    description = "A suite of tools for emulating optical drives and discs";
+    longDescription = ''
+      CDEmu consists of:
+
+      - a kernel module implementing a virtual drive-controller
+      - libmirage which is a software library for interpreting optical disc images
+      - a daemon which emulates the functionality of an optical drive+disc
+      - textmode and GTK clients for controlling the emulator
+      - an image analyzer to view the structure of image files
+
+      Optical media emulated by CDemu can be mounted within Linux. Automounting is also allowed.
+    '';
+    homepage = "https://cdemu.sourceforge.io/";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with lib.maintainers; [ bendlas ];
+  };
+} // drvParams)

pkgs/applications/emulators/cdemu/client.nix

@@ -0,0 +1,16 @@
+{ callPackage, python3Packages, intltool, makeWrapper }:
+let pkg = import ./base.nix {
+  version = "3.2.5";
+  pname = "cdemu-client";
+  pkgSha256 = "1prrdhv0ia0axc6b73crszqzh802wlkihz6d100yvg7wbgmqabd7";
+};
+in callPackage pkg {
+  buildInputs = [ python3Packages.python python3Packages.dbus-python python3Packages.pygobject3
+                  intltool makeWrapper ];
+  drvParams = {
+    postFixup = ''
+      wrapProgram $out/bin/cdemu \
+        --set PYTHONPATH "$PYTHONPATH"
+    '';
+  };
+}

pkgs/applications/emulators/cdemu/daemon.nix

@@ -0,0 +1,9 @@
+{ callPackage, glib, libao, intltool, libmirage }:
+let pkg = import ./base.nix {
+  version = "3.2.5";
+  pname = "cdemu-daemon";
+  pkgSha256 = "16g6fv1lxkdmbsy6zh5sj54dvgwvm900fd18aq609yg8jnqm644d";
+};
+in callPackage pkg {
+  buildInputs = [ glib libao libmirage intltool ];
+}

pkgs/applications/emulators/cdemu/gui.nix

@@ -0,0 +1,23 @@
+{ callPackage, makeWrapper, gobject-introspection, cmake
+, python3Packages, gtk3, glib, libnotify, intltool, gnome, gdk-pixbuf, librsvg }:
+let
+  pkg = import ./base.nix {
+    version = "3.2.5";
+    pname = "gcdemu";
+    pkgSha256 = "1nvpbq4mz8caw91q5ny9gf206g9bypavxws9nxyfcanfkc4zfkl4";
+  };
+  inherit (python3Packages) python pygobject3;
+in callPackage pkg {
+  buildInputs = [ python pygobject3 gtk3 glib libnotify intltool makeWrapper
+                  gnome.adwaita-icon-theme gdk-pixbuf librsvg ];
+  drvParams = {
+    nativeBuildInputs = [ gobject-introspection cmake ];
+    postFixup = ''
+      wrapProgram $out/bin/gcdemu \
+        --set PYTHONPATH "$PYTHONPATH" \
+        --set GI_TYPELIB_PATH "$GI_TYPELIB_PATH" \
+        --prefix XDG_DATA_DIRS : "$out/share:$XDG_ICON_DIRS:$GSETTINGS_SCHEMAS_PATH"
+    '';
+    # TODO AppIndicator
+  };
+}

pkgs/applications/emulators/cdemu/libmirage.nix

@@ -0,0 +1,18 @@
+{ callPackage, gobject-introspection, cmake, pkg-config
+, glib, libsndfile, zlib, bzip2, xz, libsamplerate, intltool
+, pcre, util-linux, libselinux, libsepol }:
+
+let pkg = import ./base.nix {
+  version = "3.2.5";
+  pname = "libmirage";
+  pkgSha256 = "0f8i2ha44rykkk3ac2q8zsw3y1zckw6qnf6zvkyrj3qqbzhrf3fm";
+};
+in callPackage pkg {
+  buildInputs = [ glib libsndfile zlib bzip2 xz libsamplerate intltool ];
+  drvParams = {
+    PKG_CONFIG_GOBJECT_INTROSPECTION_1_0_GIRDIR = "${placeholder "out"}/share/gir-1.0";
+    PKG_CONFIG_GOBJECT_INTROSPECTION_1_0_TYPELIBDIR = "${placeholder "out"}/lib/girepository-1.0";
+    nativeBuildInputs = [ cmake gobject-introspection pkg-config ];
+    propagatedBuildInputs = [ pcre util-linux libselinux libsepol ];
+  };
+}

pkgs/applications/emulators/cdemu/vhba.nix

@@ -0,0 +1,22 @@
+{ lib, stdenv, fetchurl, kernel }:
+
+stdenv.mkDerivation rec {
+  pname = "vhba";
+  version = "20211218";
+
+  src  = fetchurl {
+    url = "mirror://sourceforge/cdemu/vhba-module-${version}.tar.xz";
+    sha256 = "sha256-csWowcRSgF5M74yv787MLSXOGXrkxnODCCgC5a3Nd7Y=";
+  };
+
+  makeFlags = kernel.makeFlags ++ [ "KDIR=${kernel.dev}/lib/modules/${kernel.modDirVersion}/build" "INSTALL_MOD_PATH=$(out)" ];
+  nativeBuildInputs = kernel.moduleBuildDependencies;
+
+  meta = with lib; {
+    description = "Provides a Virtual (SCSI) HBA";
+    homepage = "https://cdemu.sourceforge.io/about/vhba/";
+    platforms = platforms.linux;
+    license = licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ bendlas ];
+  };
+}