uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov
Alan Daniels
commit
56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
122
pkgs/applications/emulators/dolphin-emu/default.nix
Normal file
122
pkgs/applications/emulators/dolphin-emu/default.nix
Normal file
|
|
@ -0,0 +1,122 @@
|
|||
{ stdenv
|
||||
, lib
|
||||
, fetchpatch
|
||||
, pkg-config
|
||||
, cmake
|
||||
, bluez
|
||||
, ffmpeg
|
||||
, libao
|
||||
, gtk2
|
||||
, glib
|
||||
, libGLU
|
||||
, libGL
|
||||
, gettext
|
||||
, libpthreadstubs
|
||||
, libXrandr
|
||||
, libXext
|
||||
, readline
|
||||
, openal
|
||||
, libXdmcp
|
||||
, portaudio
|
||||
, fetchFromGitHub
|
||||
, libusb1
|
||||
, libevdev
|
||||
, wxGTK30
|
||||
, soundtouch
|
||||
, miniupnpc
|
||||
, mbedtls
|
||||
, curl
|
||||
, lzo
|
||||
, sfml
|
||||
, libpulseaudio ? null
|
||||
}:
|
||||
|
||||
stdenv.mkDerivation rec {
|
||||
pname = "dolphin-emu";
|
||||
version = "5.0";
|
||||
|
||||
src = fetchFromGitHub {
|
||||
owner = "dolphin-emu";
|
||||
repo = "dolphin";
|
||||
rev = version;
|
||||
sha256 = "07mlfnh0hwvk6xarcg315x7z2j0qbg9g7cm040df9c8psiahc3g6";
|
||||
};
|
||||
|
||||
patches = [
|
||||
# Fix build with soundtouch 2.1.2
|
||||
(fetchpatch {
|
||||
url = "https://src.fedoraproject.org/rpms/dolphin-emu/raw/a1b91fdf94981e12c8889a02cba0ec2267d0f303/f/dolphin-emu-5.0-soundtouch-exception-fix.patch";
|
||||
name = "dolphin-emu-5.0-soundtouch-exception-fix.patch";
|
||||
sha256 = "0yd3l46nja5qiknnl30ryad98f3v8911jwnr67hn61dzx2kwbbaw";
|
||||
})
|
||||
# Fix build with gcc 8
|
||||
(fetchpatch {
|
||||
url = "https://salsa.debian.org/games-team/dolphin-emu/raw/9b7b4aeac1b60dcf28bdcafbed6bc498b2aeb0ad/debian/patches/03_gcc8.patch";
|
||||
name = "03_gcc8.patch";
|
||||
sha256 = "1da95gb8c95kd5cjhdvg19cv2z863lj3va5gx3bqc7g8r36glqxr";
|
||||
})
|
||||
];
|
||||
|
||||
postPatch = ''
|
||||
substituteInPlace Source/Core/VideoBackends/OGL/RasterFont.cpp \
|
||||
--replace " CHAR_WIDTH " " CHARWIDTH "
|
||||
'';
|
||||
|
||||
cmakeFlags = [
|
||||
"-DGTK2_GLIBCONFIG_INCLUDE_DIR=${glib.out}/lib/glib-2.0/include"
|
||||
"-DGTK2_GDKCONFIG_INCLUDE_DIR=${gtk2.out}/lib/gtk-2.0/include"
|
||||
"-DGTK2_INCLUDE_DIRS=${gtk2.dev}/include/gtk-2.0"
|
||||
"-DENABLE_LTO=True"
|
||||
];
|
||||
|
||||
nativeBuildInputs = [
|
||||
pkg-config
|
||||
cmake
|
||||
];
|
||||
|
||||
buildInputs = [
|
||||
bluez
|
||||
ffmpeg
|
||||
libao
|
||||
libGLU
|
||||
libGL
|
||||
gtk2
|
||||
glib
|
||||
gettext
|
||||
libpthreadstubs
|
||||
libXrandr
|
||||
libXext
|
||||
readline
|
||||
openal
|
||||
libevdev
|
||||
libXdmcp
|
||||
portaudio
|
||||
libpulseaudio
|
||||
libevdev
|
||||
libXdmcp
|
||||
portaudio
|
||||
libusb1
|
||||
libpulseaudio
|
||||
wxGTK30
|
||||
soundtouch
|
||||
miniupnpc
|
||||
mbedtls
|
||||
curl
|
||||
lzo
|
||||
sfml
|
||||
];
|
||||
|
||||
postInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
|
||||
install -D $src/Data/51-usb-device.rules $out/etc/udev/rules.d/51-usb-device.rules
|
||||
'';
|
||||
|
||||
meta = with lib; {
|
||||
homepage = "https://dolphin-emu.org/";
|
||||
description = "Gamecube/Wii/Triforce emulator for x86_64 and ARMv8";
|
||||
license = licenses.gpl2Plus;
|
||||
maintainers = with maintainers; [ MP2E ashkitten ];
|
||||
# x86_32 is an unsupported platform.
|
||||
# Enable generic build if you really want a JIT-less binary.
|
||||
platforms = [ "x86_64-linux" ];
|
||||
};
|
||||
}
|
||||
87
pkgs/applications/emulators/dolphin-emu/master.nix
Normal file
87
pkgs/applications/emulators/dolphin-emu/master.nix
Normal file
|
|
@ -0,0 +1,87 @@
|
|||
{ lib, stdenv, fetchFromGitHub, pkg-config, cmake
|
||||
, wrapQtAppsHook, qtbase, bluez, ffmpeg, libao, libGLU, libGL, pcre, gettext
|
||||
, libXrandr, libusb1, libpthreadstubs, libXext, libXxf86vm, libXinerama
|
||||
, libSM, libXdmcp, readline, openal, udev, libevdev, portaudio, curl, alsa-lib
|
||||
, miniupnpc, enet, mbedtls, soundtouch, sfml, xz, writeScript
|
||||
, vulkan-loader ? null, libpulseaudio ? null
|
||||
|
||||
# - Inputs used for Darwin
|
||||
, CoreBluetooth, ForceFeedback, IOKit, OpenGL, libpng, hidapi }:
|
||||
|
||||
stdenv.mkDerivation rec {
|
||||
pname = "dolphin-emu";
|
||||
version = "5.0-16380";
|
||||
|
||||
src = fetchFromGitHub {
|
||||
owner = "dolphin-emu";
|
||||
repo = "dolphin";
|
||||
rev = "8335ec70e5fe253eb21509408ca6b5736ed57dfc";
|
||||
sha256 = "sha256-WRQ3WfMTlIPoYrEFWLHL9KSfhzQl24AlkbWjh3a4fPE=";
|
||||
fetchSubmodules = true;
|
||||
};
|
||||
|
||||
nativeBuildInputs = [ cmake pkg-config ]
|
||||
++ lib.optional stdenv.isLinux wrapQtAppsHook;
|
||||
|
||||
buildInputs = [
|
||||
curl ffmpeg libao libGLU libGL pcre gettext libpthreadstubs libpulseaudio
|
||||
libXrandr libXext libXxf86vm libXinerama libSM readline openal libXdmcp
|
||||
portaudio libusb1 libpng hidapi miniupnpc enet mbedtls soundtouch sfml xz
|
||||
qtbase
|
||||
] ++ lib.optionals stdenv.isLinux [
|
||||
bluez udev libevdev alsa-lib vulkan-loader
|
||||
] ++ lib.optionals stdenv.isDarwin [
|
||||
CoreBluetooth OpenGL ForceFeedback IOKit
|
||||
];
|
||||
|
||||
cmakeFlags = [
|
||||
"-DUSE_SHARED_ENET=ON"
|
||||
"-DENABLE_LTO=ON"
|
||||
"-DDOLPHIN_WC_REVISION=${src.rev}"
|
||||
"-DDOLPHIN_WC_DESCRIBE=${version}"
|
||||
"-DDOLPHIN_WC_BRANCH=master"
|
||||
] ++ lib.optionals stdenv.isDarwin [
|
||||
"-DOSX_USE_DEFAULT_SEARCH_PATH=True"
|
||||
];
|
||||
|
||||
qtWrapperArgs = lib.optionals stdenv.isLinux [
|
||||
"--prefix LD_LIBRARY_PATH : ${vulkan-loader}/lib"
|
||||
# https://bugs.dolphin-emu.org/issues/11807
|
||||
# The .desktop file should already set this, but Dolphin may be launched in other ways
|
||||
"--set QT_QPA_PLATFORM xcb"
|
||||
];
|
||||
|
||||
# - Allow Dolphin to use nix-provided libraries instead of building them
|
||||
postPatch = ''
|
||||
sed -i -e 's,DISTRIBUTOR "None",DISTRIBUTOR "NixOS",g' CMakeLists.txt
|
||||
'' + lib.optionalString stdenv.isDarwin ''
|
||||
sed -i -e 's,if(NOT APPLE),if(true),g' CMakeLists.txt
|
||||
sed -i -e 's,if(LIBUSB_FOUND AND NOT APPLE),if(LIBUSB_FOUND),g' \
|
||||
CMakeLists.txt
|
||||
'';
|
||||
|
||||
postInstall = lib.optionalString stdenv.hostPlatform.isLinux ''
|
||||
install -D $src/Data/51-usb-device.rules $out/etc/udev/rules.d/51-usb-device.rules
|
||||
'';
|
||||
|
||||
|
||||
passthru.updateScript = writeScript "dolphin-update-script" ''
|
||||
#!/usr/bin/env nix-shell
|
||||
#!nix-shell -i bash -p curl jq common-updater-scripts
|
||||
set -eou pipefail
|
||||
json="$(curl -s https://dolphin-emu.org/update/latest/beta)"
|
||||
version="$(jq -r '.shortrev' <<< "$json")"
|
||||
rev="$(jq -r '.hash' <<< "$json")"
|
||||
update-source-version dolphin-emu-beta "$version" --rev="$rev"
|
||||
'';
|
||||
|
||||
meta = with lib; {
|
||||
homepage = "https://dolphin-emu.org";
|
||||
description = "Gamecube/Wii/Triforce emulator for x86_64 and ARMv8";
|
||||
license = licenses.gpl2Plus;
|
||||
maintainers = with maintainers; [ MP2E ashkitten xfix ];
|
||||
branch = "master";
|
||||
broken = stdenv.isDarwin;
|
||||
platforms = platforms.unix;
|
||||
};
|
||||
}
|
||||
149
pkgs/applications/emulators/dolphin-emu/primehack.nix
Normal file
149
pkgs/applications/emulators/dolphin-emu/primehack.nix
Normal file
|
|
@ -0,0 +1,149 @@
|
|||
{ lib
|
||||
, stdenv
|
||||
, fetchFromGitHub
|
||||
, pkg-config
|
||||
, cmake
|
||||
, wrapQtAppsHook
|
||||
, qtbase
|
||||
, bluez
|
||||
, ffmpeg
|
||||
, libao
|
||||
, libGLU
|
||||
, libGL
|
||||
, pcre
|
||||
, gettext
|
||||
, libXrandr
|
||||
, libusb1
|
||||
, libpthreadstubs
|
||||
, libXext
|
||||
, libXxf86vm
|
||||
, libXinerama
|
||||
, libSM
|
||||
, libXdmcp
|
||||
, readline
|
||||
, openal
|
||||
, udev
|
||||
, libevdev
|
||||
, portaudio
|
||||
, curl
|
||||
, alsa-lib
|
||||
, miniupnpc
|
||||
, enet
|
||||
, mbedtls
|
||||
, soundtouch
|
||||
, sfml
|
||||
, fmt
|
||||
, xz
|
||||
, vulkan-loader
|
||||
, libpulseaudio
|
||||
|
||||
# - Inputs used for Darwin
|
||||
, CoreBluetooth
|
||||
, ForceFeedback
|
||||
, IOKit
|
||||
, OpenGL
|
||||
, libpng
|
||||
, hidapi
|
||||
}:
|
||||
|
||||
stdenv.mkDerivation rec {
|
||||
pname = "dolphin-emu-primehack";
|
||||
version = "1.0.6";
|
||||
|
||||
src = fetchFromGitHub {
|
||||
owner = "shiiion";
|
||||
repo = "dolphin";
|
||||
rev = version;
|
||||
sha256 = "sha256-ywCh6wiBjXY5baWfu7cBgwc8w8yJaLM3QQ0FATsrweQ=";
|
||||
fetchSubmodules = true;
|
||||
};
|
||||
|
||||
nativeBuildInputs = [
|
||||
pkg-config
|
||||
cmake
|
||||
] ++ lib.optional stdenv.isLinux wrapQtAppsHook;
|
||||
|
||||
buildInputs = [
|
||||
curl
|
||||
ffmpeg
|
||||
libao
|
||||
libGLU
|
||||
libGL
|
||||
pcre
|
||||
gettext
|
||||
libpthreadstubs
|
||||
libpulseaudio
|
||||
libXrandr
|
||||
libXext
|
||||
libXxf86vm
|
||||
libXinerama
|
||||
libSM
|
||||
readline
|
||||
openal
|
||||
libXdmcp
|
||||
portaudio
|
||||
libusb1
|
||||
libpng
|
||||
hidapi
|
||||
miniupnpc
|
||||
enet
|
||||
mbedtls
|
||||
soundtouch
|
||||
sfml
|
||||
fmt
|
||||
xz
|
||||
qtbase
|
||||
] ++ lib.optionals stdenv.isLinux [
|
||||
bluez
|
||||
udev
|
||||
libevdev
|
||||
alsa-lib
|
||||
vulkan-loader
|
||||
] ++ lib.optionals stdenv.isDarwin [
|
||||
CoreBluetooth
|
||||
OpenGL
|
||||
ForceFeedback
|
||||
IOKit
|
||||
];
|
||||
|
||||
cmakeFlags = [
|
||||
"-DUSE_SHARED_ENET=ON"
|
||||
"-DENABLE_LTO=ON"
|
||||
] ++ lib.optionals stdenv.isDarwin [
|
||||
"-DOSX_USE_DEFAULT_SEARCH_PATH=True"
|
||||
];
|
||||
|
||||
qtWrapperArgs = lib.optionals stdenv.isLinux [
|
||||
"--prefix LD_LIBRARY_PATH : ${vulkan-loader}/lib"
|
||||
# https://bugs.dolphin-emu.org/issues/11807
|
||||
# The .desktop file should already set this, but Dolphin may be launched in other ways
|
||||
"--set QT_QPA_PLATFORM xcb"
|
||||
];
|
||||
|
||||
# - Allow Dolphin to use nix-provided libraries instead of building them
|
||||
postPatch = ''
|
||||
substituteInPlace CMakeLists.txt --replace 'DISTRIBUTOR "None"' 'DISTRIBUTOR "NixOS"'
|
||||
'' + lib.optionalString stdenv.isDarwin ''
|
||||
substituteInPlace CMakeLists.txt --replace 'if(NOT APPLE)' 'if(true)'
|
||||
substituteInPlace CMakeLists.txt --replace 'if(LIBUSB_FOUND AND NOT APPLE)' 'if(LIBUSB_FOUND)'
|
||||
'';
|
||||
|
||||
postInstall = ''
|
||||
mv $out/bin/dolphin-emu $out/bin/dolphin-emu-primehack
|
||||
mv $out/bin/dolphin-emu-nogui $out/bin/dolphin-emu-primehack-nogui
|
||||
mv $out/share/applications/dolphin-emu.desktop $out/share/applications/dolphin-emu-primehack.desktop
|
||||
mv $out/share/icons/hicolor/256x256/apps/dolphin-emu.png $out/share/icons/hicolor/256x256/apps/dolphin-emu-primehack.png
|
||||
substituteInPlace $out/share/applications/dolphin-emu-primehack.desktop --replace 'dolphin-emu' 'dolphin-emu-primehack'
|
||||
'' + lib.optionalString stdenv.hostPlatform.isLinux ''
|
||||
install -D $src/Data/51-usb-device.rules $out/etc/udev/rules.d/51-usb-device.rules
|
||||
'';
|
||||
|
||||
meta = with lib; {
|
||||
homepage = "https://github.com/shiiion/dolphin";
|
||||
description = "Gamecube/Wii/Triforce emulator for x86_64 and ARMv8";
|
||||
license = licenses.gpl2Plus;
|
||||
maintainers = with maintainers; [ MP2E ashkitten Madouura ];
|
||||
broken = stdenv.isDarwin;
|
||||
platforms = platforms.unix;
|
||||
};
|
||||
}
|
||||
Loading…
Add table
Add a link
Reference in a new issue