uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/emulators/yuzu/default.nix

@@ -0,0 +1,45 @@
+{ branch ? "mainline"
+, libsForQt5
+, fetchFromGitHub
+, fetchurl
+}:
+
+let
+  # Fetched from https://api.yuzu-emu.org/gamedb, last updated 2022-05-12
+  # Please make sure to update this when updating yuzu!
+  compat-list = fetchurl {
+    name = "yuzu-compat-list";
+    url = "https://web.archive.org/web/20220512184801/https://api.yuzu-emu.org/gamedb";
+    sha256 = "sha256-anOmO7NscHDsQxT03+YbJEyBkXjhcSVGgKpDwt//GHw=";
+  };
+in {
+  mainline = libsForQt5.callPackage ./generic.nix rec {
+    pname = "yuzu-mainline";
+    version = "1014";
+
+    src = fetchFromGitHub {
+      owner = "yuzu-emu";
+      repo = "yuzu-mainline";
+      rev = "mainline-0-${version}";
+      sha256 = "1x3d1fjssadv4kybc6mk153jlvncsfgm5aipkq5n5i8sr7mmr3nw";
+      fetchSubmodules = true;
+    };
+
+    inherit branch compat-list;
+  };
+
+  early-access = libsForQt5.callPackage ./generic.nix rec {
+    pname = "yuzu-ea";
+    version = "2725";
+
+    src = fetchFromGitHub {
+      owner = "pineappleEA";
+      repo = "pineapple-src";
+      rev = "EA-${version}";
+      sha256 = "1nmcl9y9chr7cdvnra5zs1v42d3i801hmsjdlz3fmp15n04bcjmp";
+      fetchSubmodules = true;
+    };
+
+    inherit branch compat-list;
+  };
+}.${branch}

pkgs/applications/emulators/yuzu/generic.nix

@@ -0,0 +1,164 @@
+{ pname
+, version
+, src
+, branch
+, compat-list
+
+, lib
+, stdenv
+, runCommandLocal
+, substituteAll
+, wrapQtAppsHook
+, alsa-lib
+, boost
+, catch2
+, cmake
+, doxygen
+, ffmpeg
+, fmt_8
+, glslang
+, libjack2
+, libopus
+, libpulseaudio
+, libusb1
+, libva
+, libzip
+, lz4
+, nlohmann_json
+, perl
+, pkg-config
+, python3
+, qtbase
+, qttools
+, qtwebengine
+, rapidjson
+, SDL2
+, sndio
+, speexdsp
+, udev
+, vulkan-headers
+, vulkan-loader
+, zlib
+, zstd
+}:
+
+stdenv.mkDerivation rec {
+  inherit pname version src;
+
+  # Replace icons licensed under CC BY-ND 3.0 with free ones to allow
+  # for binary redistribution: https://github.com/yuzu-emu/yuzu/pull/8104
+  # The patch hosted on GitHub has the binary information stripped, so
+  # it has been regenerated with "git format-patch --text --full-index --binary"
+  patches = [ ./yuzu-free-icons.patch ];
+
+  nativeBuildInputs = [
+    cmake
+    doxygen
+    perl
+    pkg-config
+    python3
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    alsa-lib
+    boost
+    catch2
+    ffmpeg
+    fmt_8
+    glslang
+    libjack2
+    libopus
+    libpulseaudio
+    libusb1
+    libva
+    libzip
+    lz4
+    nlohmann_json
+    qtbase
+    qttools
+    qtwebengine
+    rapidjson
+    SDL2
+    sndio
+    speexdsp
+    udev
+    zlib
+    zstd
+  ];
+
+  doCheck = true;
+
+  # This changes `ir/opt` to `ir/var/empty` in `externals/dynarmic/src/dynarmic/CMakeLists.txt`
+  # making the build fail, as that path does not exist
+  dontFixCmake = true;
+
+  cmakeFlags = [
+    "-DYUZU_USE_BUNDLED_QT=OFF"
+    "-DYUZU_USE_BUNDLED_FFMPEG=OFF"
+    "-DYUZU_USE_BUNDLED_OPUS=OFF"
+    "-DYUZU_USE_EXTERNAL_SDL2=OFF"
+
+    "-DENABLE_QT_TRANSLATION=ON"
+    "-DYUZU_USE_QT_WEB_ENGINE=ON"
+    "-DUSE_DISCORD_PRESENCE=ON"
+
+    # We dont want to bother upstream with potentially outdated compat reports
+    "-DYUZU_ENABLE_COMPATIBILITY_REPORTING=OFF"
+    "-DENABLE_COMPATIBILITY_LIST_DOWNLOAD=OFF" # We provide this deterministically
+  ];
+
+  preConfigure = ''
+    # This prevents a check for submodule directories.
+    rm -f .gitmodules
+
+    # see https://github.com/NixOS/nixpkgs/issues/114044, setting this through cmakeFlags does not work.
+    cmakeFlagsArray+=(
+      "-DTITLE_BAR_FORMAT_IDLE=yuzu ${branch} ${version}"
+      "-DTITLE_BAR_FORMAT_RUNNING=yuzu ${branch} ${version} | {3}"
+    )
+  '';
+
+  # This must be done after cmake finishes as it overwrites the file
+  postConfigure = ''
+    ln -sf ${compat-list} ./dist/compatibility_list/compatibility_list.json
+  '';
+
+  # Fix vulkan detection
+  postFixup = ''
+    for bin in $out/bin/yuzu $out/bin/yuzu-cmd; do
+      wrapProgram $bin --prefix LD_LIBRARY_PATH : ${vulkan-loader}/lib
+    done
+  '';
+
+  passthru.updateScript = runCommandLocal "yuzu-${branch}-updateScript" {
+    script = substituteAll {
+      src = ./update.sh;
+      inherit branch;
+    };
+  } "install -Dm755 $script $out";
+
+  meta = with lib; {
+    homepage = "https://yuzu-emu.org";
+    changelog = "https://yuzu-emu.org/entry";
+    description = "The ${branch} branch of an experimental Nintendo Switch emulator written in C++";
+    longDescription = ''
+      An experimental Nintendo Switch emulator written in C++.
+      Using the mainline branch is recommanded for general usage.
+      Using the early-access branch is recommanded if you would like to try out experimental features, with a cost of stability.
+    '';
+    mainProgram = "yuzu";
+    platforms = [ "x86_64-linux" ];
+    license = with licenses; [
+      gpl3Plus
+      # Icons. Note that this would be cc0 and cc-by-nd-30 without the "yuzu-free-icons" patch
+      asl20 mit cc0
+    ];
+    maintainers = with maintainers; [
+      ashley
+      ivar
+      joshuafern
+      sbruder
+    ];
+  };
+}

pkgs/applications/emulators/yuzu/update.sh

@@ -0,0 +1,84 @@
+#! /usr/bin/env nix-shell
+#! nix-shell -i bash -p nix nix-prefetch-git coreutils curl jq gnused
+
+set -e
+
+# Will be replaced with the actual branch when running this from passthru.updateScript
+BRANCH="@branch@"
+
+if [[ ! "$(basename $PWD)" = "yuzu" ]]; then
+    echo "error: Script must be ran from yuzu's directory!"
+    exit 1
+fi
+
+getLocalVersion() {
+    pushd ../../../.. >/dev/null
+    nix eval --raw -f default.nix "$1".version
+    popd >/dev/null
+}
+
+getLocalHash() {
+    pushd ../../../.. >/dev/null
+    nix eval --raw -f default.nix "$1".src.drvAttrs.outputHash
+    popd >/dev/null
+}
+
+updateMainline() {
+    OLD_MAINLINE_VERSION="$(getLocalVersion "yuzu-mainline")"
+    OLD_MAINLINE_HASH="$(getLocalHash "yuzu-mainline")"
+
+    NEW_MAINLINE_VERSION="$(curl -s ${GITHUB_TOKEN:+"-u \":$GITHUB_TOKEN\""} \
+        "https://api.github.com/repos/yuzu-emu/yuzu-mainline/releases?per_page=1" | jq -r '.[0].name' | cut -d" " -f2)"
+
+    if [[ "${OLD_MAINLINE_VERSION}" = "${NEW_MAINLINE_VERSION}" ]]; then
+        echo "yuzu-mainline is already up to date!"
+
+        [ "$KEEP_GOING" ] && return || exit
+    else
+        echo "yuzu-mainline: ${OLD_MAINLINE_VERSION} -> ${NEW_MAINLINE_VERSION}"
+    fi
+
+    echo "  Fetching source code..."
+
+    NEW_MAINLINE_HASH="$(nix-prefetch-git --quiet --fetch-submodules --rev "mainline-0-${NEW_MAINLINE_VERSION}" "https://github.com/yuzu-emu/yuzu-mainline" | jq -r '.sha256')"
+
+    echo "  Succesfully fetched. hash: ${NEW_MAINLINE_HASH}"
+
+    sed -i "s/${OLD_MAINLINE_VERSION}/${NEW_MAINLINE_VERSION}/" ./default.nix
+    sed -i "s/${OLD_MAINLINE_HASH}/${NEW_MAINLINE_HASH}/" ./default.nix
+}
+
+updateEarlyAccess() {
+    OLD_EA_VERSION="$(getLocalVersion "yuzu-ea")"
+    OLD_EA_HASH="$(getLocalHash "yuzu-ea")"
+
+    NEW_EA_VERSION="$(curl -s ${GITHUB_TOKEN:+"-u \":$GITHUB_TOKEN\""} \
+        "https://api.github.com/repos/pineappleEA/pineapple-src/releases?per_page=1" | jq -r '.[0].name' | cut -d"-" -f2 | cut -d" " -f1)"
+
+    if [[ "${OLD_EA_VERSION}" = "${NEW_EA_VERSION}" ]]; then
+        echo "yuzu-ea is already up to date!"
+
+        [ "$KEEP_GOING" ] && return || exit
+    else
+        echo "yuzu-ea: ${OLD_EA_VERSION} -> ${NEW_EA_VERSION}"
+    fi
+
+    echo "  Fetching source code..."
+
+    NEW_EA_HASH="$(nix-prefetch-git --quiet --fetch-submodules --rev "EA-${NEW_EA_VERSION}" "https://github.com/pineappleEA/pineapple-src" | jq -r '.sha256')"
+
+    echo "  Succesfully fetched. hash: ${NEW_EA_HASH}"
+
+    sed -i "s/${OLD_EA_VERSION}/${NEW_EA_VERSION}/" ./default.nix
+    sed -i "s/${OLD_EA_HASH}/${NEW_EA_HASH}/" ./default.nix
+}
+
+if [[ "$BRANCH" = "mainline" ]]; then
+    updateMainline
+elif [[ "$BRANCH" = "early-access" ]]; then
+    updateEarlyAccess
+else
+    KEEP_GOING=1
+    updateMainline
+    updateEarlyAccess
+fi