uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/maui/buho.nix

@@ -0,0 +1,48 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, applet-window-buttons
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-filebrowsing
+, mauikit-accounts
+, mauikit-texteditor
+, qtmultimedia
+, qtquickcontrols2
+}:
+
+mkDerivation {
+  pname = "buho";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    applet-window-buttons
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-filebrowsing
+    mauikit-accounts
+    mauikit-texteditor
+    qtmultimedia
+    qtquickcontrols2
+  ];
+
+  meta = with lib; {
+    description = "Task and Note Keeper";
+    homepage = "https://invent.kde.org/maui/buho";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/clip.nix

@@ -0,0 +1,48 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, applet-window-buttons
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-filebrowsing
+, qtmultimedia
+, qtquickcontrols2
+, taglib
+, ffmpeg
+}:
+
+mkDerivation {
+  pname = "clip";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    applet-window-buttons
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-filebrowsing
+    qtmultimedia
+    qtquickcontrols2
+    taglib
+    ffmpeg
+  ];
+
+  meta = with lib; {
+    description = "Video player and video collection manager";
+    homepage = "https://invent.kde.org/maui/clip";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/communicator.nix

@@ -0,0 +1,57 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, applet-window-buttons
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-accounts
+, mauikit-filebrowsing
+, mauikit-texteditor
+, qtmultimedia
+, qtquickcontrols2
+, kpeople
+, kcontacts
+}:
+
+mkDerivation {
+  pname = "communicator";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace "/usr/share/maui-accounts/manifests" "$out/usr/share/maui-accounts/manifests"
+  '';
+
+  buildInputs = [
+    applet-window-buttons
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-accounts
+    mauikit-filebrowsing
+    mauikit-texteditor
+    qtmultimedia
+    qtquickcontrols2
+    kpeople
+    kcontacts
+  ];
+
+  meta = with lib; {
+    description = "Contacts and dialer application";
+    homepage = "https://invent.kde.org/maui/communicator";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/default.nix

@@ -0,0 +1,82 @@
+/*
+
+# New packages
+
+READ THIS FIRST
+
+This module is for the MauiKit framework and official Maui applications. All
+available packages are listed in `callPackage ./srcs.nix`, although some are not yet
+packaged in Nixpkgs.
+
+IF YOUR PACKAGE IS NOT LISTED IN `callPackage ./srcs.nix`, IT DOES NOT GO HERE.
+
+See also `pkgs/applications/kde` as this is what this is based on.
+
+# Updates
+
+1. Update the URL in `callPackage ./fetch.sh`.
+2. Run `callPackage ./maintainers/scripts/fetch-kde-qt.sh pkgs/applications/maui`
+   from the top of the Nixpkgs tree.
+3. Use `nixpkgs-review wip` to check that everything builds.
+4. Commit the changes and open a pull request.
+
+*/
+
+{ lib
+, libsForQt5
+, fetchurl
+}:
+
+let
+  minQtVersion = "5.15";
+  broken = lib.versionOlder libsForQt5.qtbase.version minQtVersion;
+
+  mirror = "mirror://kde";
+  srcs = import ./srcs.nix { inherit fetchurl mirror; };
+
+  mkDerivation = args:
+    let
+      inherit (args) pname;
+      inherit (srcs.${pname}) src version;
+      mkDerivation =
+        libsForQt5.callPackage ({ mkDerivation }: mkDerivation) {};
+    in
+      mkDerivation (args // {
+        inherit pname version src;
+
+        outputs = args.outputs or [ "out" ];
+
+        meta =
+          let meta = args.meta or {}; in
+          meta // {
+            homepage = meta.homepage or "https://mauikit.org/";
+            platforms = meta.platforms or lib.platforms.linux;
+            broken = meta.broken or broken;
+          };
+      });
+
+  packages = self: with self;
+    let
+      callPackage = self.newScope {
+        inherit mkDerivation;
+      };
+    in {
+      # libraries
+      mauikit = callPackage ./mauikit.nix { };
+      mauikit-accounts = callPackage ./mauikit-accounts.nix { };
+      mauikit-filebrowsing = callPackage ./mauikit-filebrowsing.nix { };
+      mauikit-imagetools = callPackage ./mauikit-imagetools.nix { };
+      mauikit-texteditor = callPackage ./mauikit-texteditor.nix { };
+
+      # applications
+      buho = callPackage ./buho.nix { };
+      clip = callPackage ./clip.nix { };
+      communicator = callPackage ./communicator.nix { };
+      index = callPackage ./index.nix { };
+      nota = callPackage ./nota.nix { };
+      pix = callPackage ./pix.nix { };
+      shelf = callPackage ./shelf.nix { };
+      vvave = callPackage ./vvave.nix { };
+    };
+
+in lib.makeScope libsForQt5.newScope packages

pkgs/applications/maui/fetch.sh

@@ -0,0 +1 @@
+WGET_ARGS=( https://download.kde.org/stable/maui/ -A '*-2.1.2.tar.xz' )

pkgs/applications/maui/index.nix

@@ -0,0 +1,47 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-filebrowsing
+, qtmultimedia
+, qtquickcontrols2
+}:
+
+mkDerivation {
+  pname = "index-fm";
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace "-Werror" ""
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-filebrowsing
+    qtmultimedia
+    qtquickcontrols2
+  ];
+
+  meta = with lib; {
+    description = "Multi-platform file manager";
+    homepage = "https://invent.kde.org/maui/index-fm";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ dotlambda ];
+  };
+}

pkgs/applications/maui/mauikit-accounts.nix

@@ -0,0 +1,30 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, kconfig
+, kio
+, mauikit
+}:
+
+mkDerivation {
+  pname = "mauikit-accounts";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    kconfig
+    kio
+    mauikit
+  ];
+
+  meta = with lib; {
+    homepage = "https://invent.kde.org/maui/mauikit-accounts";
+    description = "MauiKit utilities to handle User Accounts";
+    license = licenses.lgpl21Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/mauikit-filebrowsing.nix

@@ -0,0 +1,30 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, kconfig
+, kio
+, mauikit
+}:
+
+mkDerivation {
+  pname = "mauikit-filebrowsing";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    kconfig
+    kio
+    mauikit
+  ];
+
+  meta = with lib; {
+    homepage = "https://invent.kde.org/maui/mauikit-filebrowsing";
+    description = "MauiKit File Browsing utilities and controls";
+    license = licenses.lgpl21Plus;
+    maintainers = with maintainers; [ dotlambda ];
+  };
+}

pkgs/applications/maui/mauikit-imagetools.nix

@@ -0,0 +1,36 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, kconfig
+, kio
+, mauikit
+, qtlocation
+, exiv2
+, kquickimageedit
+}:
+
+mkDerivation {
+  pname = "mauikit-imagetools";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    kconfig
+    kio
+    mauikit
+    qtlocation
+    exiv2
+    kquickimageedit
+  ];
+
+  meta = with lib; {
+    homepage = "https://invent.kde.org/maui/mauikit-imagetools";
+    description = "MauiKit Image Tools Components";
+    license = licenses.lgpl21Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/mauikit-texteditor.nix

@@ -0,0 +1,32 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, kconfig
+, kio
+, mauikit
+, syntax-highlighting
+}:
+
+mkDerivation {
+  pname = "mauikit-texteditor";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    kconfig
+    kio
+    mauikit
+    syntax-highlighting
+  ];
+
+  meta = with lib; {
+    homepage = "https://invent.kde.org/maui/mauikit-texteditor";
+    description = "MauiKit Text Editor components";
+    license = licenses.lgpl21Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/mauikit.nix

@@ -0,0 +1,37 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, kconfig
+, kcoreaddons
+, ki18n
+, knotifications
+, qtbase
+, qtquickcontrols2
+, qtx11extras
+}:
+
+mkDerivation {
+  pname = "mauikit";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    kconfig
+    kcoreaddons
+    ki18n
+    knotifications
+    qtquickcontrols2
+    qtx11extras
+  ];
+
+  meta = with lib; {
+    homepage = "https://mauikit.org/";
+    description = "Free and modular front-end framework for developing fast and compelling user experiences";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ dotlambda ];
+  };
+}

pkgs/applications/maui/nota.nix

@@ -0,0 +1,46 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, applet-window-buttons
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-filebrowsing
+, mauikit-texteditor
+, qtmultimedia
+, qtquickcontrols2
+}:
+
+mkDerivation {
+  pname = "nota";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    applet-window-buttons
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-filebrowsing
+    mauikit-texteditor
+    qtmultimedia
+    qtquickcontrols2
+  ];
+
+  meta = with lib; {
+    description = "Multi-platform text editor";
+    homepage = "https://invent.kde.org/maui/nota";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/pix.nix

@@ -0,0 +1,52 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, applet-window-buttons
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-filebrowsing
+, mauikit-imagetools
+, qtmultimedia
+, qtquickcontrols2
+, qtlocation
+, exiv2
+, kquickimageedit
+}:
+
+mkDerivation {
+  pname = "pix";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    applet-window-buttons
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-filebrowsing
+    mauikit-imagetools
+    qtmultimedia
+    qtquickcontrols2
+    qtlocation
+    exiv2
+    kquickimageedit
+  ];
+
+  meta = with lib; {
+    description = "Image gallery application";
+    homepage = "https://invent.kde.org/maui/pix";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/shelf.nix

@@ -0,0 +1,48 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, applet-window-buttons
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-filebrowsing
+, mauikit-texteditor
+, qtmultimedia
+, qtquickcontrols2
+, poppler
+}:
+
+mkDerivation {
+  pname = "shelf";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    applet-window-buttons
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-filebrowsing
+    mauikit-texteditor
+    qtmultimedia
+    qtquickcontrols2
+    poppler
+  ];
+
+  meta = with lib; {
+    description = "Document and EBook collection manager";
+    homepage = "https://invent.kde.org/maui/shelf";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}

pkgs/applications/maui/srcs.nix

@@ -0,0 +1,118 @@
+# DO NOT EDIT! This file is generated automatically.
+# Command: ./maintainers/scripts/fetch-kde-qt.sh pkgs/applications/maui
+{ fetchurl, mirror }:
+
+{
+  buho = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/buho/2.1.2/buho-2.1.2.tar.xz";
+      sha256 = "0xc623w1zp0yh929b8h6mf9r4frnfabd30634ba43x4ac12jk7g8";
+      name = "buho-2.1.2.tar.xz";
+    };
+  };
+  clip = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/clip/2.1.2/clip-2.1.2.tar.xz";
+      sha256 = "168lz2qi4y56pwfwyzqnhwz4lgh2763w260l860527aw049crv4z";
+      name = "clip-2.1.2.tar.xz";
+    };
+  };
+  communicator = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/communicator/2.1.2/communicator-2.1.2.tar.xz";
+      sha256 = "0m7axdjpl7s9cz6fcaj4kwr9wdxybwdb76k9rz5yigyy35vigcfi";
+      name = "communicator-2.1.2.tar.xz";
+    };
+  };
+  index-fm = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/index/2.1.2/index-fm-2.1.2.tar.xz";
+      sha256 = "1yawnzx51h6yrlnivbwz9d7481k382pzg3jnczrajfjnv7ir29dn";
+      name = "index-fm-2.1.2.tar.xz";
+    };
+  };
+  mauikit = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/mauikit/2.1.2/mauikit-2.1.2.tar.xz";
+      sha256 = "1n5p8107lwa4m5gbwlcqmmdlyw15vjaq0dfaz5zal733s6rq2gm7";
+      name = "mauikit-2.1.2.tar.xz";
+    };
+  };
+  mauikit-accounts = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/mauikit-accounts/2.1.2/mauikit-accounts-2.1.2.tar.xz";
+      sha256 = "00nc54gi34r8z6cwa0h8490gd0w01a245rh2g4d9fvbkrybwg7sk";
+      name = "mauikit-accounts-2.1.2.tar.xz";
+    };
+  };
+  mauikit-filebrowsing = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/mauikit-filebrowsing/2.1.2/mauikit-filebrowsing-2.1.2.tar.xz";
+      sha256 = "09pfjr449mkf27ywmwsvflzq0dgaiprw8b2lcms3m5ad7i6jvvyq";
+      name = "mauikit-filebrowsing-2.1.2.tar.xz";
+    };
+  };
+  mauikit-imagetools = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/mauikit-imagetools/2.1.2/mauikit-imagetools-2.1.2.tar.xz";
+      sha256 = "1830x8xwyjs7bj0qi63pl1dk5h2qi6f84mki1schviddddq5cv6j";
+      name = "mauikit-imagetools-2.1.2.tar.xz";
+    };
+  };
+  mauikit-texteditor = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/mauikit-texteditor/2.1.2/mauikit-texteditor-2.1.2.tar.xz";
+      sha256 = "19z9qry56h2624kdx5xnfjzd3spv5shc87p2m6ix33x9mmrf92p1";
+      name = "mauikit-texteditor-2.1.2.tar.xz";
+    };
+  };
+  nota = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/nota/2.1.2/nota-2.1.2.tar.xz";
+      sha256 = "11z1mw6yhwin3wj19gj9495az4p40yjkwrn0nb6i8h9b0nh44pn7";
+      name = "nota-2.1.2.tar.xz";
+    };
+  };
+  pix = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/pix/2.1.2/pix-2.1.2.tar.xz";
+      sha256 = "0ycpazi267pl4l178i34lwzc0ssjklp0indz79r7mcfpr1vicz1s";
+      name = "pix-2.1.2.tar.xz";
+    };
+  };
+  shelf = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/shelf/2.1.2/shelf-2.1.2.tar.xz";
+      sha256 = "0f3781l8wfbpj0irmri0zkp3ia3qlik4aaq3w6qk97xjv24d98xh";
+      name = "shelf-2.1.2.tar.xz";
+    };
+  };
+  station = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/station/2.1.2/station-2.1.2.tar.xz";
+      sha256 = "0lrw7rf8i277nl9bwyx5sc05bswgll00k1jzad1i69rwdfiy9ghg";
+      name = "station-2.1.2.tar.xz";
+    };
+  };
+  vvave = {
+    version = "2.1.2";
+    src = fetchurl {
+      url = "${mirror}/stable/maui/vvave/2.1.2/vvave-2.1.2.tar.xz";
+      sha256 = "14b6b034899vyvvhzl2jqifqq715lb26dnw3d5wxzxhdplfd7pdf";
+      name = "vvave-2.1.2.tar.xz";
+    };
+  };
+}

pkgs/applications/maui/vvave.nix

@@ -0,0 +1,49 @@
+{ lib
+, mkDerivation
+, cmake
+, extra-cmake-modules
+, applet-window-buttons
+, karchive
+, kcoreaddons
+, ki18n
+, kio
+, kirigami2
+, mauikit
+, mauikit-accounts
+, mauikit-filebrowsing
+, qtmultimedia
+, qtquickcontrols2
+, taglib
+}:
+
+mkDerivation {
+  pname = "vvave";
+
+  nativeBuildInputs = [
+    cmake
+    extra-cmake-modules
+  ];
+
+  buildInputs = [
+    applet-window-buttons
+    karchive
+    kcoreaddons
+    ki18n
+    kio
+    kirigami2
+    mauikit
+    mauikit-accounts
+    mauikit-filebrowsing
+    qtmultimedia
+    qtquickcontrols2
+    taglib
+  ];
+
+  meta = with lib; {
+    description = "Multi-platform media player";
+    homepage = "https://invent.kde.org/maui/vvave";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ onny ];
+  };
+}
+