uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov
Alan Daniels
commit
56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
163
pkgs/applications/misc/electrum/default.nix
Normal file
163
pkgs/applications/misc/electrum/default.nix
Normal file
|
|
@ -0,0 +1,163 @@
|
|||
{ lib
|
||||
, stdenv
|
||||
, fetchurl
|
||||
, fetchFromGitHub
|
||||
, fetchpatch
|
||||
, wrapQtAppsHook
|
||||
, python3
|
||||
, zbar
|
||||
, secp256k1
|
||||
, enableQt ? true
|
||||
# for updater.nix
|
||||
, writeScript
|
||||
, common-updater-scripts
|
||||
, bash
|
||||
, coreutils
|
||||
, curl
|
||||
, gnugrep
|
||||
, gnupg
|
||||
, gnused
|
||||
, nix
|
||||
}:
|
||||
|
||||
let
|
||||
version = "4.2.1";
|
||||
|
||||
libsecp256k1_name =
|
||||
if stdenv.isLinux then "libsecp256k1.so.0"
|
||||
else if stdenv.isDarwin then "libsecp256k1.0.dylib"
|
||||
else "libsecp256k1${stdenv.hostPlatform.extensions.sharedLibrary}";
|
||||
|
||||
libzbar_name =
|
||||
if stdenv.isLinux then "libzbar.so.0"
|
||||
else "libzbar${stdenv.hostPlatform.extensions.sharedLibrary}";
|
||||
|
||||
# Not provided in official source releases, which are what upstream signs.
|
||||
tests = fetchFromGitHub {
|
||||
owner = "spesmilo";
|
||||
repo = "electrum";
|
||||
rev = version;
|
||||
sha256 = "sha256-BoikYSsQZAv8WswIr5nmBsGmjZbTXaLAbdO2QtPvc7c=";
|
||||
|
||||
postFetch = ''
|
||||
mv $out ./all
|
||||
mv ./all/electrum/tests $out
|
||||
'';
|
||||
};
|
||||
|
||||
in
|
||||
|
||||
python3.pkgs.buildPythonApplication {
|
||||
pname = "electrum";
|
||||
inherit version;
|
||||
|
||||
src = fetchurl {
|
||||
url = "https://download.electrum.org/${version}/Electrum-${version}.tar.gz";
|
||||
sha256 = "sha256-2SxSTH9P380j2KaCbkXjgmQO7K2z81AG6PMA/EMggXA=";
|
||||
};
|
||||
|
||||
postUnpack = ''
|
||||
# can't symlink, tests get confused
|
||||
cp -ar ${tests} $sourceRoot/electrum/tests
|
||||
'';
|
||||
|
||||
nativeBuildInputs = lib.optionals enableQt [ wrapQtAppsHook ];
|
||||
|
||||
propagatedBuildInputs = with python3.pkgs; [
|
||||
aiohttp
|
||||
aiohttp-socks
|
||||
aiorpcx
|
||||
attrs
|
||||
bitstring
|
||||
cryptography
|
||||
dnspython
|
||||
jsonrpclib-pelix
|
||||
matplotlib
|
||||
pbkdf2
|
||||
protobuf
|
||||
pysocks
|
||||
qrcode
|
||||
requests
|
||||
tlslite-ng
|
||||
# plugins
|
||||
btchip
|
||||
ckcc-protocol
|
||||
keepkey
|
||||
trezor
|
||||
] ++ lib.optionals enableQt [
|
||||
pyqt5
|
||||
qdarkstyle
|
||||
];
|
||||
|
||||
preBuild = ''
|
||||
sed -i 's,usr_share = .*,usr_share = "'$out'/share",g' setup.py
|
||||
substituteInPlace ./electrum/ecc_fast.py \
|
||||
--replace ${libsecp256k1_name} ${secp256k1}/lib/libsecp256k1${stdenv.hostPlatform.extensions.sharedLibrary}
|
||||
'' + (if enableQt then ''
|
||||
substituteInPlace ./electrum/qrscanner.py \
|
||||
--replace ${libzbar_name} ${zbar.lib}/lib/libzbar${stdenv.hostPlatform.extensions.sharedLibrary}
|
||||
'' else ''
|
||||
sed -i '/qdarkstyle/d' contrib/requirements/requirements.txt
|
||||
'');
|
||||
|
||||
postInstall = lib.optionalString stdenv.isLinux ''
|
||||
# Despite setting usr_share above, these files are installed under
|
||||
# $out/nix ...
|
||||
mv $out/${python3.sitePackages}/nix/store"/"*/share $out
|
||||
rm -rf $out/${python3.sitePackages}/nix
|
||||
|
||||
substituteInPlace $out/share/applications/electrum.desktop \
|
||||
--replace 'Exec=sh -c "PATH=\"\\$HOME/.local/bin:\\$PATH\"; electrum %u"' \
|
||||
"Exec=$out/bin/electrum %u" \
|
||||
--replace 'Exec=sh -c "PATH=\"\\$HOME/.local/bin:\\$PATH\"; electrum --testnet %u"' \
|
||||
"Exec=$out/bin/electrum --testnet %u"
|
||||
|
||||
'';
|
||||
|
||||
postFixup = lib.optionalString enableQt ''
|
||||
wrapQtApp $out/bin/electrum
|
||||
'';
|
||||
|
||||
checkInputs = with python3.pkgs; [ pytestCheckHook pyaes pycryptodomex ];
|
||||
|
||||
pytestFlagsArray = [ "electrum/tests" ];
|
||||
|
||||
disabledTests = [
|
||||
"test_loop" # test tries to bind 127.0.0.1 causing permission error
|
||||
];
|
||||
|
||||
postCheck = ''
|
||||
$out/bin/electrum help >/dev/null
|
||||
'';
|
||||
|
||||
passthru.updateScript = import ./update.nix {
|
||||
inherit lib;
|
||||
inherit
|
||||
writeScript
|
||||
common-updater-scripts
|
||||
bash
|
||||
coreutils
|
||||
curl
|
||||
gnupg
|
||||
gnugrep
|
||||
gnused
|
||||
nix
|
||||
;
|
||||
};
|
||||
|
||||
meta = with lib; {
|
||||
description = "A lightweight Bitcoin wallet";
|
||||
longDescription = ''
|
||||
An easy-to-use Bitcoin client featuring wallets generated from
|
||||
mnemonic seeds (in addition to other, more advanced, wallet options)
|
||||
and the ability to perform transactions without downloading a copy
|
||||
of the blockchain.
|
||||
'';
|
||||
homepage = "https://electrum.org/";
|
||||
downloadPage = "https://electrum.org/#download";
|
||||
changelog = "https://github.com/spesmilo/electrum/blob/master/RELEASE-NOTES";
|
||||
license = licenses.mit;
|
||||
platforms = platforms.all;
|
||||
maintainers = with maintainers; [ joachifm np prusnak ];
|
||||
};
|
||||
}
|
||||
185
pkgs/applications/misc/electrum/ltc.nix
Normal file
185
pkgs/applications/misc/electrum/ltc.nix
Normal file
|
|
@ -0,0 +1,185 @@
|
|||
{ lib
|
||||
, stdenv
|
||||
, fetchurl
|
||||
, fetchFromGitHub
|
||||
, wrapQtAppsHook
|
||||
, python3
|
||||
, zbar
|
||||
, secp256k1
|
||||
, enableQt ? true
|
||||
# for updater.nix
|
||||
, writeScript
|
||||
, common-updater-scripts
|
||||
, bash
|
||||
, coreutils
|
||||
, curl
|
||||
, gnugrep
|
||||
, gnupg
|
||||
, gnused
|
||||
, nix
|
||||
}:
|
||||
|
||||
let
|
||||
version = "4.0.9.3";
|
||||
|
||||
libsecp256k1_name =
|
||||
if stdenv.isLinux then "libsecp256k1.so.0"
|
||||
else if stdenv.isDarwin then "libsecp256k1.0.dylib"
|
||||
else "libsecp256k1${stdenv.hostPlatform.extensions.sharedLibrary}";
|
||||
|
||||
libzbar_name =
|
||||
if stdenv.isLinux then "libzbar.so.0"
|
||||
else "libzbar${stdenv.hostPlatform.extensions.sharedLibrary}";
|
||||
|
||||
# Not provided in official source releases, which are what upstream signs.
|
||||
tests = fetchFromGitHub {
|
||||
owner = "pooler";
|
||||
repo = "electrum-ltc";
|
||||
rev = version;
|
||||
sha256 = "sha256-oZjQnrnj8nCaQjrIz8bWNt6Ib8Wu2ZMXHEPfCCy2fjk=";
|
||||
|
||||
postFetch = ''
|
||||
mv $out ./all
|
||||
mv ./all/electrum_ltc/tests $out
|
||||
'';
|
||||
};
|
||||
|
||||
py = python3.override {
|
||||
packageOverrides = self: super: {
|
||||
|
||||
aiorpcx = super.aiorpcx.overridePythonAttrs (oldAttrs: rec {
|
||||
version = "0.18.7";
|
||||
src = oldAttrs.src.override {
|
||||
inherit version;
|
||||
sha256 = "1rswrspv27x33xa5bnhrkjqzhv0sknv5kd7pl1vidw9d2z4rx2l0";
|
||||
};
|
||||
});
|
||||
};
|
||||
};
|
||||
|
||||
in
|
||||
|
||||
python3.pkgs.buildPythonApplication {
|
||||
pname = "electrum-ltc";
|
||||
inherit version;
|
||||
|
||||
src = fetchurl {
|
||||
url = "https://electrum-ltc.org/download/Electrum-LTC-${version}.tar.gz";
|
||||
sha256 = "sha256-+oox0BGqkvj0OGOKJF8tUoKdsZFeffNb6rTF8E8mo08=";
|
||||
};
|
||||
|
||||
postUnpack = ''
|
||||
# can't symlink, tests get confused
|
||||
cp -ar ${tests} $sourceRoot/electrum_ltc/tests
|
||||
'';
|
||||
|
||||
prePatch = ''
|
||||
substituteInPlace contrib/requirements/requirements.txt \
|
||||
--replace "dnspython>=2.0,<2.1" "dnspython>=2.0"
|
||||
|
||||
# according to upstream, this is fine
|
||||
# https://github.com/spesmilo/electrum/issues/7361
|
||||
substituteInPlace contrib/requirements/requirements.txt \
|
||||
--replace "qdarkstyle<2.9" "qdarkstyle>=2.7"
|
||||
'';
|
||||
|
||||
nativeBuildInputs = lib.optionals enableQt [ wrapQtAppsHook ];
|
||||
|
||||
propagatedBuildInputs = with py.pkgs; [
|
||||
aiohttp
|
||||
aiohttp-socks
|
||||
aiorpcx
|
||||
attrs
|
||||
bitstring
|
||||
cryptography
|
||||
dnspython
|
||||
jsonrpclib-pelix
|
||||
matplotlib
|
||||
pbkdf2
|
||||
protobuf
|
||||
py_scrypt
|
||||
pysocks
|
||||
qrcode
|
||||
requests
|
||||
tlslite-ng
|
||||
# plugins
|
||||
btchip
|
||||
ckcc-protocol
|
||||
keepkey
|
||||
trezor
|
||||
] ++ lib.optionals enableQt [
|
||||
pyqt5
|
||||
qdarkstyle
|
||||
];
|
||||
|
||||
preBuild = ''
|
||||
sed -i 's,usr_share = .*,usr_share = "'$out'/share",g' setup.py
|
||||
substituteInPlace ./electrum_ltc/ecc_fast.py \
|
||||
--replace ${libsecp256k1_name} ${secp256k1}/lib/libsecp256k1${stdenv.hostPlatform.extensions.sharedLibrary}
|
||||
'' + (if enableQt then ''
|
||||
substituteInPlace ./electrum_ltc/qrscanner.py \
|
||||
--replace ${libzbar_name} ${zbar.lib}/lib/libzbar${stdenv.hostPlatform.extensions.sharedLibrary}
|
||||
'' else ''
|
||||
sed -i '/qdarkstyle/d' contrib/requirements/requirements.txt
|
||||
'');
|
||||
|
||||
postInstall = lib.optionalString stdenv.isLinux ''
|
||||
# Despite setting usr_share above, these files are installed under
|
||||
# $out/nix ...
|
||||
mv $out/${python3.sitePackages}/nix/store"/"*/share $out
|
||||
rm -rf $out/${python3.sitePackages}/nix
|
||||
|
||||
substituteInPlace $out/share/applications/electrum-ltc.desktop \
|
||||
--replace 'Exec=sh -c "PATH=\"\\$HOME/.local/bin:\\$PATH\"; electrum-ltc %u"' \
|
||||
"Exec=$out/bin/electrum-ltc %u" \
|
||||
--replace 'Exec=sh -c "PATH=\"\\$HOME/.local/bin:\\$PATH\"; electrum-ltc --testnet %u"' \
|
||||
"Exec=$out/bin/electrum-ltc --testnet %u"
|
||||
|
||||
'';
|
||||
|
||||
postFixup = lib.optionalString enableQt ''
|
||||
wrapQtApp $out/bin/electrum-ltc
|
||||
'';
|
||||
|
||||
checkInputs = with python3.pkgs; [ pytestCheckHook pyaes pycryptodomex ];
|
||||
|
||||
pytestFlagsArray = [ "electrum_ltc/tests" ];
|
||||
|
||||
disabledTests = [
|
||||
"test_loop" # test tries to bind 127.0.0.1 causing permission error
|
||||
"test_is_ip_address" # fails spuriously https://github.com/spesmilo/electrum/issues/7307
|
||||
];
|
||||
|
||||
postCheck = ''
|
||||
$out/bin/electrum-ltc help >/dev/null
|
||||
'';
|
||||
|
||||
passthru.updateScript = import ./update.nix {
|
||||
inherit lib;
|
||||
inherit
|
||||
writeScript
|
||||
common-updater-scripts
|
||||
bash
|
||||
coreutils
|
||||
curl
|
||||
gnupg
|
||||
gnugrep
|
||||
gnused
|
||||
nix
|
||||
;
|
||||
};
|
||||
|
||||
meta = with lib; {
|
||||
description = "Lightweight Litecoin Client";
|
||||
longDescription = ''
|
||||
Electrum-LTC is a simple, but powerful Litecoin wallet. A unique secret
|
||||
phrase (or “seed”) leaves intruders stranded and your peace of mind
|
||||
intact. Keep it on paper, or in your head... and never worry about losing
|
||||
your litecoins to theft or hardware failure.
|
||||
'';
|
||||
homepage = "https://electrum-ltc.org/";
|
||||
license = licenses.mit;
|
||||
platforms = platforms.all;
|
||||
maintainers = with maintainers; [ lourkeur ];
|
||||
};
|
||||
}
|
||||
59
pkgs/applications/misc/electrum/update.nix
Normal file
59
pkgs/applications/misc/electrum/update.nix
Normal file
|
|
@ -0,0 +1,59 @@
|
|||
{ lib
|
||||
, writeScript
|
||||
, common-updater-scripts
|
||||
, bash
|
||||
, coreutils
|
||||
, curl
|
||||
, gnugrep
|
||||
, gnupg
|
||||
, gnused
|
||||
, nix
|
||||
}:
|
||||
|
||||
with lib;
|
||||
|
||||
let
|
||||
downloadPageUrl = "https://download.electrum.org";
|
||||
|
||||
signingKeys = ["6694 D8DE 7BE8 EE56 31BE D950 2BD5 824B 7F94 70E6"];
|
||||
in
|
||||
|
||||
writeScript "update-electrum" ''
|
||||
#! ${bash}/bin/bash
|
||||
|
||||
set -eu -o pipefail
|
||||
|
||||
export PATH=${makeBinPath [
|
||||
common-updater-scripts
|
||||
coreutils
|
||||
curl
|
||||
gnugrep
|
||||
gnupg
|
||||
gnused
|
||||
nix
|
||||
]}
|
||||
|
||||
version=$(curl -L --list-only -- '${downloadPageUrl}' \
|
||||
| grep -Po '<a href="\K([[:digit:]]+\.?)+' \
|
||||
| sort -Vu \
|
||||
| tail -n1)
|
||||
|
||||
srcName=Electrum-$version
|
||||
srcFile=$srcName.tar.gz
|
||||
srcUrl="${downloadPageUrl}/$version/$srcFile"
|
||||
sigUrl=$srcUrl.asc
|
||||
sigFile=$srcFile.asc
|
||||
|
||||
[[ -e "$srcFile" ]] || curl -L -o "$srcFile" -- "$srcUrl"
|
||||
[[ -e "$sigFile" ]] || curl -L -o "$sigFile" -- "$sigUrl"
|
||||
|
||||
export GNUPGHOME=$PWD/gnupg
|
||||
mkdir -m 700 -p "$GNUPGHOME"
|
||||
|
||||
gpg --batch --recv-keys ${concatStringsSep " " (map (x: "'${x}'") signingKeys)}
|
||||
gpg --batch --verify "$sigFile" "$srcFile"
|
||||
|
||||
sha256=$(nix-prefetch-url --type sha256 "file://$PWD/$srcFile")
|
||||
|
||||
update-source-version electrum "$version" "$sha256"
|
||||
''
|
||||
Loading…
Add table
Add a link
Reference in a new issue