aland/nixpkgs-odroid-hc4
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 2

uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

Browse source 
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov 2021-04-03 12:58:10 +02:00 • committed by Alan Daniels
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

64
pkgs/applications/misc/veracrypt/default.nix Normal file
View file

@ -0,0 +1,64 @@
{ lib
, stdenv
, fetchurl
, pkg-config
, makeself
, yasm
, fuse
, wxGTK
, lvm2
, substituteAll
, e2fsprogs
, exfat
, ntfs3g
, btrfs-progs
}:
with lib;
stdenv.mkDerivation rec {
pname = "veracrypt";
version = "1.25.9";
src = fetchurl {
url = "https://launchpad.net/${pname}/trunk/${toLower version}/+download/VeraCrypt_${version}_Source.tar.bz2";
sha256 = "sha256-drbhgYS8IaQdKUn/Y9ch1JBUpxbO/zpL13tcNRC3lK8=";
};
patches = [
(substituteAll {
src = ./fix-paths.patch;
ext2 = "${e2fsprogs}/bin/mkfs.ext2";
ext3 = "${e2fsprogs}/bin/mkfs.ext3";
ext4 = "${e2fsprogs}/bin/mkfs.ext4";
exfat = "${exfat}/bin/mkfs.exfat";
ntfs = "${ntfs3g}/bin/mkfs.ntfs";
btrfs = "${btrfs-progs}/bin/mkfs.btrfs";
})
];
sourceRoot = "src";
nativeBuildInputs = [ makeself pkg-config yasm ];
buildInputs = [ fuse lvm2 wxGTK ];
enableParallelBuilding = true;
installPhase = ''
install -Dm 755 Main/${pname} "$out/bin/${pname}"
install -Dm 444 Resources/Icons/VeraCrypt-256x256.xpm "$out/share/pixmaps/${pname}.xpm"
install -Dm 444 License.txt -t "$out/share/doc/${pname}/"
install -d $out/share/applications
substitute Setup/Linux/${pname}.desktop $out/share/applications/${pname}.desktop \
--replace "Exec=/usr/bin/veracrypt" "Exec=$out/bin/veracrypt" \
--replace "Icon=veracrypt" "Icon=veracrypt.xpm"
'';
meta = {
description = "Free Open-Source filesystem on-the-fly encryption";
homepage = "https://www.veracrypt.fr/";
license = with licenses; [ asl20 /* and */ unfree /* TrueCrypt License version 3.0 */ ];
maintainers = with maintainers; [ dsferruzza ];
platforms = platforms.linux;
};
}

22
pkgs/applications/misc/veracrypt/fix-paths.patch Normal file
View file

@ -0,0 +1,22 @@
diff --color --unified --recursive --text a/Core/VolumeCreator.h b/Core/VolumeCreator.h
--- a/Core/VolumeCreator.h 2021-06-20 20:54:50.725210056 +0300
+++ b/Core/VolumeCreator.h 2021-06-20 20:58:46.117742419 +0300
@@ -77,12 +77,12 @@
switch (fsType)
{
#if defined (TC_LINUX)
- case VolumeCreationOptions::FilesystemType::Ext2: return "mkfs.ext2";
- case VolumeCreationOptions::FilesystemType::Ext3: return "mkfs.ext3";
- case VolumeCreationOptions::FilesystemType::Ext4: return "mkfs.ext4";
- case VolumeCreationOptions::FilesystemType::NTFS: return "mkfs.ntfs";
- case VolumeCreationOptions::FilesystemType::exFAT: return "mkfs.exfat";
- case VolumeCreationOptions::FilesystemType::Btrfs: return "mkfs.btrfs";
+ case VolumeCreationOptions::FilesystemType::Ext2: return "@ext2@";
+ case VolumeCreationOptions::FilesystemType::Ext3: return "@ext3@";
+ case VolumeCreationOptions::FilesystemType::Ext4: return "@ext4@";
+ case VolumeCreationOptions::FilesystemType::NTFS: return "@ntfs@";
+ case VolumeCreationOptions::FilesystemType::exFAT: return "@exfat@";
+ case VolumeCreationOptions::FilesystemType::Btrfs: return "@btrfs@";
#elif defined (TC_MACOSX)
case VolumeCreationOptions::FilesystemType::MacOsExt: return "newfs_hfs";
case VolumeCreationOptions::FilesystemType::exFAT: return "newfs_exfat";