uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov
Alan Daniels
commit
56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
|
|
@ -0,0 +1,205 @@
|
|||
{ lib
|
||||
, stdenv
|
||||
, fetchurl
|
||||
, dpkg
|
||||
, undmg
|
||||
, makeWrapper
|
||||
, nodePackages
|
||||
, alsa-lib
|
||||
, at-spi2-atk
|
||||
, at-spi2-core
|
||||
, atk
|
||||
, cairo
|
||||
, cups
|
||||
, curl
|
||||
, dbus
|
||||
, expat
|
||||
, fontconfig
|
||||
, freetype
|
||||
, gdk-pixbuf
|
||||
, glib
|
||||
, gtk3
|
||||
, libGL
|
||||
, libappindicator-gtk3
|
||||
, libdrm
|
||||
, libnotify
|
||||
, libpulseaudio
|
||||
, libuuid
|
||||
, libxcb
|
||||
, libxkbcommon
|
||||
, libxshmfence
|
||||
, mesa
|
||||
, nspr
|
||||
, nss
|
||||
, pango
|
||||
, pipewire
|
||||
, systemd
|
||||
, xdg-utils
|
||||
, xorg
|
||||
}:
|
||||
|
||||
let
|
||||
inherit (stdenv.hostPlatform) system;
|
||||
throwSystem = throw "Unsupported system: ${system}";
|
||||
|
||||
pname = "slack";
|
||||
|
||||
x86_64-darwin-version = "4.26.1";
|
||||
x86_64-darwin-sha256 = "0883nnnwjaii89x6idqcl68acw1fbijyhhrwy7inwgrdw233qqcd";
|
||||
|
||||
x86_64-linux-version = "4.26.1";
|
||||
x86_64-linux-sha256 = "0nw3cfypinzp8csli1myh3b9hvv2pg1d8p9izg7znfpnlwps8gy1";
|
||||
|
||||
aarch64-darwin-version = "4.26.1";
|
||||
aarch64-darwin-sha256 = "1p5qn5zyibpyiv5is70g1la9y6wc038j3sxjyxflgqsdvania7vq";
|
||||
|
||||
version = {
|
||||
x86_64-darwin = x86_64-darwin-version;
|
||||
x86_64-linux = x86_64-linux-version;
|
||||
aarch64-darwin = aarch64-darwin-version;
|
||||
}.${system} or throwSystem;
|
||||
|
||||
|
||||
src = let
|
||||
base = "https://downloads.slack-edge.com";
|
||||
in {
|
||||
x86_64-darwin = fetchurl {
|
||||
url = "${base}/releases/macos/${version}/prod/x64/Slack-${version}-macOS.dmg";
|
||||
sha256 = x86_64-darwin-sha256;
|
||||
};
|
||||
x86_64-linux = fetchurl {
|
||||
url = "${base}/releases/linux/${version}/prod/x64/slack-desktop-${version}-amd64.deb";
|
||||
sha256 = x86_64-linux-sha256;
|
||||
};
|
||||
aarch64-darwin = fetchurl {
|
||||
url = "${base}/releases/macos/${version}/prod/arm64/Slack-${version}-macOS.dmg";
|
||||
sha256 = aarch64-darwin-sha256;
|
||||
};
|
||||
}.${system} or throwSystem;
|
||||
|
||||
meta = with lib; {
|
||||
description = "Desktop client for Slack";
|
||||
homepage = "https://slack.com";
|
||||
license = licenses.unfree;
|
||||
maintainers = with maintainers; [ mmahut maxeaubrey ];
|
||||
platforms = [ "x86_64-darwin" "x86_64-linux" "aarch64-darwin" ];
|
||||
};
|
||||
|
||||
linux = stdenv.mkDerivation rec {
|
||||
inherit pname version src meta;
|
||||
|
||||
passthru.updateScript = ./update.sh;
|
||||
|
||||
rpath = lib.makeLibraryPath [
|
||||
alsa-lib
|
||||
at-spi2-atk
|
||||
at-spi2-core
|
||||
atk
|
||||
cairo
|
||||
cups
|
||||
curl
|
||||
dbus
|
||||
expat
|
||||
fontconfig
|
||||
freetype
|
||||
gdk-pixbuf
|
||||
glib
|
||||
gtk3
|
||||
libGL
|
||||
libappindicator-gtk3
|
||||
libdrm
|
||||
libnotify
|
||||
libpulseaudio
|
||||
libuuid
|
||||
libxcb
|
||||
libxkbcommon
|
||||
mesa
|
||||
nspr
|
||||
nss
|
||||
pango
|
||||
pipewire
|
||||
stdenv.cc.cc
|
||||
systemd
|
||||
xorg.libX11
|
||||
xorg.libXScrnSaver
|
||||
xorg.libXcomposite
|
||||
xorg.libXcursor
|
||||
xorg.libXdamage
|
||||
xorg.libXext
|
||||
xorg.libXfixes
|
||||
xorg.libXi
|
||||
xorg.libXrandr
|
||||
xorg.libXrender
|
||||
xorg.libXtst
|
||||
xorg.libxkbfile
|
||||
xorg.libxshmfence
|
||||
] + ":${stdenv.cc.cc.lib}/lib64";
|
||||
|
||||
buildInputs = [
|
||||
gtk3 # needed for GSETTINGS_SCHEMAS_PATH
|
||||
];
|
||||
|
||||
nativeBuildInputs = [ dpkg makeWrapper nodePackages.asar ];
|
||||
|
||||
dontUnpack = true;
|
||||
dontBuild = true;
|
||||
dontPatchELF = true;
|
||||
|
||||
installPhase = ''
|
||||
runHook preInstall
|
||||
|
||||
# The deb file contains a setuid binary, so 'dpkg -x' doesn't work here
|
||||
dpkg --fsys-tarfile $src | tar --extract
|
||||
rm -rf usr/share/lintian
|
||||
|
||||
mkdir -p $out
|
||||
mv usr/* $out
|
||||
|
||||
# Otherwise it looks "suspicious"
|
||||
chmod -R g-w $out
|
||||
|
||||
for file in $(find $out -type f \( -perm /0111 -o -name \*.so\* \) ); do
|
||||
patchelf --set-interpreter "$(cat $NIX_CC/nix-support/dynamic-linker)" "$file" || true
|
||||
patchelf --set-rpath ${rpath}:$out/lib/slack $file || true
|
||||
done
|
||||
|
||||
# Replace the broken bin/slack symlink with a startup wrapper
|
||||
rm $out/bin/slack
|
||||
makeWrapper $out/lib/slack/slack $out/bin/slack \
|
||||
--prefix XDG_DATA_DIRS : $GSETTINGS_SCHEMAS_PATH \
|
||||
--prefix PATH : ${lib.makeBinPath [xdg-utils]} \
|
||||
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--enable-features=UseOzonePlatform --ozone-platform=wayland}}"
|
||||
|
||||
# Fix the desktop link
|
||||
substituteInPlace $out/share/applications/slack.desktop \
|
||||
--replace /usr/bin/ $out/bin/ \
|
||||
--replace /usr/share/ $out/share/
|
||||
|
||||
runHook postInstall
|
||||
'';
|
||||
};
|
||||
|
||||
darwin = stdenv.mkDerivation {
|
||||
inherit pname version src meta;
|
||||
|
||||
passthru.updateScript = ./update.sh;
|
||||
|
||||
nativeBuildInputs = [ undmg ];
|
||||
|
||||
sourceRoot = "Slack.app";
|
||||
|
||||
installPhase = ''
|
||||
runHook preInstall
|
||||
mkdir -p $out/Applications/Slack.app
|
||||
cp -R . $out/Applications/Slack.app
|
||||
'' + lib.optionalString (!stdenv.isAarch64) ''
|
||||
# on aarch64-darwin we get: Could not write domain com.tinyspeck.slackmacgap; exiting
|
||||
/usr/bin/defaults write com.tinyspeck.slackmacgap SlackNoAutoUpdates -Bool YES
|
||||
'' + ''
|
||||
runHook postInstall
|
||||
'';
|
||||
};
|
||||
in
|
||||
if stdenv.isDarwin
|
||||
then darwin
|
||||
else linux
|
||||
48
pkgs/applications/networking/instant-messengers/slack/update.sh
Executable file
48
pkgs/applications/networking/instant-messengers/slack/update.sh
Executable file
|
|
@ -0,0 +1,48 @@
|
|||
#!/usr/bin/env nix-shell
|
||||
#! nix-shell -i bash -p curl gnused
|
||||
|
||||
set -eou pipefail
|
||||
|
||||
latest_linux_version=$(curl -L --silent https://slack.com/downloads/linux | sed -n 's/.*Version \([0-9\.]\+\).*/\1/p')
|
||||
latest_mac_version=$(curl -L --silent https://slack.com/downloads/mac | sed -n 's/.*Version \([0-9\.]\+\).*/\1/p')
|
||||
|
||||
# Double check that the latest mac and linux versions are in sync.
|
||||
if [[ "$latest_linux_version" != "$latest_mac_version" ]]; then
|
||||
echo "the latest linux ($latest_linux_version) and mac ($latest_mac_version) versions are not the same"
|
||||
exit 1
|
||||
fi
|
||||
|
||||
nixpkgs="$(git rev-parse --show-toplevel)"
|
||||
slack_nix="$nixpkgs/pkgs/applications/networking/instant-messengers/slack/default.nix"
|
||||
nixpkgs_linux_version=$(cat "$slack_nix" | sed -n 's/.*x86_64-linux-version = \"\([0-9\.]\+\)\";.*/\1/p')
|
||||
nixpkgs_mac_version=$(cat "$slack_nix" | sed -n 's/.*x86_64-darwin-version = \"\([0-9\.]\+\)\";.*/\1/p')
|
||||
nixpkgs_mac_arm_version=$(cat "$slack_nix" | sed -n 's/.*aarch64-darwin-version = \"\([0-9\.]\+\)\";.*/\1/p')
|
||||
|
||||
if [[ "$nixpkgs_linux_version" == "$latest_linux_version" && \
|
||||
"$nixpkgs_mac_version" == "$latest_mac_version" && \
|
||||
"$nixpkgs_mac_arm_version" == "$latest_mac_version" ]]; then
|
||||
echo "nixpkgs versions are all up to date!"
|
||||
exit 0
|
||||
fi
|
||||
|
||||
linux_url="https://downloads.slack-edge.com/releases/linux/${latest_linux_version}/prod/x64/slack-desktop-${latest_linux_version}-amd64.deb"
|
||||
mac_url="https://downloads.slack-edge.com/releases/macos/${latest_mac_version}/prod/x64/Slack-${latest_mac_version}-macOS.dmg"
|
||||
mac_arm_url="https://downloads.slack-edge.com/releases/macos/${latest_mac_version}/prod/arm64/Slack-${latest_mac_version}-macOS.dmg"
|
||||
linux_sha256=$(nix-prefetch-url ${linux_url})
|
||||
mac_sha256=$(nix-prefetch-url ${mac_url})
|
||||
mac_arm_sha256=$(nix-prefetch-url ${mac_arm_url})
|
||||
|
||||
sed -i "s/x86_64-linux-version = \".*\"/x86_64-linux-version = \"${latest_linux_version}\"/" "$slack_nix"
|
||||
sed -i "s/x86_64-darwin-version = \".*\"/x86_64-darwin-version = \"${latest_mac_version}\"/" "$slack_nix"
|
||||
sed -i "s/aarch64-darwin-version = \".*\"/aarch64-darwin-version = \"${latest_mac_version}\"/" "$slack_nix"
|
||||
sed -i "s/x86_64-linux-sha256 = \".*\"/x86_64-linux-sha256 = \"${linux_sha256}\"/" "$slack_nix"
|
||||
sed -i "s/x86_64-darwin-sha256 = \".*\"/x86_64-darwin-sha256 = \"${mac_sha256}\"/" "$slack_nix"
|
||||
sed -i "s/aarch64-darwin-sha256 = \".*\"/aarch64-darwin-sha256 = \"${mac_arm_sha256}\"/" "$slack_nix"
|
||||
|
||||
if ! nix-build -A slack "$nixpkgs"; then
|
||||
echo "The updated slack failed to build."
|
||||
exit 1
|
||||
fi
|
||||
|
||||
echo "Successfully updated"
|
||||
echo "slack: $nixpkgs_linux_version -> $latest_linux_version"
|
||||
Loading…
Add table
Add a link
Reference in a new issue