uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/radio/noaa-apt/default.nix

@@ -0,0 +1,65 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, pkg-config
+, atk
+, cairo
+, gdk-pixbuf
+, glib
+, gtk3
+, openssl
+, pango
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "noaa-apt";
+  version = "1.3.1";
+
+  src = fetchFromGitHub {
+    owner = "martinber";
+    repo = "noaa-apt";
+    rev = "v${version}";
+    sha256 = "sha256-A78O5HkD/LyfvjLJjf7PpJDuftkNbaxq7Zs5kNUaULk=";
+  };
+
+  nativeBuildInputs = [
+    pkg-config
+  ];
+
+  buildInputs = [
+    atk
+    cairo
+    gdk-pixbuf
+    glib
+    gtk3
+    openssl
+    pango
+  ];
+
+  cargoSha256 = "sha256-o39RvJkaJ8ZPOfLWDqykCLadwHhgBbmOWGQ4hZ6/6BI=";
+
+  preBuild = ''
+    # Used by macro pointing to resource location at compile time.
+    export NOAA_APT_RES_DIR=$out/share/noaa-apt
+  '';
+
+  postInstall = ''
+    # Resources.
+    mkdir -p $out/share/noaa-apt
+    cp -R $src/res/* $out/share/noaa-apt/
+
+    # Desktop icon.
+    install -Dm644 -t $out/share/applications $src/debian/ar.com.mbernardi.noaa-apt.desktop
+    install -Dm644 -t $out/share/icons/hicolor/48x48/apps $src/debian/noaa-apt.png
+    install -Dm644 -t $out/share/icons/hicolor/scalable/apps $src/debian/noaa-apt.svg
+  '';
+
+  meta = with lib; {
+    description = "NOAA APT image decoder";
+    homepage = "https://noaa-apt.mbernardi.com.ar/";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ trepetti ];
+    platforms = platforms.all;
+    changelog = "https://github.com/martinber/noaa-apt/releases/tag/v${version}";
+  };
+}