uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/search/doodle/default.nix

@@ -0,0 +1,21 @@
+{ lib, stdenv, fetchurl, libextractor, gettext }:
+
+stdenv.mkDerivation rec {
+  pname = "doodle";
+  version = "0.7.2";
+
+  buildInputs = [ libextractor gettext ];
+
+  src = fetchurl {
+    url = "https://grothoff.org/christian/doodle/download/doodle-${version}.tar.gz";
+    sha256 = "sha256-dtRPfUjhBNgN+5zHMYmszISmBv1+K6yjKsbQBiAXWRA=";
+  };
+
+  meta = {
+    homepage = "https://grothoff.org/christian/doodle/";
+    description = "Tool to quickly index and search documents on a computer";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [ viric ];
+    platforms = with lib.platforms; linux;
+  };
+}

pkgs/applications/search/grepcidr/default.nix

@@ -0,0 +1,21 @@
+{ lib, stdenv, fetchurl }:
+
+stdenv.mkDerivation rec {
+  pname = "grepcidr";
+  version = "2.0";
+
+  src = fetchurl {
+    url = "http://www.pc-tools.net/files/unix/${pname}-${version}.tar.gz";
+    sha256 = "1yzpa1nigmmp4hir6377hrkpp0z6jnxgccaw2jbqgydbglvnm231";
+  };
+
+  installFlags = [ "PREFIX=$(out)" ];
+
+  meta = with lib; {
+    description = "Filter IPv4 and IPv6 addresses matching CIDR patterns";
+    homepage = "http://www.pc-tools.net/unix/grepcidr/";
+    license = licenses.gpl3;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.fadenb ];
+  };
+}

pkgs/applications/search/grepm/default.nix

@@ -0,0 +1,33 @@
+{ lib, stdenv, fetchurl, perlPackages, mutt }:
+
+stdenv.mkDerivation {
+  pname = "grepm";
+  version = "0.6";
+
+  src = fetchurl {
+    url = "http://www.barsnick.net/sw/grepm";
+    sha256 = "0ppprhfw06779hz1b10qvq62gsw73shccsav982dyi6xmqb6jqji";
+  };
+
+  dontUnpack = true;
+
+  buildInputs = [ perlPackages.grepmail mutt ];
+
+  installPhase = ''
+    mkdir -p $out/bin
+    cp -a $src $out/bin/grepm
+    chmod +x $out/bin/grepm
+    sed -i \
+      -e "s:^grepmail:${perlPackages.grepmail}/bin/grepmail:" \
+      -e "s:^\( *\)mutt:\1${mutt}/bin/mutt:" \
+      $out/bin/grepm
+  '';
+
+  meta = with lib; {
+    description = "Wrapper for grepmail utilizing mutt";
+    homepage = "http://www.barsnick.net/sw/grepm.html";
+    license = licenses.free;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.romildo ];
+  };
+}

pkgs/applications/search/recoll/default.nix

@@ -0,0 +1,108 @@
+{ stdenv
+, fetchurl
+, lib
+, mkDerivation
+, antiword
+, bison
+, catdoc
+, chmlib
+, djvulibre
+, file
+, gawk
+, ghostscript
+, gnugrep
+, gnused
+, gnutar
+, groff
+, gzip
+, libiconv
+, libwpd
+, libxslt
+, lyx
+, perl
+, pkg-config
+, poppler_utils
+, python3Packages
+, qtbase
+, unrtf
+, untex
+, unzip
+, which
+, xapian
+, zlib
+, withGui ? true
+}:
+
+mkDerivation rec {
+  pname = "recoll";
+  version = "1.32.0";
+
+  src = fetchurl {
+    url = "https://www.lesbonscomptes.com/${pname}/${pname}-${version}.tar.gz";
+    sha256 = "sha256-4kt6g5MVZTyYLSH7q2z72nzAsU6fatC0vTebEKhSA6E=";
+  };
+
+  configureFlags = [ "--enable-recollq" "--disable-webkit" "--without-systemd" ]
+    ++ lib.optionals (!withGui) [ "--disable-qtgui" "--disable-x11mon" ]
+    ++ (if stdenv.isLinux then [ "--with-inotify" ] else [ "--without-inotify" ]);
+
+  nativeBuildInputs = [
+    file pkg-config python3Packages.setuptools which
+  ];
+
+  buildInputs = [
+    bison chmlib python3Packages.python xapian zlib
+  ] ++ lib.optional withGui qtbase
+    ++ lib.optional stdenv.isDarwin libiconv;
+
+  # the filters search through ${PATH} using a sh proc 'checkcmds' for the
+  # filtering utils. Short circuit this by replacing the filtering command with
+  # the absolute path to the filtering command.
+  postInstall = ''
+    substituteInPlace $out/lib/*/site-packages/recoll/rclconfig.py --replace /usr/share/recoll $out/share/recoll
+    substituteInPlace $out/share/recoll/filters/rclconfig.py       --replace /usr/share/recoll $out/share/recoll
+    for f in $out/share/recoll/filters/* ; do
+      if [[ ! "$f" =~ \.zip$ ]]; then
+        substituteInPlace $f --replace '"antiword"'  '"${lib.getBin antiword}/bin/antiword"'
+        substituteInPlace $f --replace '"awk"'       '"${lib.getBin gawk}/bin/awk"'
+        substituteInPlace $f --replace '"catppt"'    '"${lib.getBin catdoc}/bin/catppt"'
+        substituteInPlace $f --replace '"djvused"'   '"${lib.getBin djvulibre}/bin/djvused"'
+        substituteInPlace $f --replace '"djvutxt"'   '"${lib.getBin djvulibre}/bin/djvutxt"'
+        substituteInPlace $f --replace '"egrep"'     '"${lib.getBin gnugrep}/bin/egrep"'
+        substituteInPlace $f --replace '"groff"'     '"${lib.getBin groff}/bin/groff"'
+        substituteInPlace $f --replace '"gunzip"'    '"${lib.getBin gzip}/bin/gunzip"'
+        substituteInPlace $f --replace '"iconv"'     '"${lib.getBin libiconv}/bin/iconv"'
+        substituteInPlace $f --replace '"pdftotext"' '"${lib.getBin poppler_utils}/bin/pdftotext"'
+        substituteInPlace $f --replace '"pstotext"'  '"${lib.getBin ghostscript}/bin/ps2ascii"'
+        substituteInPlace $f --replace '"sed"'       '"${lib.getBin gnused}/bin/sed"'
+        substituteInPlace $f --replace '"tar"'       '"${lib.getBin gnutar}/bin/tar"'
+        substituteInPlace $f --replace '"unzip"'     '"${lib.getBin unzip}/bin/unzip"'
+        substituteInPlace $f --replace '"xls2csv"'   '"${lib.getBin catdoc}/bin/xls2csv"'
+        substituteInPlace $f --replace '"xsltproc"'  '"${lib.getBin libxslt}/bin/xsltproc"'
+        substituteInPlace $f --replace '"unrtf"'     '"${lib.getBin unrtf}/bin/unrtf"'
+        substituteInPlace $f --replace '"untex"'     '"${lib.getBin untex}/bin/untex"'
+        substituteInPlace $f --replace '"wpd2html"'  '"${lib.getBin libwpd}/bin/wpd2html"'
+        substituteInPlace $f --replace /usr/bin/perl   ${lib.getBin perl}/bin/perl
+      fi
+    done
+  '' + lib.optionalString stdenv.isLinux ''
+    substituteInPlace  $f --replace '"lyx"' '"${lib.getBin lyx}/bin/lyx"'
+  '' + lib.optionalString (stdenv.isDarwin && withGui) ''
+    mkdir $out/Applications
+    mv $out/bin/recoll.app $out/Applications
+  '';
+
+  enableParallelBuilding = true;
+
+  meta = with lib; {
+    description = "A full-text search tool";
+    longDescription = ''
+      Recoll is an Xapian frontend that can search through files, archive
+      members, email attachments.
+    '';
+    homepage = "https://www.lesbonscomptes.com/recoll/";
+    license = licenses.gpl2;
+    platforms = platforms.unix;
+    maintainers = with maintainers; [ jcumming kiyengar ];
+  };
+}

pkgs/applications/search/xlsxgrep/default.nix

@@ -0,0 +1,20 @@
+{ lib, python3Packages }:
+
+python3Packages.buildPythonApplication rec {
+  pname = "xlsxgrep";
+  version = "0.0.23";
+
+  src = python3Packages.fetchPypi {
+    inherit pname version;
+    sha256 = "014i1nifx67mxi0k9sch00j6bjykb6krzl2q3ara9s1g75inl4rm";
+  };
+
+  pythonPath = with python3Packages; [ xlrd ];
+
+  meta = with lib; {
+    maintainers = with maintainers; [ felixscheinost ];
+    description = "CLI tool to search text in XLSX and XLS files. It works similarly to Unix/GNU Linux grep";
+    homepage = "https://github.com/zazuum/xlsxgrep";
+    license = licenses.mit;
+  };
+}