uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/virtualization/runc/default.nix

@@ -0,0 +1,63 @@
+{ lib
+, fetchFromGitHub
+, buildGoModule
+, go-md2man
+, installShellFiles
+, pkg-config
+, which
+, libapparmor
+, apparmor-parser
+, libseccomp
+, libselinux
+, makeWrapper
+, procps
+, nixosTests
+}:
+
+buildGoModule rec {
+  pname = "runc";
+  version = "1.1.2";
+
+  src = fetchFromGitHub {
+    owner = "opencontainers";
+    repo = "runc";
+    rev = "v${version}";
+    sha256 = "sha256-tMneqB81w8lQp5RWWCjALyKbOY3xog+oqb6cYKasG/8=";
+  };
+
+  vendorSha256 = null;
+  outputs = [ "out" "man" ];
+
+  nativeBuildInputs = [ go-md2man installShellFiles makeWrapper pkg-config which ];
+
+  buildInputs = [ libselinux libseccomp libapparmor ];
+
+  makeFlags = [ "BUILDTAGS+=seccomp" ];
+
+  buildPhase = ''
+    runHook preBuild
+    patchShebangs .
+    make ${toString makeFlags} runc man
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 runc $out/bin/runc
+    installManPage man/*/*.[1-9]
+    wrapProgram $out/bin/runc \
+      --prefix PATH : ${lib.makeBinPath [ procps ]} \
+      --prefix PATH : /run/current-system/systemd/bin
+    runHook postInstall
+  '';
+
+  passthru.tests = { inherit (nixosTests) cri-o docker podman; };
+
+  meta = with lib; {
+    homepage = "https://github.com/opencontainers/runc";
+    description = "A CLI tool for spawning and running containers according to the OCI specification";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ offline ] ++ teams.podman.members;
+    platforms = platforms.linux;
+  };
+}