uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/window-managers/cage/default.nix

@@ -0,0 +1,44 @@
+{ lib, stdenv, fetchFromGitHub
+, meson, ninja, pkg-config, wayland-scanner, scdoc, makeWrapper
+, wlroots, wayland, wayland-protocols, pixman, libxkbcommon
+, systemd, libGL, libX11, mesa
+, xwayland ? null
+, nixosTests
+}:
+
+stdenv.mkDerivation rec {
+  pname = "cage";
+  version = "0.1.4";
+
+  src = fetchFromGitHub {
+    owner = "Hjdskes";
+    repo = "cage";
+    rev = "v${version}";
+    sha256 = "0vm96gxinhy48m3x9p1sfldyd03w3gk6iflb7n9kn06j1vqyswr6";
+  };
+
+  nativeBuildInputs = [ meson ninja pkg-config wayland-scanner scdoc makeWrapper ];
+
+  buildInputs = [
+    wlroots wayland wayland-protocols pixman libxkbcommon
+    mesa # for libEGL headers
+    systemd libGL libX11
+  ];
+
+  mesonFlags = [ "-Dxwayland=${lib.boolToString (xwayland != null)}" ];
+
+  postFixup = lib.optionalString (xwayland != null) ''
+    wrapProgram $out/bin/cage --prefix PATH : "${xwayland}/bin"
+  '';
+
+  # Tests Cage using the NixOS module by launching xterm:
+  passthru.tests.basic-nixos-module-functionality = nixosTests.cage;
+
+  meta = with lib; {
+    description = "A Wayland kiosk that runs a single, maximized application";
+    homepage    = "https://www.hjdskes.nl/projects/cage/";
+    license     = licenses.mit;
+    platforms   = platforms.linux;
+    maintainers = with maintainers; [ primeos ];
+  };
+}