uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/applications/window-managers/dwm/default.nix

@@ -0,0 +1,48 @@
+{ lib, stdenv, fetchurl, libX11, libXinerama, libXft, writeText, patches ? [ ], conf ? null}:
+
+stdenv.mkDerivation rec {
+  pname = "dwm";
+  version = "6.3";
+
+  src = fetchurl {
+    url = "https://dl.suckless.org/dwm/${pname}-${version}.tar.gz";
+    sha256 = "utqgKFKbH7of1/moTztk8xGQRmyFgBG1Pi97cMajB40=";
+  };
+
+  buildInputs = [ libX11 libXinerama libXft ];
+
+  prePatch = ''
+    sed -i "s@/usr/local@$out@" config.mk
+  '';
+
+  # Allow users set their own list of patches
+  inherit patches;
+
+  # Allow users to set the config.def.h file containing the configuration
+  postPatch =
+    let
+      configFile =
+        if lib.isDerivation conf || builtins.isPath conf
+        then conf else writeText "config.def.h" conf;
+    in
+    lib.optionalString (conf != null) "cp ${configFile} config.def.h";
+
+  makeFlags = [ "CC=${stdenv.cc.targetPrefix}cc" ];
+
+  meta = with lib; {
+    homepage = "https://dwm.suckless.org/";
+    description = "An extremely fast, small, and dynamic window manager for X";
+    longDescription = ''
+      dwm is a dynamic window manager for X. It manages windows in tiled,
+      monocle and floating layouts. All of the layouts can be applied
+      dynamically, optimising the environment for the application in use and the
+      task performed.
+      Windows are grouped by tags. Each window can be tagged with one or
+      multiple tags. Selecting certain tags displays all windows with these
+      tags.
+    '';
+    license = licenses.mit;
+    maintainers = with maintainers; [ viric neonfuz ];
+    platforms = platforms.all;
+  };
+}

pkgs/applications/window-managers/dwm/dwm-status.nix

@@ -0,0 +1,38 @@
+{ lib, rustPlatform, fetchFromGitHub, dbus, gdk-pixbuf, libnotify, makeWrapper, pkg-config, xorg
+, enableAlsaUtils ? true, alsa-utils, coreutils
+, enableNetwork ? true, dnsutils, iproute2, wirelesstools }:
+
+let
+  bins = lib.optionals enableAlsaUtils [ alsa-utils coreutils ]
+    ++ lib.optionals enableNetwork [ dnsutils iproute2 wirelesstools ];
+in
+
+rustPlatform.buildRustPackage rec {
+  pname = "dwm-status";
+  version = "1.7.3";
+
+  src = fetchFromGitHub {
+    owner = "Gerschtli";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-dkVo9NpGt3G6by9Of1kOlXaZn7xsVSvfNXq7KPO6HE4=";
+  };
+
+  nativeBuildInputs = [ makeWrapper pkg-config ];
+  buildInputs = [ dbus gdk-pixbuf libnotify xorg.libX11 ];
+
+  cargoSha256 = "sha256-QPnr7dUsq/RzuNLpbTRQbGB3zU6lNuPPPM9FmH4ydzY=";
+
+  postInstall = lib.optionalString (bins != [])  ''
+    wrapProgram $out/bin/dwm-status --prefix "PATH" : "${lib.makeBinPath bins}"
+  '';
+
+  meta = with lib; {
+    description = "Highly performant and configurable DWM status service";
+    homepage = "https://github.com/Gerschtli/dwm-status";
+    license = with licenses; [ mit ];
+    maintainers = with maintainers; [ gerschtli ];
+    mainProgram = pname;
+    platforms = platforms.linux;
+  };
+}