uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/applications/window-managers/jwm/default.nix
+++ b/pkgs/applications/window-managers/jwm/default.nix
@ -0,0 +1,84 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, autoconf
+, automake
+, expat
+, fontconfig
+, freetype
+, gettext
+, libX11
+, libXau
+, libXdmcp
+, libXext
+, libXft
+, libXinerama
+, libXmu
+, libXpm
+, libjpeg
+, libpng
+, librsvg
+, pango
+, pkg-config
+, which
+, xorg
+, xorgproto
+, gitUpdater
+}:
+
+stdenv.mkDerivation rec {
+  pname = "jwm";
+  version = "2.4.2";
+
+  src = fetchFromGitHub {
+    owner = "joewing";
+    repo = "jwm";
+    rev = "v${version}";
+    sha256 = "sha256-rvuz2Pmon3XBqRMgDwZNrQlWDyLNSK30JPmmQTlN+Rs=";
+  };
+
+  nativeBuildInputs = [
+    autoconf
+    automake
+    gettext
+    pkg-config
+    which
+  ];
+
+  buildInputs = [
+    expat
+    fontconfig
+    freetype
+    libX11
+    libXau
+    libXdmcp
+    libXext
+    libXft
+    libXinerama
+    libXmu
+    libXpm
+    libjpeg
+    libpng
+    librsvg
+    pango
+    xorg.libXrender
+    xorgproto
+  ];
+
+  preConfigure = "NOCONFIGURE=1 ./autogen.sh";
+
+  enableParallelBuilding = true;
+
+  passthru.updateScript = gitUpdater {
+    inherit pname version;
+    rev-prefix = "v";
+  };
+
+  meta = {
+    homepage = "http://joewing.net/projects/jwm/";
+    description = "Joe's Window Manager is a light-weight X11 window manager";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+    maintainers = [ lib.maintainers.romildo ];
+  };
+}
--- a/pkgs/applications/window-managers/jwm/jwm-settings-manager.nix
+++ b/pkgs/applications/window-managers/jwm/jwm-settings-manager.nix
@ -0,0 +1,48 @@
+{ lib, stdenv, fetchbzr, cmake, pkg-config, gettext, libXpm, libGL, fltk, hicolor-icon-theme, glib, gnome2, which }:
+
+stdenv.mkDerivation rec {
+  pname = "jwm-settings-manager";
+  version = "2019-01-27";
+
+  src = fetchbzr {
+    url = "lp:${pname}";
+    rev = "292";
+    sha256 = "1yqc1ac2pbkc88z7p1qags1jygdlr5y1rhc5mx6gapcf54bk0lmi";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    gettext
+  ];
+
+  buildInputs = [
+    libXpm
+    libGL
+    fltk
+    hicolor-icon-theme
+    which # needed at runtime to locate optional programs
+    glib.bin # provides gsettings
+    gnome2.GConf # provides gconftool-2
+  ];
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace 'CMAKE_INSTALL_PREFIX "/usr"' "CMAKE_INSTALL_PREFIX $out"
+    substituteInPlace data/CMakeLists.txt \
+      --replace 'DESTINATION usr/share' "DESTINATION share"
+  '';
+
+  postConfigure = ''
+    substituteInPlace cmake_install.cmake \
+      --replace "/var/empty" "/usr"
+  '';
+
+  meta = with lib; {
+    description = "A full configuration manager for JWM";
+    homepage = "https://joewing.net/projects/jwm";
+    license = licenses.gpl3;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.romildo ];
+  };
+}