uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/build-support/ocaml/default.nix

@@ -0,0 +1,36 @@
+{ lib, stdenv, writeText, ocaml, findlib, ocamlbuild, camlp4 }:
+
+{ pname ? args.name, version, nativeBuildInputs ? [],
+  createFindlibDestdir ?  true,
+  dontStrip ? true,
+  minimumSupportedOcamlVersion ? null,
+  hasSharedObjects ? false,
+  setupHook ? null,
+  meta ? {}, ...
+}@args:
+let
+  defaultMeta = {
+    platforms = ocaml.meta.platforms or [];
+  };
+in
+  assert minimumSupportedOcamlVersion != null ->
+          lib.versionOlder minimumSupportedOcamlVersion ocaml.version;
+
+stdenv.mkDerivation (args // {
+  name = "ocaml-${pname}-${version}";
+
+  nativeBuildInputs = [ ocaml findlib ocamlbuild camlp4 ] ++ nativeBuildInputs;
+
+  strictDeps = true;
+
+  setupHook = if setupHook == null && hasSharedObjects
+  then writeText "setupHook.sh" ''
+    export CAML_LD_LIBRARY_PATH="''${CAML_LD_LIBRARY_PATH-}''${CAML_LD_LIBRARY_PATH:+:}''$1/lib/ocaml/${ocaml.version}/site-lib/${pname}/"
+    ''
+  else setupHook;
+
+  inherit createFindlibDestdir;
+  inherit dontStrip;
+
+  meta = defaultMeta // meta;
+})

pkgs/build-support/ocaml/dune.nix

@@ -0,0 +1,45 @@
+{ lib, stdenv, ocaml, findlib, dune_1, dune_2, dune_3 }:
+
+{ pname, version, nativeBuildInputs ? [], enableParallelBuilding ? true, ... }@args:
+
+let Dune =
+  let dune-version = args . duneVersion or (if args.useDune2 or true then "2" else "1"); in
+  { "1" = dune_1; "2" = dune_2; "3" = dune_3; }."${dune-version}"
+; in
+
+if (args ? minimumOCamlVersion && lib.versionOlder ocaml.version args.minimumOCamlVersion) ||
+   (args ? minimalOCamlVersion && lib.versionOlder ocaml.version args.minimalOCamlVersion)
+then throw "${pname}-${version} is not available for OCaml ${ocaml.version}"
+else
+
+stdenv.mkDerivation ({
+
+  inherit enableParallelBuilding;
+  dontAddStaticConfigureFlags = true;
+  configurePlatforms = [];
+
+  buildPhase = ''
+    runHook preBuild
+    dune build -p ${pname} ''${enableParallelBuilding:+-j $NIX_BUILD_CORES}
+    runHook postBuild
+  '';
+  checkPhase = ''
+    runHook preCheck
+    dune runtest -p ${pname} ''${enableParallelBuilding:+-j $NIX_BUILD_CORES}
+    runHook postCheck
+  '';
+  installPhase = ''
+    runHook preInstall
+    dune install --prefix $out --libdir $OCAMLFIND_DESTDIR ${pname}
+    runHook postInstall
+  '';
+
+} // (builtins.removeAttrs args [ "minimalOCamlVersion" "duneVersion" ]) // {
+
+  name = "ocaml${ocaml.version}-${pname}-${version}";
+
+  nativeBuildInputs = [ ocaml Dune findlib ] ++ nativeBuildInputs;
+
+  meta = (args.meta or {}) // { platforms = args.meta.platforms or ocaml.meta.platforms; };
+
+})

pkgs/build-support/ocaml/oasis.nix

@@ -0,0 +1,46 @@
+{ lib, stdenv, ocaml_oasis, ocaml, findlib, ocamlbuild }:
+
+{ pname, version, nativeBuildInputs ? [], meta ? { platforms = ocaml.meta.platforms or []; },
+  minimumOCamlVersion ? null,
+  createFindlibDestdir ? true,
+  dontStrip ? true,
+  ...
+}@args:
+
+if args ? minimumOCamlVersion &&
+   lib.versionOlder ocaml.version args.minimumOCamlVersion
+then throw "${pname}-${version} is not available for OCaml ${ocaml.version}"
+else
+
+stdenv.mkDerivation (args // {
+  name = "ocaml${ocaml.version}-${pname}-${version}";
+
+  nativeBuildInputs = [ ocaml findlib ocamlbuild ocaml_oasis ] ++ nativeBuildInputs;
+
+  inherit createFindlibDestdir;
+  inherit dontStrip;
+
+  strictDeps = true;
+
+  buildPhase = ''
+    runHook preBuild
+    oasis setup
+    ocaml setup.ml -configure --prefix $OCAMLFIND_DESTDIR --exec-prefix $out
+    ocaml setup.ml -build
+    runHook postBuild
+  '';
+
+  checkPhase = ''
+    runHook preCheck
+    ocaml setup.ml -test
+    runHook postCheck
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out
+    ocaml setup.ml -install
+    runHook postInstall
+  '';
+
+})