uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/data/documentation/anarchism/default.nix

@@ -0,0 +1,43 @@
+{ lib, stdenv, fetchFromGitLab, xdg-utils }:
+
+stdenv.mkDerivation rec {
+  pname = "anarchism";
+  version = "15.3-1";
+
+  src = fetchFromGitLab {
+    domain = "salsa.debian.org";
+    owner = "debian";
+    repo = pname;
+    rev = "debian/${version}";
+    sha256 = "04ylk0y5b3jml2awmyz7m1hnymni8y1n83m0k6ychdh0px8frhm5";
+  };
+
+  postPatch = ''
+    substituteInPlace debian/anarchism.desktop \
+      --replace "/usr/bin/xdg-open" "${xdg-utils}/bin/xdg-open"
+    substituteInPlace debian/anarchism.desktop \
+      --replace "file:///usr" "file://$out"
+  '';
+
+  installPhase = ''
+    mkdir -p $out/share/doc/anarchism $out/share/applications $out/share/icons/hicolor/scalable/apps
+    cp -r {html,markdown} $out/share/doc/anarchism
+    cp debian/anarchism.svg $out/share/icons/hicolor/scalable/apps
+    cp debian/anarchism.desktop $out/share/applications
+  '';
+
+  meta = with lib; {
+    homepage = "http://www.anarchistfaq.org/";
+    changelog = "http://anarchism.pageabode.com/afaq/new.html";
+    description = "Exhaustive exploration of Anarchist theory and practice";
+    longDescription = ''
+      The Anarchist FAQ is an excellent source of information regarding Anarchist
+      (libertarian socialist) theory and practice. It covers all major topics,
+      from the basics of Anarchism to very specific discussions of politics,
+      social organization, and economics.
+    '';
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ davidak ];
+    platforms = with platforms; all;
+  };
+}

pkgs/data/documentation/bgnet/default.nix

@@ -0,0 +1,35 @@
+{ stdenv, lib, fetchFromGitHub, python3, pandoc }:
+
+stdenv.mkDerivation {
+  pname = "bgnet";
+  # to be found in the Makefile
+  version = "3.1.2";
+
+  src = fetchFromGitHub {
+    owner = "beejjorgensen";
+    repo = "bgnet";
+    rev = "782a785a35d43c355951b8151628d7c64e4d0346";
+    sha256 = "19w0r3zr71ydd29amqwn8q3npgrpy5kkshyshyji2hw5hky6iy92";
+  };
+
+  buildPhase = ''
+    # build scripts need some love
+    patchShebangs bin/preproc
+
+    make -C src bgnet.html
+  '';
+
+  installPhase = ''
+    install -Dm644 src/bgnet.html $out/share/doc/bgnet/html/index.html
+  '';
+
+  nativeBuildInputs = [ python3 pandoc ];
+
+  meta = {
+    description = "Beej’s Guide to Network Programming";
+    homepage = "https://beej.us/guide/bgnet/";
+    license = lib.licenses.unfree;
+
+    maintainers = with lib.maintainers; [ Profpatsch ];
+  };
+}

pkgs/data/documentation/execline-man-pages/default.nix

@@ -0,0 +1,9 @@
+{ lib, buildManPages }:
+
+buildManPages {
+  pname = "execline-man-pages";
+  version = "2.8.1.0.4";
+  sha256 = "1cxi09dlzvjbilmzgmr3xvwvx0l3s1874k3gr85kbjnvp1c1r6cd";
+  description = "Port of the documentation for the execline suite to mdoc";
+  maintainers = [ lib.maintainers.sternenseemann ];
+}

pkgs/data/documentation/gnome-user-docs/default.nix

@@ -0,0 +1,41 @@
+{ lib, stdenv
+, fetchurl
+, gettext
+, gnome
+, itstool
+, libxml2
+, yelp-tools
+}:
+
+stdenv.mkDerivation rec {
+  pname = "gnome-user-docs";
+  version = "42.0";
+
+  src = fetchurl {
+    url = "mirror://gnome/sources/gnome-user-docs/${lib.versions.major version}/${pname}-${version}.tar.xz";
+    sha256 = "srJ9oEEAu90vTw5bw48tBW2V+jZWcgFj9kNqMWfV6QU=";
+  };
+
+  nativeBuildInputs = [
+    gettext
+    itstool
+    libxml2
+    yelp-tools
+  ];
+
+  enableParallelBuilding = true;
+
+  passthru = {
+    updateScript = gnome.updateScript {
+      packageName = pname;
+    };
+  };
+
+  meta = with lib; {
+    description = "User and system administration help for the GNOME desktop";
+    homepage = "https://help.gnome.org/users/gnome-help/";
+    license = licenses.cc-by-30;
+    maintainers = teams.gnome.members;
+    platforms = platforms.all;
+  };
+}

pkgs/data/documentation/linux-manual/default.nix

@@ -0,0 +1,40 @@
+{ lib, stdenv, fetchurl, perl, linuxPackages_latest }:
+
+stdenv.mkDerivation rec {
+  pname = "linux-manual";
+  inherit (linuxPackages_latest.kernel) version src;
+
+  nativeBuildInputs = [ perl ];
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  postPatch = ''
+    patchShebangs --build \
+      scripts/kernel-doc \
+      scripts/split-man.pl
+  '';
+
+  installPhase = ''
+    mandir=$out/share/man/man9
+    mkdir -p $mandir
+
+    KBUILD_BUILD_TIMESTAMP=$(stat -c %Y Makefile) \
+    grep -F -l -Z \
+      --exclude-dir Documentation \
+      --exclude-dir tools \
+      -R '/**' \
+      | xargs -0 -n 256 -P $NIX_BUILD_CORES \
+        $SHELL -c '{ scripts/kernel-doc -man "$@" || :; } \
+          | scripts/split-man.pl '$mandir kernel-doc
+
+    test -f $mandir/kmalloc.9
+  '';
+
+  meta = with lib; {
+    homepage = "https://kernel.org/";
+    description = "Linux kernel API manual pages";
+    license = licenses.gpl2Only;
+    maintainers = with maintainers; [ mvs ];
+  };
+}

pkgs/data/documentation/man-pages-posix/default.nix

@@ -0,0 +1,27 @@
+{lib, stdenv, fetchurl}:
+
+let
+  year = "2017";
+  minor = "a";
+in
+
+stdenv.mkDerivation rec {
+  pname = "man-pages-posix";
+  version = "${year}${minor}";
+
+  src = fetchurl {
+    url = "mirror://kernel/linux/docs/man-pages/man-pages-posix/${pname}-${year}-${minor}.tar.xz";
+    sha256 = "ce67bb25b5048b20dad772e405a83f4bc70faf051afa289361c81f9660318bc3";
+  };
+
+  makeFlags = [
+    "MANDIR=${placeholder "out"}/share/man"
+  ];
+
+  meta = {
+    description = "POSIX man-pages (0p, 1p, 3p)";
+    homepage = "https://www.kernel.org/doc/man-pages/";
+    platforms = lib.platforms.unix;
+    maintainers = [ lib.maintainers.sternenseemann ];
+  };
+}

pkgs/data/documentation/man-pages/default.nix

@@ -0,0 +1,31 @@
+{ lib, stdenv, fetchurl }:
+
+stdenv.mkDerivation rec {
+  pname = "man-pages";
+  version = "5.13";
+
+  src = fetchurl {
+    url = "mirror://kernel/linux/docs/man-pages/${pname}-${version}.tar.xz";
+    sha256 = "sha256-YU2uPv59/UgJhnY6KiqBeSFQMqWkUmwL5eiZol8Ja4s=";
+  };
+
+  makeFlags = [ "prefix=$(out)" ];
+  postInstall = ''
+    # conflict with shadow-utils
+    rm $out/share/man/man5/passwd.5 \
+       $out/share/man/man3/getspnam.3
+
+    # The manpath executable looks up manpages from PATH. And this package won't
+    # appear in PATH unless it has a /bin folder
+    mkdir -p $out/bin
+  '';
+  outputDocdev = "out";
+
+  meta = with lib; {
+    description = "Linux development manual pages";
+    homepage = "https://www.kernel.org/doc/man-pages/";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    priority = 30; # if a package comes with its own man page, prefer it
+  };
+}

pkgs/data/documentation/mustache-spec/default.nix

@@ -0,0 +1,42 @@
+{ stdenv, lib, fetchFromGitHub }:
+
+stdenv.mkDerivation rec {
+  pname = "mustache-spec";
+  version = "1.0.2";
+
+  src = fetchFromGitHub {
+    owner = "mustache";
+    repo = "mustache";
+    rev = "v${version}";
+    sha256 = "03xrfyjzm5ss6zkdlpl9ypwzcglspcdcnr3f94vj1rjfqm2rxcjw";
+  };
+
+  configurePhase = "";
+  dontBuild = true;
+
+  installPhase = ''
+    mkdir -p $out/{man/man5,doc/html}
+    cp man/mustache.5 $out/man/man5
+    cp man/mustache.5.html $out/doc/html
+  '';
+
+  meta = rec {
+    description = "Logic-less templates, specification package";
+    longDescription = ''
+      Inspired by ctemplate and et, Mustache is a framework-agnostic way to
+      render logic-free views.
+
+      Provides the specification as man page and html docs.
+
+      As ctemplates says, "It emphasizes separating logic from presentation: it
+      is impossible to embed application logic in this template language."
+
+      For a list of implementations and tips, see ${homepage}.
+    '';
+
+    homepage = "http://mustache.github.io/";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ Profpatsch ];
+    platforms = lib.platforms.all;
+  };
+}

pkgs/data/documentation/nginx-doc/default.nix

@@ -0,0 +1,40 @@
+{ lib, stdenv, libxml2, libxslt, fetchhg }:
+
+# Upstream maintains documentation (sources of https://nginx.org) in separate
+# mercurial repository, which do not correspond to particular git commit, but at
+# least has "introduced in version X.Y" comments.
+#
+# In other words, documentation does not necessary matches capabilities of
+# $out/bin/nginx, but we have no better options.
+stdenv.mkDerivation {
+  pname = "nginx-doc-unstable";
+  version = "2022-05-05";
+  src = fetchhg {
+    url = "https://hg.nginx.org/nginx.org";
+    rev = "a3aee2697d4e";
+    sha256 = "029n4mnmjw94h01qalmjgf1c2h3h7wm798xv5knk3padxiy4m28b";
+  };
+  patches = [ ./exclude-google-analytics.patch ];
+  nativeBuildInputs = [ libxslt libxml2 ];
+
+  # Generated documentation is not local-friendly, since it assumes that link to directory
+  # is the same as link to index.html in that directory, which is not how browsers behave
+  # with local filesystem.
+  #
+  # TODO: patch all relative links that do not end with .html.
+
+  # /en subdirectory must exist, relative links expect it.
+  installPhase = ''
+    mkdir -p $out/share/doc/nginx
+    mv libxslt/en $out/share/doc/nginx
+  '';
+
+  meta = with lib; {
+    description = "A reverse proxy and lightweight webserver (documentation)";
+    homepage    = "https://nginx.org/";
+    license     = licenses.bsd2;
+    platforms   = platforms.all;
+    priority    = 6;
+    maintainers = with maintainers; [ kaction ];
+  };
+}

pkgs/data/documentation/nginx-doc/exclude-google-analytics.patch

@@ -0,0 +1,29 @@
+Kill google analytics from local documentation.
+
+diff -r bb0a2fbdc886 xslt/ga.xslt
+--- a/xslt/ga.xslt	Mon Apr 06 11:17:11 2020 +0100
++++ b/xslt/ga.xslt	Thu Apr 09 10:29:02 2020 -0400
+@@ -6,23 +6,6 @@
+ <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
+ 
+ <xsl:template name="ga">
+-
+-    <script>
+-        (function(w, d, s, l, i) {
+-            w[l] = w[l] || [];
+-            w[l].push({
+-                'gtm.start': new Date().getTime(),
+-                event: 'gtm.js'
+-            });
+-            var f = d.getElementsByTagName(s)[0],
+-                j = d.createElement(s),
+-                dl = l != 'dataLayer' ? '&amp;l=' + l : '';
+-            j.async = true;
+-            j.src = '//www.googletagmanager.com/gtm.js?id=' + i + dl;
+-            f.parentNode.insertBefore(j, f);
+-        })(window, document, 'script', 'dataLayer', 'GTM-TPSP33');
+-    </script>
+-
+ </xsl:template>
+ 
+ </xsl:stylesheet>

pkgs/data/documentation/s6-man-pages/default.nix

@@ -0,0 +1,9 @@
+{ lib, buildManPages }:
+
+buildManPages {
+  pname = "s6-man-pages";
+  version = "2.11.0.1.1";
+  sha256 = "03gl0vvdaqfb5hs0dfdbs9djxiyq3abcx9vwgkfw22b1rm2fa0r6";
+  description = "Port of the documentation for the s6 supervision suite to mdoc";
+  maintainers = [ lib.maintainers.sternenseemann ];
+}

pkgs/data/documentation/s6-networking-man-pages/default.nix

@@ -0,0 +1,9 @@
+{ lib, buildManPages }:
+
+buildManPages {
+  pname = "s6-networking-man-pages";
+  version = "2.5.1.0.1";
+  sha256 = "1h87s3wixsms8ys7gvm1s9d8pzn73q5j4sgybpi3gmr55d4cwra4";
+  description = "Port of the documentation for the s6-networking suite to mdoc";
+  maintainers = [ lib.maintainers.sternenseemann ];
+}

pkgs/data/documentation/scheme-manpages/default.nix

@@ -0,0 +1,28 @@
+{ lib, stdenv, fetchFromGitHub }:
+
+stdenv.mkDerivation rec {
+  pname = "scheme-manpages-unstable";
+  version = "2022-04-21";
+
+  src = fetchFromGitHub {
+    owner = "schemedoc";
+    repo = "manpages";
+    rev = "e3faaa1b80b3493ee644958a105f84f2995a0436";
+    sha256 = "sha256-28e6tFRTqX/PWMhdoUZ4nQU1e/JL2uR+NjVXGBwogMM=";
+  };
+
+  dontBuild = true;
+
+  installPhase = ''
+    mkdir -p $out/share/man
+    cp -r man3/ man7/ $out/share/man/
+  '';
+
+  meta = with lib; {
+    description = "Unix manual pages for R6RS and R7RS";
+    homepage = "https://github.com/schemedoc/manpages";
+    license = licenses.mit;
+    maintainers = [ maintainers.marsam ];
+    platforms = platforms.all;
+  };
+}

pkgs/data/documentation/std-man-pages/default.nix

@@ -0,0 +1,25 @@
+{ stdenv, lib, fetchurl }:
+
+stdenv.mkDerivation rec {
+  pname = "std-man-pages";
+  version = "4.4.0";
+
+  src = fetchurl {
+    url = "mirror://gcc/libstdc++/doxygen/libstdc++-man.${version}.tar.bz2";
+    sha256 = "0153py77ll759jacq41dp2z2ksr08pdcfic0rwjd6pr84dk89y9v";
+  };
+
+  outputDevdoc = "out";
+
+  installPhase = ''
+    mkdir -p $out/share/man
+    cp -R * $out/share/man
+  '';
+
+  meta = with lib; {
+    description = "GCC C++ STD manual pages";
+    homepage = "https://gcc.gnu.org/";
+    license = with licenses; [ fdl12Plus ];
+    platforms = platforms.unix;
+  };
+}

pkgs/data/documentation/stdman/default.nix

@@ -0,0 +1,34 @@
+{ lib, stdenv, curl, fetchFromGitHub }:
+
+stdenv.mkDerivation rec {
+  pname = "stdman";
+  version = "2021.12.21";
+
+  src = fetchFromGitHub {
+    owner = "jeaye";
+    repo = "stdman";
+    rev = version;
+    sha256 = "sha256-wOMQzC5w8aDmxNxQ5HK8jMgoow1wXBfHGUwFBw2WiPA=";
+  };
+
+  outputDevdoc = "out";
+
+  preConfigure = "
+    patchShebangs ./configure
+    patchShebangs ./do_install
+  ";
+
+  buildInputs = [ curl ];
+
+  meta = with lib; {
+    description = "Formatted C++17 stdlib man pages (cppreference)";
+    longDescription = "stdman is a tool that parses archived HTML
+      files from cppreference and generates groff-formatted manual
+      pages for Unix-based systems. The goal is to provide excellent
+      formatting for easy readability.";
+    homepage = "https://github.com/jeaye/stdman";
+    license = licenses.mit;
+    platforms = platforms.unix;
+    maintainers = [ maintainers.twey ];
+  };
+}

pkgs/data/documentation/zeal/default.nix

@@ -0,0 +1,44 @@
+{ lib, fetchFromGitHub, cmake, extra-cmake-modules, pkg-config
+, qtbase, qtimageformats, qtwebengine, qtx11extras, mkDerivation
+, libarchive, libXdmcp, libpthreadstubs, xcbutilkeysyms  }:
+
+mkDerivation rec {
+  pname = "zeal";
+  version = "0.6.999";
+
+  src = fetchFromGitHub {
+    owner = "zealdocs";
+    repo = "zeal";
+    rev = "763edca12ccd6c67e51f10891d1ced8b2510904f";
+    sha256 = "sha256-1/wQXkRWvpRia8UDvvvmzHinPG8q2Tz9Uoeegej9uC8=";
+  };
+
+  # we only need this if we are using a version that hasn't been released. We
+  # could also match on the "VERSION x.y.z" bit but then it would have to be
+  # updated based on whatever is the latest release, so instead just rewrite the
+  # line.
+  postPatch = ''
+    sed -i CMakeLists.txt \
+      -e 's@^project.*@project(Zeal VERSION ${version})@'
+  '';
+
+  nativeBuildInputs = [ cmake extra-cmake-modules pkg-config ];
+
+  buildInputs = [
+    qtbase qtimageformats qtwebengine qtx11extras
+    libarchive
+    libXdmcp libpthreadstubs xcbutilkeysyms
+  ];
+
+  meta = with lib; {
+    description = "A simple offline API documentation browser";
+    longDescription = ''
+      Zeal is a simple offline API documentation browser inspired by Dash (macOS
+      app), available for Linux and Windows.
+    '';
+    homepage = "https://zealdocs.org/";
+    license = licenses.gpl3;
+    maintainers = with maintainers; [ skeidel peterhoeg ];
+    platforms = platforms.linux;
+  };
+}