uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/desktops/lxqt/compton-conf/default.nix

@@ -0,0 +1,51 @@
+{ stdenv
+, lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, qtbase
+, qttools
+, lxqt
+, libconfig
+}:
+
+mkDerivation rec {
+  pname = "compton-conf";
+  version = "0.16.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "0gcvyn7aabdz5yj0jzv14hlgjgbm8d9ib5r73i842f0hv4cv9m0q";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt.lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    libconfig
+  ];
+
+  preConfigure = ''
+    substituteInPlace autostart/CMakeLists.txt \
+      --replace "DESTINATION \"\''${LXQT_ETC_XDG_DIR}" "DESTINATION \"etc/xdg" \
+  '';
+
+  passthru.updateScript = lxqt.lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    broken = stdenv.isDarwin;
+    homepage = "https://github.com/lxqt/compton-conf";
+    description = "GUI configuration tool for compton X composite manager";
+    license = licenses.lgpl21Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/default.nix

@@ -0,0 +1,114 @@
+{ pkgs, makeScope, libsForQt5, qt5 }:
+let
+  packages = self: with self; {
+
+    # Update script tailored to LXQt packages from git repository
+    lxqtUpdateScript = { pname, version, src }:
+      pkgs.gitUpdater {
+        inherit pname version;
+        attrPath = "lxqt.${pname}";
+      };
+
+    # For compiling information, see:
+    # - https://github.com/lxqt/lxqt/wiki/Building-from-source
+
+    ### BASE
+    libqtxdg = callPackage ./libqtxdg {};
+    lxqt-build-tools = callPackage ./lxqt-build-tools {};
+    libsysstat = callPackage ./libsysstat {};
+    liblxqt = callPackage ./liblxqt {};
+    qtxdg-tools = callPackage ./qtxdg-tools {};
+
+    ### CORE 1
+    libfm-qt = callPackage ./libfm-qt {};
+    lxqt-about = callPackage ./lxqt-about {};
+    lxqt-admin = callPackage ./lxqt-admin {};
+    lxqt-config = callPackage ./lxqt-config {};
+    lxqt-globalkeys = callPackage ./lxqt-globalkeys {};
+    lxqt-notificationd = callPackage ./lxqt-notificationd {};
+    lxqt-openssh-askpass = callPackage ./lxqt-openssh-askpass {};
+    lxqt-policykit = callPackage ./lxqt-policykit {};
+    lxqt-powermanagement = callPackage ./lxqt-powermanagement {};
+    lxqt-qtplugin = callPackage ./lxqt-qtplugin {};
+    lxqt-session = callPackage ./lxqt-session {};
+    lxqt-sudo = callPackage ./lxqt-sudo {};
+    lxqt-themes = callPackage ./lxqt-themes {};
+    pavucontrol-qt = libsForQt5.callPackage ./pavucontrol-qt {};
+    qtermwidget = callPackage ./qtermwidget {};
+
+    ### CORE 2
+    lxqt-panel = callPackage ./lxqt-panel {};
+    lxqt-runner = callPackage ./lxqt-runner {};
+    pcmanfm-qt = callPackage ./pcmanfm-qt {};
+
+    ### OPTIONAL
+    qterminal = callPackage ./qterminal {};
+    compton-conf = qt5.callPackage ./compton-conf {};
+    obconf-qt = callPackage ./obconf-qt {};
+    lximage-qt = callPackage ./lximage-qt {};
+    qps = callPackage ./qps {};
+    screengrab = callPackage ./screengrab {};
+    qlipper = callPackage ./qlipper {};
+    lxqt-archiver = callPackage ./lxqt-archiver {};
+    xdg-desktop-portal-lxqt = callPackage ./xdg-desktop-portal-lxqt {};
+
+    preRequisitePackages = [
+      libsForQt5.kwindowsystem # provides some QT5 plugins needed by lxqt-panel
+      libsForQt5.libkscreen # provides plugins for screen management software
+      pkgs.libfm
+      pkgs.libfm-extra
+      pkgs.lxmenu-data
+      pkgs.menu-cache
+      pkgs.openbox # default window manager
+      qt5.qtsvg # provides QT5 plugins for svg icons
+    ];
+
+    corePackages = [
+      ### BASE
+      libqtxdg
+      libsysstat
+      liblxqt
+
+      ### CORE 1
+      libfm-qt
+      lxqt-about
+      lxqt-admin
+      lxqt-config
+      lxqt-globalkeys
+      lxqt-notificationd
+      lxqt-openssh-askpass
+      lxqt-policykit
+      lxqt-powermanagement
+      lxqt-qtplugin
+      lxqt-session
+      lxqt-sudo
+      lxqt-themes
+      pavucontrol-qt
+
+      ### CORE 2
+      lxqt-panel
+      lxqt-runner
+      pcmanfm-qt
+    ];
+
+    optionalPackages = [
+      ### LXQt project
+      qterminal
+      obconf-qt
+      lximage-qt
+      lxqt-archiver
+
+      ### QtDesktop project
+      qps
+      screengrab
+
+      ### Default icon theme
+      libsForQt5.breeze-icons
+
+      ### Screen saver
+      pkgs.xscreensaver
+    ];
+
+  };
+in
+makeScope libsForQt5.newScope packages

pkgs/desktops/lxqt/libfm-qt/default.nix

@@ -0,0 +1,55 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, lxqt-build-tools
+, pcre
+, libexif
+, xorg
+, libfm
+, menu-cache
+, qtx11extras
+, qttools
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "libfm-qt";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = "libfm-qt";
+    rev = version;
+    sha256 = "kF3u1Eh45l/HvL5R0PazIfGIdOVYyB2VAI33NwRfLJk=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    pcre
+    libexif
+    xorg.libpthreadstubs
+    xorg.libxcb
+    xorg.libXdmcp
+    qtx11extras
+    qttools
+    libfm
+    menu-cache
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/libfm-qt";
+    description = "Core library of PCManFM-Qt (Qt binding for libfm)";
+    license = licenses.lgpl21Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/liblxqt/default.nix

@@ -0,0 +1,62 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtx11extras
+, qttools
+, qtsvg
+, libqtxdg
+, polkit-qt
+, kwindowsystem
+, xorg
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "liblxqt";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "vfqEB9Vh/BL47dlEvnyWwDBO0pRIUS1IuixW8A0PRds=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtx11extras
+    qttools
+    qtsvg
+    polkit-qt
+    kwindowsystem
+    libqtxdg
+    xorg.libXScrnSaver
+  ];
+
+  # convert name of wrapped binary, e.g. .lxqt-whatever-wrapped to the original name, e.g. lxqt-whatever so binaries can find their resources
+  patches = [ ./fix-application-path.patch ];
+
+  postPatch = ''
+    # https://github.com/NixOS/nixpkgs/issues/119766
+    substituteInPlace lxqtbacklight/linux_backend/driver/libbacklight_backend.c \
+      --replace "pkexec lxqt-backlight_backend" "pkexec $out/bin/lxqt-backlight_backend"
+
+    sed -i "s|\''${POLKITQT-1_POLICY_FILES_INSTALL_DIR}|''${out}/share/polkit-1/actions|" CMakeLists.txt
+  '';
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    description = "Core utility library for all LXQt components";
+    homepage = "https://github.com/lxqt/liblxqt";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/liblxqt/fix-application-path.patch

@@ -0,0 +1,23 @@
+--- a/lxqtapplication.cpp
++++ b/lxqtapplication.cpp
+@@ -77,7 +77,7 @@ Application::Application(int &argc, char** argv, bool handleQuitSignals)
+ 
+ void Application::updateTheme()
+ {
+-    const QString styleSheetKey = QFileInfo(applicationFilePath()).fileName();
++    const QString styleSheetKey = QFileInfo(applicationFilePath()).fileName().mid(1).chopped(8);
+     setStyleSheet(lxqtTheme.qss(styleSheetKey));
+     Q_EMIT themeChanged();
+ }
+
+--- a/lxqttranslator.cpp
++++ b/lxqttranslator.cpp
+@@ -147,7 +147,7 @@ bool Translator::translateApplication(const QString &applicationName)
+     if (!applicationName.isEmpty())
+         return translate(applicationName);
+     else
+-        return translate(QFileInfo(QCoreApplication::applicationFilePath()).baseName());
++        return translate(QFileInfo(QCoreApplication::applicationFilePath()).baseName().mid(1).chopped(8));
+ }
+ 
+ 

pkgs/desktops/lxqt/libqtxdg/default.nix

@@ -0,0 +1,49 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, qtbase
+, qtsvg
+, lxqt-build-tools
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "libqtxdg";
+  version = "3.9.1";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "zrlaOiIsfbwjHFjqhYZ9lCo+oTsddICxl2UAum9Xoi4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qtsvg
+  ];
+
+  preConfigure = ''
+    cmakeFlagsArray+=(
+      "-DQTXDGX_ICONENGINEPLUGIN_INSTALL_PATH=$out/$qtPluginPrefix/iconengines"
+      "-DCMAKE_INSTALL_INCLUDEDIR=include"
+      "-DCMAKE_INSTALL_LIBDIR=lib"
+    )
+  '';
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/libqtxdg";
+    description = "Qt implementation of freedesktop.org xdg specs";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/libsysstat/default.nix

@@ -0,0 +1,41 @@
+{ stdenv
+, lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, qtbase
+, lxqt-build-tools
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "libsysstat";
+  version = "0.4.6";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "0z2r8041vqssm59lkb3ka7qis9br4wvavxzd45m3pnqlp7wwhkbn";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    broken = stdenv.isDarwin;
+    description = "Library used to query system info and statistics";
+    homepage = "https://github.com/lxqt/libsysstat";
+    license = licenses.lgpl21Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lximage-qt/default.nix

@@ -0,0 +1,54 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, qtbase
+, qttools
+, qtx11extras
+, qtsvg
+, xorg
+, lxqt-build-tools
+, libfm-qt
+, libexif
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lximage-qt";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "QvQ0LBGP9XD7vwuUD+A1x8oGDvqTeCkYyd2XyjU0fUo=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtsvg
+    libfm-qt
+    xorg.libpthreadstubs
+    xorg.libXdmcp
+    libexif
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lximage-qt";
+    description = "The image viewer and screenshot tool for lxqt";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-about/default.nix

@@ -0,0 +1,49 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtx11extras
+, qttools
+, qtsvg
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-about";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "GTnjmMVbkO5CeNLxNisD6XncqX32otaATZSka4YVNHo=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtx11extras
+    qttools
+    qtsvg
+    kwindowsystem
+    liblxqt
+    libqtxdg
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-about";
+    description = "Dialogue window providing information about LXQt and the system it's running on";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-admin/default.nix

@@ -0,0 +1,59 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtx11extras
+, qttools
+, qtsvg
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, polkit-qt
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-admin";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "A5dpw/vG92tC4W1q1wpDyMdRn1ScEH7m287MCEGOp9w=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtx11extras
+    qttools
+    qtsvg
+    kwindowsystem
+    liblxqt
+    libqtxdg
+    polkit-qt
+  ];
+
+  postPatch = ''
+    for f in lxqt-admin-{time,user}/CMakeLists.txt; do
+      substituteInPlace $f --replace \
+        "\''${POLKITQT-1_POLICY_FILES_INSTALL_DIR}" \
+        "$out/share/polkit-1/actions"
+    done
+  '';
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-admin";
+    description = "LXQt system administration tool";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-archiver/default.nix

@@ -0,0 +1,51 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, lxqt-build-tools
+, json-glib
+, libfm-qt
+, qtbase
+, qttools
+, qtx11extras
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-archiver";
+  version = "0.6.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = "lxqt-archiver";
+    rev = version;
+    sha256 = "ay0nWCe/uMsJFFtBAQnsuxR6I/8q3xv6zK/qYr3BQyw=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    json-glib
+    libfm-qt
+    qtbase
+    qttools
+    qtx11extras
+  ];
+
+  hardeningDisable = [ "format" ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-archiver/";
+    description = "Archive tool for the LXQt desktop environment";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    maintainers = with maintainers; [ jchw ] ++ teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-build-tools/LXQtConfigVars.cmake

@@ -0,0 +1,7 @@
+add_definitions("-DLXQT_RELATIVE_SHARE_DIR=\"${LXQT_RELATIVE_SHARE_DIR}\"")
+add_definitions("-DLXQT_SHARE_DIR=\"${LXQT_SHARE_DIR}\"")
+add_definitions("-DLXQT_RELATIVE_SHARE_TRANSLATIONS_DIR=\"${LXQT_RELATIVE_TRANSLATIONS_DIR}\"")
+add_definitions("-DLXQT_SHARE_TRANSLATIONS_DIR=\"${LXQT_TRANSLATIONS_DIR}\"")
+add_definitions("-DLXQT_GRAPHICS_DIR=\"${LXQT_GRAPHICS_DIR}\"")
+add_definitions("-DLXQT_ETC_XDG_DIR=\"${LXQT_ETC_XDG_DIR}\"")
+add_definitions("-DLXQT_DATA_DIR=\"${LXQT_DATA_DIR}\"")

pkgs/desktops/lxqt/lxqt-build-tools/default.nix

@@ -0,0 +1,71 @@
+{ lib
+, stdenv
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, pcre
+, qtbase
+, glib
+, perl
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-build-tools";
+  version = "0.11.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "vzppKTDwADBG5pOaluT858cWCKFFRaSbHz2Qhe6799E=";
+  };
+
+  postPatch = ''
+    # Nix clang on darwin identifies as 'Clang', not 'AppleClang'
+    # Without this, dependants fail to link.
+    substituteInPlace cmake/modules/LXQtCompilerSettings.cmake \
+      --replace AppleClang Clang
+
+    # GLib 2.72 moved the file from gio-unix-2.0 to gio-2.0.
+    # https://github.com/lxqt/lxqt-build-tools/pull/74
+    substituteInPlace cmake/find-modules/FindGLIB.cmake \
+      --replace gio/gunixconnection.h gio/gunixfdlist.h
+  '';
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    setupHook
+  ];
+
+  buildInputs = [
+    qtbase
+    glib
+    pcre
+  ];
+
+  propagatedBuildInputs = [
+    perl # needed by LXQtTranslateDesktop.cmake
+  ];
+
+  setupHook = ./setup-hook.sh;
+
+  # We're dependent on this macro doing add_definitions in most places
+  # But we have the setup-hook to set the values.
+  postInstall = ''
+    rm $out/share/cmake/lxqt-build-tools/modules/LXQtConfigVars.cmake
+    cp ${./LXQtConfigVars.cmake} $out/share/cmake/lxqt-build-tools/modules/LXQtConfigVars.cmake
+  '';
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-build-tools";
+    description = "Various packaging tools and scripts for LXQt applications";
+    license = licenses.lgpl21Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-build-tools/setup-hook.sh

@@ -0,0 +1,15 @@
+LXQtCMakePostHook() {
+  cmakeFlagsArray+=(
+    -DLXQT_LIBRARY_NAME=lxqt
+    -DLXQT_SHARE_DIR=$out/share/lxqt
+    -DLXQT_TRANSLATIONS_DIR=$out/share/lxqt/translations
+    -DLXQT_GRAPHICS_DIR=$out/share/lxqt/graphics
+    -DLXQT_ETC_XDG_DIR=$out/etc/xdg
+    -DLXQT_DATA_DIR=$out/share
+    -DLXQT_RELATIVE_SHARE_DIR=lxqt
+    -DLXQT_RELATIVE_SHARE_TRANSLATIONS_DIR=lxqt/translations
+  )
+
+}
+
+postHooks+=(LXQtCMakePostHook)

pkgs/desktops/lxqt/lxqt-config/default.nix

@@ -0,0 +1,77 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, glib
+, lxqt-build-tools
+, qtbase
+, qtx11extras
+, qttools
+, qtsvg
+, kwindowsystem
+, libkscreen
+, liblxqt
+, libqtxdg
+, xkeyboard_config
+, xorg
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-config";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "ncoJLpKzE1tqOV+KuUiGLDWiDvzJg0le4m4BMKFw6Mg=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    glib.bin
+    qtbase
+    qtx11extras
+    qttools
+    qtsvg
+    kwindowsystem
+    libkscreen
+    liblxqt
+    libqtxdg
+    xorg.libpthreadstubs
+    xorg.libXdmcp
+    xorg.libXScrnSaver
+    xorg.libxcb
+    xorg.libXcursor
+    xorg.xf86inputlibinput
+    xorg.xf86inputlibinput.dev
+  ];
+
+  postPatch = ''
+    substituteInPlace lxqt-config-appearance/configothertoolkits.cpp \
+      --replace 'QStringLiteral("gsettings' \
+                'QStringLiteral("${glib.bin}/bin/gsettings'
+
+    substituteInPlace lxqt-config-input/keyboardlayoutconfig.h \
+      --replace '/usr/share/X11/xkb/rules/base.lst' \
+                '${xkeyboard_config}/share/X11/xkb/rules/base.lst'
+  '';
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-config";
+    description = "Tools to configure LXQt and the underlying operating system";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+
+}

pkgs/desktops/lxqt/lxqt-globalkeys/default.nix

@@ -0,0 +1,51 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtx11extras
+, qtsvg
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-globalkeys";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "6io6gH+n7dodTDQjvCqxjvaafQ4E9H7kx+s2QiAm3mY=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtsvg
+    kwindowsystem
+    liblxqt
+    libqtxdg
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-globalkeys";
+    description = "LXQt service for global keyboard shortcuts registration";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-notificationd/default.nix

@@ -0,0 +1,51 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtsvg
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, qtx11extras
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-notificationd";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "YXwWqab6OW1KE7Zct92xdK/f/QaDVqEMVM+Cb9kNe7E=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtsvg
+    kwindowsystem
+    liblxqt
+    libqtxdg
+    qtx11extras
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-notificationd";
+    description = "The LXQt notification daemon";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-openssh-askpass/default.nix

@@ -0,0 +1,51 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtsvg
+, qtx11extras
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-openssh-askpass";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "s1ywmlcHsbeaRi5zrhFMPS0SJ1s8IYnDXWkFvB1kaI4=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtsvg
+    kwindowsystem
+    liblxqt
+    libqtxdg
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-openssh-askpass";
+    description = "GUI to query passwords on behalf of SSH agents";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-panel/default.nix

@@ -0,0 +1,83 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, alsa-lib
+, kguiaddons
+, kwindowsystem
+, libXdamage
+, libdbusmenu
+, liblxqt
+, libpulseaudio
+, libqtxdg
+, libstatgrab
+, libsysstat
+, lm_sensors
+, lxmenu-data
+, lxqt-build-tools
+, lxqt-globalkeys
+, lxqtUpdateScript
+, menu-cache
+, pcre
+, qtbase
+, qtsvg
+, qttools
+, qtx11extras
+, solid
+, xorg
+}:
+
+mkDerivation rec {
+  pname = "lxqt-panel";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "w5/uS8kRb5yFUXd1NImWMXxx40YtzxMZMS87e9syb6A=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    alsa-lib
+    kguiaddons
+    kwindowsystem
+    libXdamage
+    libdbusmenu
+    liblxqt
+    libpulseaudio
+    libqtxdg
+    libstatgrab
+    libsysstat
+    lm_sensors
+    lxmenu-data
+    lxqt-globalkeys
+    menu-cache
+    pcre
+    qtbase
+    qtsvg
+    qttools
+    qtx11extras
+    solid
+    xorg.libXdmcp
+    xorg.libXtst
+    xorg.libpthreadstubs
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-panel";
+    description = "The LXQt desktop panel";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-policykit/default.nix

@@ -0,0 +1,59 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtx11extras
+, qtsvg
+, polkit
+, polkit-qt
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, pcre
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-policykit";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "Fs3N9r8RkawbXnX8jv8Fx63ijwAfy+OfrCpjeHDjKio=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtsvg
+    polkit
+    polkit-qt
+    kwindowsystem
+    liblxqt
+    libqtxdg
+    pcre
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-policykit";
+    description = "The LXQt PolicyKit agent";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-powermanagement/default.nix

@@ -0,0 +1,57 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtx11extras
+, qtsvg
+, kwindowsystem
+, solid
+, kidletime
+, liblxqt
+, libqtxdg
+, lxqt-globalkeys
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-powermanagement";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "+FpJD5PEH2/HOSWDQEwMX2sV2JJH0kjcoohBolhSP1A=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtsvg
+    kwindowsystem
+    solid
+    kidletime
+    liblxqt
+    libqtxdg
+    lxqt-globalkeys
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-powermanagement";
+    description = "Power management module for LXQt";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-qtplugin/default.nix

@@ -0,0 +1,56 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, libdbusmenu
+, libfm-qt
+, libqtxdg
+, lxqt-build-tools
+, lxqtUpdateScript
+, qtbase
+, qtsvg
+, qttools
+, qtx11extras
+}:
+
+mkDerivation rec {
+  pname = "lxqt-qtplugin";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "mTA+3sXFWFYUEQhZOnAy6D/tYVAU+9AXbuLmLi7axlc=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    libdbusmenu
+    libfm-qt
+    libqtxdg
+    qtbase
+    qtsvg
+    qttools
+    qtx11extras
+  ];
+
+  postPatch = ''
+    substituteInPlace src/CMakeLists.txt \
+      --replace "DESTINATION \"\''${QT_PLUGINS_DIR}" "DESTINATION \"$qtPluginPrefix"
+  '';
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-qtplugin";
+    description = "LXQt Qt platform integration plugin";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-runner/default.nix

@@ -0,0 +1,61 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtsvg
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, lxqt-globalkeys
+, qtx11extras
+, menu-cache
+, muparser
+, pcre
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-runner";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "hnuzoHKXqM6xEzN0jvHVjVWUXRxuwdhD3BiBfFMmZSk=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtsvg
+    qtx11extras
+    kwindowsystem
+    liblxqt
+    libqtxdg
+    lxqt-globalkeys
+    menu-cache
+    muparser
+    pcre
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-runner";
+    description = "Tool used to launch programs quickly by typing their names";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-session/default.nix

@@ -0,0 +1,62 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtsvg
+, qtx11extras
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, qtxdg-tools
+, procps
+, xorg
+, xdg-user-dirs
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-session";
+  version = "1.1.1";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "NOwuHz5SiygE/9cLrYPz24L5v8BE6Hwqp6uKD5SnOBU=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtsvg
+    qtx11extras
+    kwindowsystem
+    liblxqt
+    libqtxdg
+    qtxdg-tools
+    procps
+    xorg.libpthreadstubs
+    xorg.libXdmcp
+    xdg-user-dirs
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-session";
+    description = "An alternative session manager ported from the original razor-session";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-sudo/default.nix

@@ -0,0 +1,53 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtbase
+, qttools
+, qtx11extras
+, qtsvg
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, sudo
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-sudo";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "Oa4OYIDXQUIQ96pEY7rGBq+spwVSU+kgDS7250tYNuc=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtsvg
+    kwindowsystem
+    liblxqt
+    libqtxdg
+    sudo
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-sudo";
+    description = "GUI frontend for sudo/su";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/lxqt-themes/default.nix

@@ -0,0 +1,34 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "lxqt-themes";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "OEl6ZfMKdqjONRA1LPZ69KyFjp1c21Uib/riYDWSRWE=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/lxqt-themes";
+    description = "Themes, graphics and icons for LXQt";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/obconf-qt/default.nix

@@ -0,0 +1,53 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, pcre
+, qtbase
+, qttools
+, qtx11extras
+, xorg
+, lxqt-build-tools
+, openbox
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "obconf-qt";
+  version = "0.16.2";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "zxwQfKowgpLjfxSV2t7Ly8o7DFqoIxi60zIVCcKDQWo=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    pcre
+    qtbase
+    qttools
+    qtx11extras
+    xorg.libpthreadstubs
+    xorg.libXdmcp
+    xorg.libSM
+    openbox
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/obconf-qt";
+    description = "The Qt port of obconf, the Openbox configuration tool";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/pavucontrol-qt/default.nix

@@ -0,0 +1,48 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, lxqt
+, libpulseaudio
+, pcre
+, qtbase
+, qttools
+, qtx11extras
+}:
+
+mkDerivation rec {
+  pname = "pavucontrol-qt";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "zHV9tR5gDjKDbfhnhVnCnw7whJDugMAGARA3UNs/6aA=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt.lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    libpulseaudio
+    pcre
+  ];
+
+  passthru.updateScript = lxqt.lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/pavucontrol-qt";
+    description = "A Pulseaudio mixer in Qt (port of pavucontrol)";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/pcmanfm-qt/default.nix

@@ -0,0 +1,56 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, lxqt
+, qtbase
+, qttools
+, qtx11extras
+, libfm-qt
+, menu-cache
+, lxmenu-data
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "pcmanfm-qt";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "AgNupKdjSigrgY2U9bnkQCV0BrRCw2X9WR4jUH6YmEU=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    lxqt.lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    libfm-qt
+    libfm-qt
+    menu-cache
+    lxmenu-data
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  postPatch = ''
+    substituteInPlace config/pcmanfm-qt/lxqt/settings.conf.in --replace @LXQT_SHARE_DIR@ /run/current-system/sw/share/lxqt
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/pcmanfm-qt";
+    description = "File manager and desktop icon manager (Qt port of PCManFM and libfm)";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/qlipper/default.nix

@@ -0,0 +1,39 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, qtbase
+, qttools
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "qlipper";
+  version = "5.1.2";
+
+  src = fetchFromGitHub {
+    owner = "pvanek";
+    repo = pname;
+    rev = version;
+    sha256 = "0zpkcqfylcfwvadp1bidcrr64d8ls5c7bdnkfqwjjd32sd35ly60";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    description = "Cross-platform clipboard history applet";
+    homepage = "https://github.com/pvanek/qlipper";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/qps/default.nix

@@ -0,0 +1,49 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, kwindowsystem
+, liblxqt
+, libqtxdg
+, lxqt-build-tools
+, lxqtUpdateScript
+, qtbase
+, qttools
+, qtx11extras
+}:
+
+mkDerivation rec {
+  pname = "qps";
+  version = "2.5.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "hkcl9bBQP994TGr4CQQlRZR88IZiRdcbUNOXXf4kXdg=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    kwindowsystem
+    liblxqt
+    libqtxdg
+    qtbase
+    qttools
+    qtx11extras
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/qps";
+    description = "Qt based process manager";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; linux; # does not build on darwin
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/qterminal/default.nix

@@ -0,0 +1,48 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, lxqt-build-tools
+, qtermwidget
+, qtbase
+, qttools
+, qtx11extras
+, lxqtUpdateScript
+, nixosTests
+}:
+
+mkDerivation rec {
+  pname = "qterminal";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "x+rgDrijDsMMdpU7afkn0dsSQbuBbEI9agoaLVsR/q8=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtermwidget
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  passthru.tests.test = nixosTests.terminal-emulators.qterminal;
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/qterminal";
+    description = "A lightweight Qt-based terminal emulator";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    maintainers = with maintainers; [ globin ] ++ teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/qtermwidget/default.nix

@@ -0,0 +1,43 @@
+{ stdenv
+, lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, qtbase
+, qttools
+, lxqt-build-tools
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "qtermwidget";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "tb1Vlkv8HsNlFCFOYfPnJlhdJmhyDmLE9SaTXZT0gGs=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    broken = stdenv.isDarwin;
+    homepage = "https://github.com/lxqt/qtermwidget";
+    description = "A terminal emulator widget for Qt 5";
+    license = licenses.gpl2Plus;
+    platforms = with platforms; unix;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/qtxdg-tools/default.nix

@@ -0,0 +1,41 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, qtbase
+, libqtxdg
+, lxqt-build-tools
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "qtxdg-tools";
+  version = "3.9.1";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-NUSeXEJ6zjTz6p/8R6YTVfPQEnk1ukZ2ikdDdkaPeSw=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    lxqt-build-tools
+  ];
+
+  buildInputs = [
+    qtbase
+    libqtxdg
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/qtxdg-tools";
+    description = "libqtxdg user tools";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/screengrab/default.nix

@@ -0,0 +1,56 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, pkg-config
+, qtbase
+, qttools
+, qtx11extras
+, qtsvg
+, kwindowsystem
+, libqtxdg
+, perl
+, xorg
+, autoPatchelfHook
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "screengrab";
+  version = "2.4.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "EWmEbXY2EEUW2Hq7JwLW/KDgQ8KHs4DZzuGgFjNthPQ=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    perl # needed by LXQtTranslateDesktop.cmake
+    autoPatchelfHook # fix libuploader.so and libextedit.so not found
+  ];
+
+  buildInputs = [
+    qtbase
+    qttools
+    qtx11extras
+    qtsvg
+    kwindowsystem
+    libqtxdg
+    xorg.libpthreadstubs
+    xorg.libXdmcp
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/screengrab";
+    description = "Crossplatform tool for fast making screenshots";
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = teams.lxqt.members;
+  };
+}

pkgs/desktops/lxqt/xdg-desktop-portal-lxqt/default.nix

@@ -0,0 +1,41 @@
+{ lib
+, mkDerivation
+, fetchFromGitHub
+, cmake
+, kwindowsystem
+, libfm-qt
+, qtx11extras
+, lxqtUpdateScript
+}:
+
+mkDerivation rec {
+  pname = "xdg-desktop-portal-lxqt";
+  version = "0.2.0";
+
+  src = fetchFromGitHub {
+    owner = "lxqt";
+    repo = pname;
+    rev = version;
+    sha256 = "15wld2p07sbf2i2qv86ljm479q0nr9r65wavmabmn3fkzkz5vlgf";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    kwindowsystem
+    libfm-qt
+    qtx11extras
+  ];
+
+  passthru.updateScript = lxqtUpdateScript { inherit pname version src; };
+
+  meta = with lib; {
+    homepage = "https://github.com/lxqt/xdg-desktop-portal-lxqt";
+    description = "Backend implementation for xdg-desktop-portal that is using Qt/KF5/libfm-qt";
+    license = licenses.lgpl21Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ romildo ];
+  };
+}