uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/desktops/pantheon/apps/elementary-code/default.nix

@@ -0,0 +1,91 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, nix-update-script
+, appstream
+, desktop-file-utils
+, meson
+, ninja
+, pkg-config
+, polkit
+, python3
+, vala
+, wrapGAppsHook
+, editorconfig-core-c
+, granite
+, gtk3
+, gtksourceview4
+, gtkspell3
+, libgee
+, libgit2-glib
+, libhandy
+, libpeas
+, libsoup
+, vte
+, ctags
+}:
+
+stdenv.mkDerivation rec {
+  pname = "elementary-code";
+  version = "6.2.0";
+
+  src = fetchFromGitHub {
+    owner = "elementary";
+    repo = "code";
+    rev = version;
+    sha256 = "sha256-QhJNRhYgGbPMd7B1X3kG+pnC/lGUoF7gc7O1PdG49LI=";
+  };
+
+  nativeBuildInputs = [
+    appstream
+    desktop-file-utils
+    meson
+    ninja
+    pkg-config
+    polkit # needed for ITS rules
+    python3
+    vala
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    editorconfig-core-c
+    granite
+    gtk3
+    gtksourceview4
+    gtkspell3
+    libgee
+    libgit2-glib
+    libhandy
+    libpeas
+    libsoup
+    vte
+  ];
+
+  # ctags needed in path by outline plugin
+  preFixup = ''
+    gappsWrapperArgs+=(
+      --prefix PATH : "${lib.makeBinPath [ ctags ]}"
+    )
+  '';
+
+  postPatch = ''
+    chmod +x meson/post_install.py
+    patchShebangs meson/post_install.py
+  '';
+
+  passthru = {
+    updateScript = nix-update-script {
+      attrPath = "pantheon.${pname}";
+    };
+  };
+
+  meta = with lib; {
+    description = "Code editor designed for elementary OS";
+    homepage = "https://github.com/elementary/code";
+    license = licenses.gpl3Plus;
+    platforms = platforms.linux;
+    maintainers = teams.pantheon.members;
+    mainProgram = "io.elementary.code";
+  };
+}