uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/desktops/xfce/applications/catfish/default.nix

@@ -0,0 +1,67 @@
+{ lib, fetchurl, file, which, intltool, gobject-introspection,
+  findutils, xdg-utils, dconf, gtk3, python3Packages, xfconf,
+  wrapGAppsHook
+}:
+
+python3Packages.buildPythonApplication rec {
+  pname = "catfish";
+  version = "4.16.3";
+
+  src = fetchurl {
+    url = "https://archive.xfce.org/src/apps/${pname}/${lib.versions.majorMinor version}/${pname}-${version}.tar.bz2";
+    sha256 = "sha256-6amaYtEJgTkVCN1D88v6LVCmm9a30e7vfTC6TGc9z9o=";
+  };
+
+  nativeBuildInputs = [
+    python3Packages.distutils_extra
+    file
+    which
+    intltool
+    gobject-introspection # for setup hook populating GI_TYPELIB_PATH
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    gtk3
+    dconf
+    python3Packages.pyxdg
+    python3Packages.ptyprocess
+    python3Packages.pycairo
+    gobject-introspection # Temporary fix, see https://github.com/NixOS/nixpkgs/issues/56943
+  ];
+
+  propagatedBuildInputs = [
+    python3Packages.dbus-python
+    python3Packages.pygobject3
+    python3Packages.pexpect
+    xdg-utils
+    findutils
+    xfconf
+  ];
+
+  # Explicitly set the prefix dir in "setup.py" because setuptools is
+  # not using "$out" as the prefix when installing catfish data. In
+  # particular the variable "__catfish_data_directory__" in
+  # "catfishconfig.py" is being set to a subdirectory in the python
+  # path in the store.
+  postPatch = ''
+    sed -i "/^        if self.root/i\\        self.prefix = \"$out\"" setup.py
+  '';
+
+  # Disable check because there is no test in the source distribution
+  doCheck = false;
+
+  meta = with lib; {
+    homepage = "https://docs.xfce.org/apps/catfish/start";
+    description = "Handy file search tool";
+    longDescription = ''
+      Catfish is a handy file searching tool. The interface is
+      intentionally lightweight and simple, using only GTK 3.
+      You can configure it to your needs by using several command line
+      options.
+    '';
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/gigolo/default.nix

@@ -0,0 +1,18 @@
+{ lib, mkXfceDerivation, gtk3, glib }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "gigolo";
+  version = "0.5.2";
+  odd-unstable = false;
+
+  sha256 = "sha256-8UDb4H3zxRKx2y+MRsozQoR3es0fs5ooR/5wBIE11bY=";
+
+  buildInputs = [ gtk3 glib ];
+
+  meta = with lib; {
+    description = "A frontend to easily manage connections to remote filesystems";
+    license = with licenses; [ gpl2Only ];
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/mousepad/default.nix

@@ -0,0 +1,22 @@
+{ lib, mkXfceDerivation, gobject-introspection, gtk3, gtksourceview4, gspell }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "mousepad";
+  version = "0.5.9";
+  odd-unstable = false;
+
+  sha256 = "sha256-xuSv2H1+/NNUAm+D8f+f5fPVR97iJ5vIDzPa3S0HLM0=";
+
+  nativeBuildInputs = [ gobject-introspection ];
+
+  buildInputs = [ gtk3 gtksourceview4 gspell ];
+
+  # Use the GSettings keyfile backend rather than DConf
+  configureFlags = [ "--enable-keyfile-settings" ];
+
+  meta = with lib; {
+    description = "Simple text editor for Xfce";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/orage/default.nix

@@ -0,0 +1,48 @@
+{ lib
+, mkXfceDerivation
+, dbus-glib
+, gtk3
+, libical
+, libnotify
+, libxfce4ui
+, popt
+, tzdata
+, xfce4-panel
+, withPanelPlugin ? true
+}:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "orage";
+  version = "4.16.0";
+  odd-unstable = false;
+  sha256 = "sha256-Q2vTjfhbhG7TrkGeU5oVBB+UvrV5QFtl372wgHU4cxw=";
+
+  buildInputs = [
+    dbus-glib
+    gtk3
+    libical
+    libnotify
+    libxfce4ui
+    popt
+  ]
+  ++ lib.optionals withPanelPlugin [
+    xfce4-panel
+  ];
+
+  postPatch = ''
+    substituteInPlace src/parameters.c        --replace "/usr/share/zoneinfo" "${tzdata}/share/zoneinfo"
+    substituteInPlace src/tz_zoneinfo_read.c  --replace "/usr/share/zoneinfo" "${tzdata}/share/zoneinfo"
+    substituteInPlace tz_convert/tz_convert.c --replace "/usr/share/zoneinfo" "${tzdata}/share/zoneinfo"
+  '';
+
+  postConfigure = ''
+    # ensure pkgs.libical is used instead of one included in the orage sources
+    rm -rf libical
+  '';
+
+  meta = with lib; {
+    description = "Simple calendar application for Xfce";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/parole/default.nix

@@ -0,0 +1,38 @@
+{ lib, mkXfceDerivation, dbus, dbus-glib
+, gst_all_1, gtk3, libnotify, libxfce4ui, libxfce4util
+, taglib, xfconf }:
+
+# Doesn't seem to find H.264 codec even though built with gst-plugins-bad.
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "parole";
+  version = "4.16.0";
+
+  sha256 = "sha256-9Rvhc8asFEb/+OU6uhuHKPl7w5mWBfzGP5ia0tiyDB4=";
+
+  postPatch = ''
+    substituteInPlace src/plugins/mpris2/Makefile.am \
+      --replace GST_BASE_CFLAGS GST_VIDEO_CFLAGS
+  '';
+
+  buildInputs = with gst_all_1; [
+    dbus
+    dbus-glib
+    gst-plugins-bad
+    gst-plugins-base
+    gst-plugins-good
+    gst-plugins-ugly
+    gtk3
+    libnotify
+    libxfce4ui
+    libxfce4util
+    taglib
+    xfconf
+  ];
+
+  meta = with lib; {
+    description = "Modern simple media player";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/ristretto/default.nix

@@ -0,0 +1,19 @@
+{ lib, mkXfceDerivation, gtk3, glib, libexif
+, libxfce4ui, libxfce4util, xfconf }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "ristretto";
+  version = "0.12.2";
+
+  sha256 = "sha256-OIt92DpDAZpy/fAOauGnzsufUi+y3Ag7KblZ5EUGuyQ=";
+
+  buildInputs = [ glib gtk3 libexif libxfce4ui libxfce4util xfconf ];
+
+  NIX_CFLAGS_COMPILE = "-I${glib.dev}/include/gio-unix-2.0";
+
+  meta = with lib; {
+    description = "A fast and lightweight picture-viewer for the Xfce desktop environment";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfburn/default.nix

@@ -0,0 +1,17 @@
+{ lib, mkXfceDerivation, docbook_xsl, exo, gtk3, libburn, libisofs, libxfce4ui, libxslt }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfburn";
+  version = "0.6.2";
+
+  sha256 = "sha256-AUonNhMs2HBF1WBLdZNYmASTOxYt6A6WDKNtvZaGXQk=";
+
+  nativeBuildInputs = [ libxslt docbook_xsl ];
+  buildInputs = [ exo gtk3 libburn libisofs libxfce4ui ];
+
+  meta = with lib; {
+    description = "Disc burner and project creator for Xfce";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfce4-dict/configure-gio.patch

@@ -0,0 +1,11 @@
+diff -urNZ a/configure.ac.in b/configure.ac.in
+--- a/configure.ac.in	2017-12-16 19:46:13.784914017 +0000
++++ b/configure.ac.in	2017-12-16 19:46:38.612477052 +0000
+@@ -53,6 +53,7 @@
+ dnl ***********************************
+ dnl *** Check for required packages ***
+ dnl ***********************************
++XDT_CHECK_PACKAGE([GIO], [gio-unix-2.0], [2.32.0])
+ XDT_CHECK_PACKAGE([GTHREAD], [gthread-2.0], [2.24.0])
+ XDT_CHECK_PACKAGE([GTK], [gtk+-3.0], [3.20.0])
+ XDT_CHECK_PACKAGE([LIBXFCE4UI], [libxfce4ui-2], [4.12.0])

pkgs/desktops/xfce/applications/xfce4-dict/default.nix

@@ -0,0 +1,24 @@
+{ lib, mkXfceDerivation, automakeAddFlags, gtk3, libxfce4ui, libxfce4util, xfce4-panel }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-dict";
+  version = "0.8.4";
+
+  sha256 = "sha256-UEkHB+i6hkTTjX62GCnr4uiCdZANuffSx2Nb2DF/pT4=";
+
+  patches = [ ./configure-gio.patch ];
+
+  nativeBuildInputs = [ automakeAddFlags ];
+
+  postPatch = ''
+    automakeAddFlags lib/Makefile.am libdict_la_CFLAGS GIO_CFLAGS
+  '';
+
+  buildInputs = [ gtk3 libxfce4ui libxfce4util xfce4-panel ];
+
+  meta = with lib; {
+    description = "A Dictionary Client for the Xfce desktop environment";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfce4-notifyd/default.nix

@@ -0,0 +1,21 @@
+{ lib, mkXfceDerivation, glib, gtk3, libnotify, libxfce4ui, libxfce4util
+, xfce4-panel, xfconf }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-notifyd";
+  version = "0.6.3";
+
+  sha256 = "sha256-JcHxqKLl4F4FQv7lE64gWUorCvl5g5mSD+jEmj1ORfY=";
+
+  buildInputs = [ gtk3 glib libnotify libxfce4ui libxfce4util xfce4-panel xfconf ];
+
+  configureFlags = [
+    "--enable-dbus-start-daemon"
+  ];
+
+  meta = with lib; {
+    description = "Simple notification daemon for Xfce";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfce4-panel-profiles/default.nix

@@ -0,0 +1,30 @@
+{ mkXfceDerivation, lib, python3, intltool, gettext,
+ gtk3, libxfce4ui, libxfce4util, pango, harfbuzz, gdk-pixbuf, atk }:
+
+let
+  pythonEnv = python3.withPackages(ps: [ ps.pygobject3 ]);
+  makeTypelibPath = lib.makeSearchPathOutput "lib/girepository-1.0" "lib/girepository-1.0";
+in mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-panel-profiles";
+  version = "1.0.13";
+
+  sha256 = "sha256-B3Q5d3KBN5m8wY82CIbIugJC8nNS+OcgKchn+TGrDhc=";
+
+  nativeBuildInputs = [ intltool gettext ];
+  propagatedBuildInputs = [ pythonEnv ];
+
+  configurePhase = ''
+    ./configure --prefix=$out
+  '';
+
+  postFixup = ''
+    wrapProgram $out/bin/xfce4-panel-profiles \
+      --set GI_TYPELIB_PATH ${makeTypelibPath [ gtk3 libxfce4ui libxfce4util pango harfbuzz gdk-pixbuf atk ]}
+  '';
+
+  meta = with lib; {
+    description = "Simple application to manage Xfce panel layouts";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfce4-screensaver/default.nix

@@ -0,0 +1,49 @@
+{ mkXfceDerivation
+, dbus-glib
+, garcon
+, glib
+, gtk3
+, libX11
+, libXScrnSaver
+, libXrandr
+, libwnck
+, libxfce4ui
+, libxklavier
+, pam
+, systemd
+, xfconf
+, lib
+}:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-screensaver";
+  version = "4.16.0";
+
+  sha256 = "1vblqhhzhv85yd5bz1xg14yli82ys5qrjdcabg3l53glbk61n99p";
+
+  buildInputs = [
+    dbus-glib
+    garcon
+    glib
+    gtk3
+    libX11
+    libXScrnSaver
+    libXrandr
+    libwnck
+    libxfce4ui
+    libxklavier
+    pam
+    systemd
+    xfconf
+  ];
+
+  configureFlags = [ "--without-console-kit" ];
+
+  makeFlags = [ "DBUS_SESSION_SERVICE_DIR=$(out)/etc" ];
+
+  meta =  {
+    description = "Screensaver for Xfce";
+    maintainers = with lib.maintainers; [ symphorien ];
+  };
+}

pkgs/desktops/xfce/applications/xfce4-screenshooter/default.nix

@@ -0,0 +1,17 @@
+{ lib, mkXfceDerivation, exo, gtk3, libsoup, libxfce4ui, libxfce4util, xfce4-panel, glib-networking }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-screenshooter";
+  version = "1.9.10";
+  odd-unstable = false;
+
+  sha256 = "sha256-i3QdQij58JYv3fWdESUeTV0IW3A8RVGNtmuxUc6FUMg=";
+
+  buildInputs = [ exo gtk3 libsoup libxfce4ui libxfce4util xfce4-panel glib-networking ];
+
+  meta = with lib; {
+    description = "Screenshot utility for the Xfce desktop";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfce4-taskmanager/default.nix

@@ -0,0 +1,17 @@
+{ lib, mkXfceDerivation, exo, gtk3, libwnck, libXmu }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-taskmanager";
+  version = "1.4.2";
+
+  sha256 = "sha256-jcICXPtG/7t0U0xqgvU52mjiA8wsyw7JQ0OmNjwA89A=";
+
+  nativeBuildInputs = [ exo ];
+  buildInputs = [ gtk3 libwnck libXmu ];
+
+  meta = with lib; {
+    description = "Easy to use task manager for Xfce";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfce4-terminal/default.nix

@@ -0,0 +1,20 @@
+{ lib, mkXfceDerivation, gtk3, libxfce4ui, vte, xfconf, pcre2, libxslt, docbook_xml_dtd_45, docbook_xsl, nixosTests }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-terminal";
+  version = "1.0.4";
+
+  sha256 = "sha256-eCb6KB9fFPuYzNLUm/yYrh+0D60ISzasnv/myStImEI=";
+
+  nativeBuildInputs = [ libxslt docbook_xml_dtd_45 docbook_xsl ];
+
+  buildInputs = [ gtk3 libxfce4ui vte xfconf pcre2 ];
+
+  passthru.tests.test = nixosTests.terminal-emulators.xfce4-terminal;
+
+  meta = with lib; {
+    description = "A modern terminal emulator";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfce4-volumed-pulse/default.nix

@@ -0,0 +1,17 @@
+{ lib, mkXfceDerivation, gtk3, libnotify, libpulseaudio, keybinder3, xfconf }:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfce4-volumed-pulse";
+  version = "0.2.3";
+
+  sha256 = "sha256-EgmTk19p9OBmz3rWQB0LoPhhoDm4u1V6/vvgitOzUuc=";
+
+  buildInputs = [ gtk3 libnotify libpulseaudio keybinder3 xfconf ];
+
+  meta = with lib; {
+    description = "A volume keys control daemon for Xfce using pulseaudio";
+    license = licenses.gpl3Plus;
+    maintainers = with maintainers; [ abbradar ] ++ teams.xfce.members;
+  };
+}

pkgs/desktops/xfce/applications/xfdashboard/default.nix

@@ -0,0 +1,47 @@
+{ lib
+, mkXfceDerivation
+, clutter
+, libXcomposite
+, libXinerama
+, libXdamage
+, libX11
+, libwnck
+, libxfce4ui
+, libxfce4util
+, garcon
+, xfconf
+, gtk3
+, glib
+, dbus-glib
+}:
+
+mkXfceDerivation {
+  category = "apps";
+  pname = "xfdashboard";
+  version = "0.9.5";
+  rev-prefix = "";
+  odd-unstable = false;
+
+  sha256 = "sha256-nb1zY78MUjEOJF59MYIOY1rxo3JFmzH9yTJVUGsOwOA=";
+
+  buildInputs = [
+    clutter
+    dbus-glib
+    garcon
+    glib
+    gtk3
+    libX11
+    libXcomposite
+    libXdamage
+    libXinerama
+    libwnck
+    libxfce4ui
+    libxfce4util
+    xfconf
+  ];
+
+  meta = with lib; {
+    description = "Gnome shell like dashboard";
+    maintainers = with maintainers; [ ] ++ teams.xfce.members;
+  };
+}