uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/compilers/alan/2.nix

@@ -0,0 +1,35 @@
+{ stdenv, lib, fetchFromGitHub
+}:
+
+stdenv.mkDerivation rec {
+  pname = "alan2";
+  version = "2.8.7";
+
+  src = fetchFromGitHub {
+    owner = "alan-if";
+    repo = "alan";
+    rev = "71f23ec79f7f5d66aa5ae9fd3f9b8dae41a89f15";
+    sha256 = "066jknqz1v6sismvfxjfffl35h14v8qwgcq99ibhp08dy2fwraln";
+  };
+
+  makefile = "Makefile.unix";
+
+  # Add a workarounf for -fno-common tollchains like upstream gcc-10.
+  # alan-3 is already fixed, but the backport is nontrivial.
+  NIX_CFLAGS_COMPILE = "-fcommon";
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/alan2
+    cp compiler/alan $out/bin/alan2
+    cp interpreter/arun $out/bin/arun2
+    cp alan.readme ChangeLog $out/share/alan2
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.alanif.se/";
+    description = "The Alan interactive fiction language (legacy version)";
+    license = licenses.artistic2;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ neilmayhew ];
+  };
+}

pkgs/development/compilers/alan/default.nix

@@ -0,0 +1,48 @@
+{ stdenv, lib, fetchFromGitHub
+, cgreen, openjdk, pkg-config, which
+}:
+
+stdenv.mkDerivation rec {
+  pname = "alan";
+  version = "3.0beta8";
+
+  src = fetchFromGitHub {
+    owner = "alan-if";
+    repo = "alan";
+    rev = "v${version}";
+    sha256 = "0zfg1frmb4yl39hk8h733bmlwk4rkikzfhvv7j34cxpdpsp7spzl";
+  };
+
+  postPatch = ''
+    patchShebangs --build bin
+    # The Makefiles have complex CFLAGS that don't allow separate control of optimization
+    sed -i 's/-O0/-O2/g' compiler/Makefile.common
+    sed -i 's/-Og/-O2/g' interpreter/Makefile.common
+  '';
+
+  installPhase = ''
+    mkdir -p $out/bin $out/share/alan/examples
+    # Build the release tarball
+    make package
+    # The release tarball isn't split up into subdirectories
+    tar -xf alan*.tgz --strip-components=1 -C $out/share/alan
+    mv $out/share/alan/*.alan $out/share/alan/examples
+    chmod a-x $out/share/alan/examples/*.alan
+    mv $out/share/alan/{alan,arun} $out/bin
+    # a2a3 isn't included in the release tarball
+    cp bin/a2a3 $out/bin
+  '';
+
+  nativeBuildInputs = [
+    cgreen
+    openjdk pkg-config which
+  ];
+
+  meta = with lib; {
+    homepage = "https://www.alanif.se/";
+    description = "The Alan interactive fiction language";
+    license = licenses.artistic2;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ neilmayhew ];
+  };
+}