uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/compilers/qbe/default.nix

@@ -0,0 +1,33 @@
+{ lib, stdenv
+, fetchgit
+, unstableGitUpdater
+, callPackage
+}:
+
+stdenv.mkDerivation rec {
+  pname = "qbe";
+  version = "unstable-2022-04-11";
+
+  src = fetchgit {
+    url = "git://c9x.me/qbe.git";
+    rev = "2caa26e388b1c904d2f12fb09f84df7e761d8331";
+    sha256 = "sha256-TNKHKX/PbrNIQJ+Q50KemfcigEBKe7gmJzTjB6ofYL8=";
+  };
+
+  makeFlags = [ "PREFIX=$(out)" ];
+
+  doCheck = true;
+
+  passthru = {
+    tests.can-run-hello-world = callPackage ./test-can-run-hello-world.nix {};
+    updateScript = unstableGitUpdater { };
+  };
+
+  meta = with lib; {
+    homepage = "https://c9x.me/compile/";
+    description = "A small compiler backend written in C";
+    maintainers = with maintainers; [ fgaz ];
+    license = licenses.mit;
+    platforms = platforms.all;
+  };
+}

pkgs/development/compilers/qbe/test-can-run-hello-world.nix

@@ -0,0 +1,32 @@
+{ stdenv
+, writeText
+, qbe
+}:
+
+# The hello world program available at https://c9x.me/compile/
+let helloWorld = writeText "hello-world.ssa" ''
+  function w $add(w %a, w %b) {        # Define a function add
+  @start
+    %c =w add %a, %b                   # Adds the 2 arguments
+    ret %c                             # Return the result
+  }
+  export function w $main() {          # Main function
+  @start
+    %r =w call $add(w 1, w 1)          # Call add(1, 1)
+    call $printf(l $fmt, w %r, ...)    # Show the result
+    ret 0
+  }
+  data $fmt = { b "One and one make %d!\n", b 0 }
+'';
+
+in stdenv.mkDerivation {
+  name = "qbe-test-can-run-hello-world";
+  meta.timeout = 10;
+  buildCommand = ''
+    ${qbe}/bin/qbe -o asm.s ${helloWorld}
+    cc -o out asm.s
+    ./out | grep 'One and one make 2!'
+    touch $out
+  '';
+}
+