uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/development/compilers/xa/dxa.nix
+++ b/pkgs/development/compilers/xa/dxa.nix
@ -0,0 +1,43 @@
+{ lib
+, stdenv
+, fetchurl
+, installShellFiles
+}:
+
+stdenv.mkDerivation rec {
+  pname = "dxa";
+  version = "0.1.4";
+
+  src = fetchurl {
+    urls = [
+      "https://www.floodgap.com/retrotech/xa/dists/${pname}-${version}.tar.gz"
+      "https://www.floodgap.com/retrotech/xa/dists/unsupported/${pname}-${version}.tar.gz"
+    ];
+    hash = "sha256-C0rgwK51Ij9EZCm9GeiVnWIkEkse0d60ok8G9hm2a5U=";
+  };
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  dontConfigure = true;
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace "CC = gcc" "CC = ${stdenv.cc.targetPrefix}cc"
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    install -d $out/bin/
+    install dxa $out/bin/
+    installManPage dxa.1
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.floodgap.com/retrotech/xa/";
+    description = "Andre Fachat's open-source 6502 disassembler";
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = with platforms; unix;
+  };
+}
--- a/pkgs/development/compilers/xa/xa.nix
+++ b/pkgs/development/compilers/xa/xa.nix
@ -0,0 +1,69 @@
+{ lib
+, stdenv
+, fetchurl
+, perl
+}:
+
+stdenv.mkDerivation rec {
+  pname = "xa";
+  version = "2.3.12";
+
+  src = fetchurl {
+    urls = [
+      "https://www.floodgap.com/retrotech/xa/dists/${pname}-${version}.tar.gz"
+      "https://www.floodgap.com/retrotech/xa/dists/unsupported/${pname}-${version}.tar.gz"
+    ];
+    hash = "sha256-+P0VNgEtZ2/Gy/zdapF5PlZMibbvdH+NuPRnwXj7BwQ=";
+  };
+
+  checkInputs = [ perl ];
+
+  dontConfigure = true;
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace "CC = gcc" "CC = ${stdenv.cc.targetPrefix}cc" \
+      --replace "LD = gcc" "LD = ${stdenv.cc.targetPrefix}cc" \
+      --replace "CFLAGS = -O2" "CFLAGS ?=" \
+      --replace "LDFLAGS = -lc" "LDFLAGS ?= -lc"
+  '';
+
+  makeFlags = [
+    "DESTDIR:=${placeholder "out"}"
+  ];
+
+  enableParallelBuilding = true;
+
+  doCheck = true;
+
+  # Running tests in parallel does not work
+  enableParallelChecking = false;
+
+  preCheck = ''
+    patchShebangs tests
+  '';
+
+  meta = with lib; {
+    homepage = "https://www.floodgap.com/retrotech/xa/";
+    description = "Andre Fachat's open-source 6502 cross assembler";
+    longDescription = ''
+      xa is a high-speed, two-pass portable cross-assembler. It understands
+      mnemonics and generates code for NMOS 6502s (such as 6502A, 6504, 6507,
+      6510, 7501, 8500, 8501, 8502 ...), CMOS 6502s (65C02 and Rockwell R65C02)
+      and the 65816.
+
+      Key amongst its features:
+
+      - C-like preprocessor (and understands cpp for additional feature support)
+      - rich expression syntax and pseudo-op vocabulary
+      - multiple character sets
+      - binary linking
+      - supports o65 relocatable objects with a full linker and relocation
+        suite, as well as "bare" plain binary object files
+      - block structure for label scoping
+    '';
+    license = licenses.gpl2Plus;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = with platforms; unix;
+  };
+}