uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov
Alan Daniels
commit
56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
248
pkgs/development/interpreters/perl/default.nix
Normal file
248
pkgs/development/interpreters/perl/default.nix
Normal file
|
|
@ -0,0 +1,248 @@
|
|||
{ config, lib, stdenv, fetchurl, fetchFromGitHub, pkgs, buildPackages
|
||||
, callPackage
|
||||
, enableThreading ? true, coreutils, makeWrapper
|
||||
, zlib
|
||||
}:
|
||||
|
||||
# Note: this package is used for bootstrapping fetchurl, and thus
|
||||
# cannot use fetchpatch! All mutable patches (generated by GitHub or
|
||||
# cgit) that are needed here should be included directly in Nixpkgs as
|
||||
# files.
|
||||
|
||||
with lib;
|
||||
|
||||
let
|
||||
|
||||
libc = if stdenv.cc.libc or null != null then stdenv.cc.libc else "/usr";
|
||||
libcInc = lib.getDev libc;
|
||||
libcLib = lib.getLib libc;
|
||||
crossCompiling = stdenv.buildPlatform != stdenv.hostPlatform;
|
||||
|
||||
common = { perl, buildPerl, version, sha256 }: stdenv.mkDerivation (rec {
|
||||
inherit version;
|
||||
pname = "perl";
|
||||
|
||||
src = fetchurl {
|
||||
url = "mirror://cpan/src/5.0/perl-${version}.tar.gz";
|
||||
inherit sha256;
|
||||
};
|
||||
|
||||
strictDeps = true;
|
||||
# TODO: Add a "dev" output containing the header files.
|
||||
outputs = [ "out" "man" "devdoc" ] ++
|
||||
optional crossCompiling "mini";
|
||||
setOutputFlags = false;
|
||||
|
||||
disallowedReferences = [ stdenv.cc ];
|
||||
|
||||
patches =
|
||||
[
|
||||
# Do not look in /usr etc. for dependencies.
|
||||
./no-sys-dirs-5.31.patch
|
||||
]
|
||||
++ optional stdenv.isSunOS ./ld-shared.patch
|
||||
++ optionals stdenv.isDarwin [ ./cpp-precomp.patch ./sw_vers.patch ]
|
||||
++ optional crossCompiling ./MakeMaker-cross.patch;
|
||||
|
||||
# This is not done for native builds because pwd may need to come from
|
||||
# bootstrap tools when building bootstrap perl.
|
||||
postPatch = (if crossCompiling then ''
|
||||
substituteInPlace dist/PathTools/Cwd.pm \
|
||||
--replace "/bin/pwd" '${coreutils}/bin/pwd'
|
||||
substituteInPlace cnf/configure_tool.sh --replace "cc -E -P" "cc -E"
|
||||
'' else ''
|
||||
substituteInPlace dist/PathTools/Cwd.pm \
|
||||
--replace "/bin/pwd" "$(type -P pwd)"
|
||||
'') +
|
||||
# Perl's build system uses the src variable, and its value may end up in
|
||||
# the output in some cases (when cross-compiling)
|
||||
''
|
||||
unset src
|
||||
'';
|
||||
|
||||
# Build a thread-safe Perl with a dynamic libperl.so. We need the
|
||||
# "installstyle" option to ensure that modules are put under
|
||||
# $out/lib/perl5 - this is the general default, but because $out
|
||||
# contains the string "perl", Configure would select $out/lib.
|
||||
# Miniperl needs -lm. perl needs -lrt.
|
||||
configureFlags =
|
||||
(if crossCompiling
|
||||
then [ "-Dlibpth=\"\"" "-Dglibpth=\"\"" "-Ddefault_inc_excludes_dot" ]
|
||||
else [ "-de" "-Dcc=cc" ])
|
||||
++ [
|
||||
"-Uinstallusrbinperl"
|
||||
"-Dinstallstyle=lib/perl5"
|
||||
] ++ lib.optional (!crossCompiling) "-Duseshrplib" ++ [
|
||||
"-Dlocincpth=${libcInc}/include"
|
||||
"-Dloclibpth=${libcLib}/lib"
|
||||
]
|
||||
++ optionals ((builtins.match ''5\.[0-9]*[13579]\..+'' version) != null) [ "-Dusedevel" "-Uversiononly" ]
|
||||
++ optional stdenv.isSunOS "-Dcc=gcc"
|
||||
++ optional enableThreading "-Dusethreads"
|
||||
++ optional stdenv.hostPlatform.isStatic "--all-static"
|
||||
++ optionals (!crossCompiling) [
|
||||
"-Dprefix=${placeholder "out"}"
|
||||
"-Dman1dir=${placeholder "out"}/share/man/man1"
|
||||
"-Dman3dir=${placeholder "out"}/share/man/man3"
|
||||
];
|
||||
|
||||
configureScript = optionalString (!crossCompiling) "${stdenv.shell} ./Configure";
|
||||
|
||||
dontAddStaticConfigureFlags = true;
|
||||
|
||||
dontAddPrefix = !crossCompiling;
|
||||
|
||||
enableParallelBuilding = !crossCompiling;
|
||||
|
||||
# perl includes the build date, the uname of the build system and the
|
||||
# username of the build user in some files.
|
||||
# We override these to make it build deterministically.
|
||||
# other distro solutions
|
||||
# https://github.com/bmwiedemann/openSUSE/blob/master/packages/p/perl/perl-reproducible.patch
|
||||
# https://github.com/archlinux/svntogit-packages/blob/packages/perl/trunk/config.over
|
||||
# https://salsa.debian.org/perl-team/interpreter/perl/blob/debian-5.26/debian/config.over
|
||||
# A ticket has been opened upstream to possibly clean some of this up: https://rt.perl.org/Public/Bug/Display.html?id=133452
|
||||
preConfigure = ''
|
||||
cat > config.over <<EOF
|
||||
${lib.optionalString (stdenv.hostPlatform.isLinux && stdenv.hostPlatform.isGnu) ''osvers="gnulinux"''}
|
||||
myuname="nixpkgs"
|
||||
myhostname="nixpkgs"
|
||||
cf_by="nixpkgs"
|
||||
cf_time="$(date -d "@$SOURCE_DATE_EPOCH")"
|
||||
EOF
|
||||
|
||||
# Compress::Raw::Zlib should use our zlib package instead of the one
|
||||
# included with the distribution
|
||||
cat > ./cpan/Compress-Raw-Zlib/config.in <<EOF
|
||||
BUILD_ZLIB = False
|
||||
INCLUDE = ${zlib.dev}/include
|
||||
LIB = ${zlib.out}/lib
|
||||
OLD_ZLIB = False
|
||||
GZIP_OS_CODE = AUTO_DETECT
|
||||
EOF
|
||||
'' + optionalString stdenv.isDarwin ''
|
||||
substituteInPlace hints/darwin.sh --replace "env MACOSX_DEPLOYMENT_TARGET=10.3" ""
|
||||
'' + optionalString (!enableThreading) ''
|
||||
# We need to do this because the bootstrap doesn't have a static libpthread
|
||||
sed -i 's,\(libswanted.*\)pthread,\1,g' Configure
|
||||
'';
|
||||
|
||||
# Default perl does not support --host= & co.
|
||||
configurePlatforms = [];
|
||||
|
||||
setupHook = ./setup-hook.sh;
|
||||
|
||||
passthru = rec {
|
||||
interpreter = "${perl}/bin/perl";
|
||||
libPrefix = "lib/perl5/site_perl";
|
||||
pkgs = callPackage ../../../top-level/perl-packages.nix {
|
||||
inherit perl buildPerl;
|
||||
overrides = config.perlPackageOverrides or (p: {}); # TODO: (self: super: {}) like in python
|
||||
};
|
||||
buildEnv = callPackage ./wrapper.nix {
|
||||
inherit perl;
|
||||
inherit (pkgs) requiredPerlModules;
|
||||
};
|
||||
withPackages = f: buildEnv.override { extraLibs = f pkgs; };
|
||||
};
|
||||
|
||||
doCheck = false; # some tests fail, expensive
|
||||
|
||||
# TODO: it seems like absolute paths to some coreutils is required.
|
||||
postInstall =
|
||||
''
|
||||
# Remove dependency between "out" and "man" outputs.
|
||||
rm "$out"/lib/perl5/*/*/.packlist
|
||||
|
||||
# Remove dependencies on glibc and gcc
|
||||
sed "/ *libpth =>/c libpth => ' '," \
|
||||
-i "$out"/lib/perl5/*/*/Config.pm
|
||||
# TODO: removing those paths would be cleaner than overwriting with nonsense.
|
||||
substituteInPlace "$out"/lib/perl5/*/*/Config_heavy.pl \
|
||||
--replace "${libcInc}" /no-such-path \
|
||||
--replace "${
|
||||
if stdenv.hasCC then stdenv.cc.cc else "/no-such-path"
|
||||
}" /no-such-path \
|
||||
--replace "${stdenv.cc}" /no-such-path \
|
||||
--replace "$man" /no-such-path
|
||||
'' + optionalString crossCompiling
|
||||
''
|
||||
mkdir -p $mini/lib/perl5/cross_perl/${version}
|
||||
for dir in cnf/{stub,cpan}; do
|
||||
cp -r $dir/* $mini/lib/perl5/cross_perl/${version}
|
||||
done
|
||||
|
||||
mkdir -p $mini/bin
|
||||
install -m755 miniperl $mini/bin/perl
|
||||
|
||||
export runtimeArch="$(ls $out/lib/perl5/site_perl/${version})"
|
||||
# wrapProgram should use a runtime-native SHELL by default, but
|
||||
# it actually uses a buildtime-native one. If we ever fix that,
|
||||
# we'll need to fix this to use a buildtime-native one.
|
||||
#
|
||||
# Adding the arch-specific directory is morally incorrect, as
|
||||
# miniperl can't load the native modules there. However, it can
|
||||
# (and sometimes needs to) load and run some of the pure perl
|
||||
# code there, so we add it anyway. When needed, stubs can be put
|
||||
# into $mini/lib/perl5/cross_perl/${version}.
|
||||
wrapProgram $mini/bin/perl --prefix PERL5LIB : \
|
||||
"$mini/lib/perl5/cross_perl/${version}:$out/lib/perl5/${version}:$out/lib/perl5/${version}/$runtimeArch"
|
||||
''; # */
|
||||
|
||||
meta = {
|
||||
homepage = "https://www.perl.org/";
|
||||
description = "The standard implementation of the Perl 5 programmming language";
|
||||
license = licenses.artistic1;
|
||||
maintainers = [ maintainers.eelco ];
|
||||
platforms = platforms.all;
|
||||
priority = 6; # in `buildEnv' (including the one inside `perl.withPackages') the library files will have priority over files in `perl`
|
||||
};
|
||||
} // optionalAttrs (stdenv.buildPlatform != stdenv.hostPlatform) rec {
|
||||
crossVersion = "31dac3e264a7f1f53dbf49570771123ebd514055"; # May 03, 2022
|
||||
|
||||
perl-cross-src = fetchFromGitHub {
|
||||
name = "perl-cross-unstable-${crossVersion}";
|
||||
owner = "arsv";
|
||||
repo = "perl-cross";
|
||||
rev = crossVersion;
|
||||
sha256 = "sha256-5hLUP34WwTFRsG0o8zSJm8WM3WfBAhHeYrrQF2MtMKc=";
|
||||
};
|
||||
|
||||
depsBuildBuild = [ buildPackages.stdenv.cc makeWrapper ];
|
||||
|
||||
postUnpack = ''
|
||||
unpackFile ${perl-cross-src}
|
||||
chmod -R u+w ${perl-cross-src.name}
|
||||
cp -R ${perl-cross-src.name}/* perl-${version}/
|
||||
'';
|
||||
|
||||
configurePlatforms = [ "build" "host" "target" ];
|
||||
|
||||
# TODO merge setup hooks
|
||||
setupHook = ./setup-hook-cross.sh;
|
||||
});
|
||||
in {
|
||||
# Maint version
|
||||
perl532 = common {
|
||||
perl = pkgs.perl532;
|
||||
buildPerl = buildPackages.perl532;
|
||||
version = "5.32.1";
|
||||
sha256 = "0b7brakq9xs4vavhg391as50nbhzryc7fy5i65r81bnq3j897dh3";
|
||||
};
|
||||
|
||||
# Maint version
|
||||
perl534 = common {
|
||||
perl = pkgs.perl534;
|
||||
buildPerl = buildPackages.perl534;
|
||||
version = "5.34.1";
|
||||
sha256 = "sha256-NXlRpJGwuhzjYRJjki/ux4zNWB3dwkpEawM+JazyQqE=";
|
||||
};
|
||||
|
||||
# the latest Devel version
|
||||
perldevel = common {
|
||||
perl = pkgs.perldevel;
|
||||
buildPerl = buildPackages.perldevel;
|
||||
version = "5.35.9";
|
||||
sha256 = "sha256-/nmSCIIXHXoC68DxFM9b5GM2AKU4WlLbfWLgduanL7U=";
|
||||
};
|
||||
}
|
||||
Loading…
Add table
Add a link
Reference in a new issue