uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/development/libraries/galario/default.nix
+++ b/pkgs/development/libraries/galario/default.nix
@ -0,0 +1,78 @@
+{ lib, stdenv
+, fetchzip
+, fetchFromGitHub
+, cmake
+, fftw
+, fftwFloat
+, enablePython ? false
+, pythonPackages ? null
+, llvmPackages
+}:
+let
+  # CMake recipes are needed to build galario
+  # Build process would usually download them
+  great-cmake-cookoff = fetchzip {
+    url = "https://github.com/UCL/GreatCMakeCookOff/archive/v2.1.9.tar.gz";
+    sha256 = "1yd53b5gx38g6f44jmjk4lc4igs3p25z6616hfb7aq79ly01q0w2";
+  };
+in
+stdenv.mkDerivation rec {
+  pname = "galario";
+  version = "1.2.2";
+
+  src = fetchFromGitHub {
+    owner = "mtazzari";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "0dw88ga50x3jwyfgcarn4azlhiarggvdg262hilm7rbrvlpyvha0";
+  };
+
+  nativeBuildInputs = [ cmake ];
+
+  buildInputs = [ fftw fftwFloat ]
+  ++ lib.optional enablePython pythonPackages.python
+  ++ lib.optional stdenv.isDarwin llvmPackages.openmp
+  ;
+
+  propagatedBuildInputs = lib.optional enablePython [
+    pythonPackages.numpy
+    pythonPackages.cython
+    pythonPackages.pytest
+  ];
+
+  checkInputs = lib.optional enablePython [ pythonPackages.scipy pythonPackages.pytest-cov ];
+
+  preConfigure = ''
+    mkdir -p build/external/src
+    cp -r ${great-cmake-cookoff} build/external/src/GreatCMakeCookOff
+    chmod -R 777 build/external/src/GreatCMakeCookOff
+  '';
+
+  preCheck = ''
+    ${if stdenv.isDarwin then "export DYLD_LIBRARY_PATH=$(pwd)/src/" else "export LD_LIBRARY_PATH=$(pwd)/src/"}
+    ${if enablePython then "sed -i -e 's|^#!.*|#!${stdenv.shell}|' python/py.test.sh" else ""}
+  '';
+
+  doCheck = true;
+
+  postInstall = lib.optionalString (stdenv.isDarwin && enablePython) ''
+    install_name_tool -change libgalario.dylib $out/lib/libgalario.dylib $out/lib/python*/site-packages/galario/double/libcommon.so
+    install_name_tool -change libgalario_single.dylib $out/lib/libgalario_single.dylib $out/lib/python*/site-packages/galario/single/libcommon.so
+  '';
+
+  meta = with lib; {
+    description = "GPU Accelerated Library for Analysing Radio Interferometer Observations";
+    longDescription = ''
+      Galario is a library that exploits the computing power of modern
+      graphic cards (GPUs) to accelerate the comparison of model
+      predictions to radio interferometer observations. Namely, it
+      speeds up the computation of the synthetic visibilities given a
+      model image (or an axisymmetric brightness profile) and their
+      comparison to the observations.
+    '';
+    homepage = "https://mtazzari.github.io/galario/";
+    license = licenses.lgpl3;
+    maintainers = [ maintainers.smaret ];
+    platforms = platforms.all;
+  };
+}