uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/development/libraries/live555/default.nix
+++ b/pkgs/development/libraries/live555/default.nix
@ -0,0 +1,82 @@
+{ lib
+, stdenv
+, fetchurl
+, darwin
+, openssl
+
+# major and only downstream dependency
+, vlc
+}:
+
+stdenv.mkDerivation rec {
+  pname = "live555";
+  version = "2022.02.07";
+
+  src = fetchurl {
+    urls = [
+      "http://www.live555.com/liveMedia/public/live.${version}.tar.gz"
+      "https://download.videolan.org/contrib/live555/live.${version}.tar.gz"
+      "mirror://sourceforge/slackbuildsdirectlinks/live.${version}.tar.gz"
+    ];
+    sha256 = "sha256-bwwfinHOtQa8v5abArSww2l7ThXa623LqYcsh0XOksY=";
+  };
+
+  nativeBuildInputs = lib.optional stdenv.isDarwin darwin.cctools;
+
+  buildInputs = [ openssl ];
+
+  postPatch = ''
+    substituteInPlace config.macosx-catalina \
+      --replace '/usr/lib/libssl.46.dylib' "${lib.getLib openssl}/lib/libssl.dylib" \
+      --replace '/usr/lib/libcrypto.44.dylib' "${lib.getLib openssl}/lib/libcrypto.dylib"
+    sed -i -e 's|/bin/rm|rm|g' genMakefiles
+    sed -i \
+      -e 's/$(INCLUDES) -I. -O2 -DSOCKLEN_T/$(INCLUDES) -I. -O2 -I. -fPIC -DRTSPCLIENT_SYNCHRONOUS_INTERFACE=1 -DSOCKLEN_T/g' \
+      config.linux
+  '' # condition from icu/base.nix
+    + lib.optionalString (stdenv.hostPlatform.libc == "glibc" || stdenv.hostPlatform.libc == "musl") ''
+    substituteInPlace liveMedia/include/Locale.hh \
+      --replace '<xlocale.h>' '<locale.h>'
+  '';
+
+  configurePhase = ''
+    runHook preConfigure
+
+    ./genMakefiles ${{
+      x86_64-darwin = "macosx-catalina";
+      i686-linux = "linux";
+      x86_64-linux = "linux-64bit";
+      aarch64-linux = "linux-64bit";
+    }.${stdenv.hostPlatform.system} or (throw "Unsupported platform ${stdenv.hostPlatform.system}")}
+
+    runHook postConfigure
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    for dir in BasicUsageEnvironment groupsock liveMedia UsageEnvironment; do
+      install -dm755 $out/{bin,lib,include/$dir}
+      install -m644 $dir/*.a "$out/lib"
+      install -m644 $dir/include/*.h* "$out/include/$dir"
+    done
+
+    runHook postInstall
+  '';
+
+  enableParallelBuilding = true;
+
+  passthru.tests = {
+    inherit vlc;
+  };
+
+  meta = with lib; {
+    homepage = "http://www.live555.com/liveMedia/";
+    description = "Set of C++ libraries for multimedia streaming, using open standard protocols (RTP/RTCP, RTSP, SIP)";
+    changelog = "http://www.live555.com/liveMedia/public/changelog.txt";
+    license = licenses.lgpl21Plus;
+    maintainers = with maintainers; [ AndersonTorres ];
+    platforms = platforms.unix;
+    broken = stdenv.hostPlatform.isAarch64;
+  };
+}