uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov
Alan Daniels
commit
56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
22
pkgs/development/libraries/vtk/7.x.nix
Normal file
22
pkgs/development/libraries/vtk/7.x.nix
Normal file
|
|
@ -0,0 +1,22 @@
|
|||
import ./generic.nix {
|
||||
majorVersion = "7.1";
|
||||
minorVersion = "1";
|
||||
sourceSha256 = "0nm7xwwj7rnsxjdv2ssviys8nhci4n9iiiqm2y14s520hl2dsp1d";
|
||||
patchesToFetch = [
|
||||
{
|
||||
url = "https://gitlab.kitware.com/vtk/vtk/-/commit/706f1b397df09a27ab8981ab9464547028d0c322.diff";
|
||||
sha256 = "1q3pi5h40g05pzpbqp75xlgzvbfvyw8raza51svmi7d8dlslqybx";
|
||||
}
|
||||
|
||||
{
|
||||
url = "https://gitweb.gentoo.org/repo/gentoo.git/plain/sci-libs/vtk/files/vtk-8.2.0-gcc-10.patch?id=c4256f68d3589570443075eccbbafacf661f785f";
|
||||
sha256 = "sha256:0bpwrdfmi15grsg4jy7bzj2z6511a0c160cmw5lsi65aabyh7cl5";
|
||||
}
|
||||
|
||||
# Add missing include required with recent Qt.
|
||||
{
|
||||
url = "https://gitlab.kitware.com/vtk/vtk/-/commit/797f28697d5ba50c1fa2bc5596af626a3c277826.diff";
|
||||
sha256 = "BFjoKws1hVD3Ly9RS4lGN62J6RTyI1E8ATHrZdzg7ds=";
|
||||
}
|
||||
];
|
||||
}
|
||||
18
pkgs/development/libraries/vtk/8.x.nix
Normal file
18
pkgs/development/libraries/vtk/8.x.nix
Normal file
|
|
@ -0,0 +1,18 @@
|
|||
import ./generic.nix {
|
||||
majorVersion = "8.2";
|
||||
minorVersion = "0";
|
||||
sourceSha256 = "1fspgp8k0myr6p2a6wkc21ldcswb4bvmb484m12mxgk1a9vxrhrl";
|
||||
patchesToFetch = [{
|
||||
url = "https://gitlab.kitware.com/vtk/vtk/-/commit/257b9d7b18d5f3db3fe099dc18f230e23f7dfbab.diff";
|
||||
sha256 = "0qdahp4f4gcaznr28j06d5fyxiis774ys0p335aazf7h51zb8rzy";
|
||||
}
|
||||
{
|
||||
url = "https://gitweb.gentoo.org/repo/gentoo.git/plain/sci-libs/vtk/files/vtk-8.2.0-gcc-10.patch?id=c4256f68d3589570443075eccbbafacf661f785f";
|
||||
sha256 = "sha256:0bpwrdfmi15grsg4jy7bzj2z6511a0c160cmw5lsi65aabyh7cl5";
|
||||
}
|
||||
{
|
||||
url = "https://gitlab.kitware.com/vtk/vtk/-/merge_requests/6943.diff";
|
||||
sha256 = "sha256:1nzdw3f6bsri04y528zj2klqkb9p8s4lnl9g5zvm119m1cmyhn04";
|
||||
}
|
||||
];
|
||||
}
|
||||
14
pkgs/development/libraries/vtk/9.x.nix
Normal file
14
pkgs/development/libraries/vtk/9.x.nix
Normal file
|
|
@ -0,0 +1,14 @@
|
|||
import ./generic.nix {
|
||||
majorVersion = "9.0";
|
||||
minorVersion = "3";
|
||||
sourceSha256 = "vD65Ylsrjb/stgUqKrCR/JFAXeQzOw7GjzMjgVFU7Yo=";
|
||||
|
||||
patchesToFetch = [
|
||||
# Add missing header includes.
|
||||
# https://gitlab.kitware.com/vtk/vtk/-/merge_requests/7611
|
||||
{
|
||||
url = "https://gitlab.kitware.com/vtk/vtk/-/commit/e066c3f4fbbfe7470c6207db0fc3f3952db633cb.patch";
|
||||
sha256 = "ggmDisS3qoMquOqrmIYlCIT7TLxP/DUtW29ktjaEnlM=";
|
||||
}
|
||||
];
|
||||
}
|
||||
111
pkgs/development/libraries/vtk/generic.nix
Normal file
111
pkgs/development/libraries/vtk/generic.nix
Normal file
|
|
@ -0,0 +1,111 @@
|
|||
{ majorVersion, minorVersion, sourceSha256, patchesToFetch ? [] }:
|
||||
{ stdenv, lib, fetchurl, cmake, libGLU, libGL, libX11, xorgproto, libXt, libpng, libtiff
|
||||
, fetchpatch
|
||||
, enableQt ? false, wrapQtAppsHook, qtbase, qtx11extras, qttools
|
||||
, enablePython ? false, pythonInterpreter ? throw "vtk: Python support requested, but no python interpreter was given."
|
||||
# Darwin support
|
||||
, Cocoa, CoreServices, DiskArbitration, IOKit, CFNetwork, Security, GLUT, OpenGL
|
||||
, ApplicationServices, CoreText, IOSurface, ImageIO, xpc, libobjc
|
||||
}:
|
||||
|
||||
let
|
||||
inherit (lib) optionalString optionals optional;
|
||||
|
||||
pythonMajor = lib.substring 0 1 pythonInterpreter.pythonVersion;
|
||||
|
||||
in stdenv.mkDerivation rec {
|
||||
pname = "vtk${optionalString enableQt "-qvtk"}";
|
||||
version = "${majorVersion}.${minorVersion}";
|
||||
|
||||
src = fetchurl {
|
||||
url = "https://www.vtk.org/files/release/${majorVersion}/VTK-${version}.tar.gz";
|
||||
sha256 = sourceSha256;
|
||||
};
|
||||
|
||||
nativeBuildInputs = [ cmake ];
|
||||
|
||||
buildInputs = [ libpng libtiff ]
|
||||
++ optionals enableQt [ qtbase qtx11extras qttools ]
|
||||
++ optionals stdenv.isLinux [
|
||||
libGLU
|
||||
libGL
|
||||
libX11
|
||||
xorgproto
|
||||
libXt
|
||||
] ++ optionals stdenv.isDarwin [
|
||||
xpc
|
||||
Cocoa
|
||||
CoreServices
|
||||
DiskArbitration
|
||||
IOKit
|
||||
CFNetwork
|
||||
Security
|
||||
ApplicationServices
|
||||
CoreText
|
||||
IOSurface
|
||||
ImageIO
|
||||
OpenGL
|
||||
GLUT
|
||||
] ++ optional enablePython [
|
||||
pythonInterpreter
|
||||
];
|
||||
propagatedBuildInputs = optionals stdenv.isDarwin [ libobjc ];
|
||||
|
||||
patches = map fetchpatch patchesToFetch;
|
||||
|
||||
preBuild = ''
|
||||
export LD_LIBRARY_PATH="$(pwd)/lib";
|
||||
'';
|
||||
|
||||
dontWrapQtApps = true;
|
||||
|
||||
# Shared libraries don't work, because of rpath troubles with the current
|
||||
# nixpkgs cmake approach. It wants to call a binary at build time, just
|
||||
# built and requiring one of the shared objects.
|
||||
# At least, we use -fPIC for other packages to be able to use this in shared
|
||||
# objects.
|
||||
cmakeFlags = [
|
||||
"-DCMAKE_C_FLAGS=-fPIC"
|
||||
"-DCMAKE_CXX_FLAGS=-fPIC"
|
||||
"-D${if lib.versionOlder version "9.0" then "VTK_USE_SYSTEM_PNG" else "VTK_MODULE_USE_EXTERNAL_vtkpng"}=ON"
|
||||
"-D${if lib.versionOlder version "9.0" then "VTK_USE_SYSTEM_TIFF" else "VTK_MODULE_USE_EXTERNAL_vtktiff"}=1"
|
||||
"-DOPENGL_INCLUDE_DIR=${libGL}/include"
|
||||
"-DCMAKE_INSTALL_LIBDIR=lib"
|
||||
"-DCMAKE_INSTALL_INCLUDEDIR=include"
|
||||
"-DCMAKE_INSTALL_BINDIR=bin"
|
||||
] ++ optionals enableQt [
|
||||
"-D${if lib.versionOlder version "9.0" then "VTK_Group_Qt:BOOL=ON" else "VTK_GROUP_ENABLE_Qt:STRING=YES"}"
|
||||
] ++ optionals (enableQt && lib.versionOlder version "8.0") [
|
||||
"-DVTK_QT_VERSION=5"
|
||||
]
|
||||
++ optionals stdenv.isDarwin [ "-DOPENGL_INCLUDE_DIR=${OpenGL}/Library/Frameworks" ]
|
||||
++ optionals enablePython [
|
||||
"-DVTK_WRAP_PYTHON:BOOL=ON"
|
||||
"-DVTK_PYTHON_VERSION:STRING=${pythonMajor}"
|
||||
];
|
||||
|
||||
postPatch = optionalString stdenv.isDarwin ''
|
||||
sed -i 's|COMMAND vtkHashSource|COMMAND "DYLD_LIBRARY_PATH=''${VTK_BINARY_DIR}/lib" ''${VTK_BINARY_DIR}/bin/vtkHashSource-${majorVersion}|' ./Parallel/Core/CMakeLists.txt
|
||||
sed -i 's/fprintf(output, shift)/fprintf(output, "%s", shift)/' ./ThirdParty/libxml2/vtklibxml2/xmlschemas.c
|
||||
sed -i 's/fprintf(output, shift)/fprintf(output, "%s", shift)/g' ./ThirdParty/libxml2/vtklibxml2/xpath.c
|
||||
'';
|
||||
|
||||
preFixup = ''
|
||||
for lib in $out/lib/libvtk*.so; do
|
||||
ln -s $lib $out/lib/"$(basename "$lib" | sed -e 's/-[[:digit:]]*.[[:digit:]]*//g')"
|
||||
done
|
||||
|
||||
mv $out/include/vtk-${majorVersion}/* $out/include
|
||||
rmdir $out/include/vtk-${majorVersion}
|
||||
ln -s $out/include $out/include/vtk-${majorVersion}
|
||||
'';
|
||||
|
||||
meta = with lib; {
|
||||
broken = stdenv.isDarwin;
|
||||
description = "Open source libraries for 3D computer graphics, image processing and visualization";
|
||||
homepage = "https://www.vtk.org/";
|
||||
license = licenses.bsd3;
|
||||
maintainers = with maintainers; [ knedlsepp tfmoraes lheckemann ];
|
||||
platforms = with platforms; unix;
|
||||
};
|
||||
}
|
||||
Loading…
Add table
Add a link
Reference in a new issue