uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/ocaml-modules/mirage-crypto/default.nix

@@ -0,0 +1,42 @@
+{ lib, fetchurl, buildDunePackage, ounit, cstruct, dune-configurator, eqaf, pkg-config
+, withFreestanding ? false
+, ocaml-freestanding
+}:
+
+buildDunePackage rec {
+  minimumOCamlVersion = "4.08";
+
+  pname = "mirage-crypto";
+  version = "0.10.5";
+
+  src = fetchurl {
+    url = "https://github.com/mirage/mirage-crypto/releases/download/v${version}/mirage-crypto-v${version}.tbz";
+    sha256 = "sha256-eeKMSRZrBiTzWLv80P5LeouPib24uTigk2HLtORKpJU=";
+  };
+
+  useDune2 = true;
+
+  doCheck = true;
+  checkInputs = [ ounit ];
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [ dune-configurator  ];
+  propagatedBuildInputs = [
+    cstruct eqaf
+  ] ++ lib.optionals withFreestanding [
+    ocaml-freestanding
+  ];
+
+  strictDeps = !doCheck;
+
+  meta = with lib; {
+    homepage = "https://github.com/mirage/mirage-crypto";
+    description = "Simple symmetric cryptography for the modern age";
+    license = [
+      licenses.isc  # default license
+      licenses.bsd2 # mirage-crypto-rng-mirage
+      licenses.mit  # mirage-crypto-ec
+    ];
+    maintainers = with maintainers; [ sternenseemann ];
+  };
+}

pkgs/development/ocaml-modules/mirage-crypto/ec.nix

@@ -0,0 +1,58 @@
+{ lib
+, ocaml
+, buildDunePackage
+, mirage-crypto
+, dune-configurator
+, pkg-config
+, cstruct
+, mirage-crypto-rng
+, mirage-crypto-pk
+, hex
+, alcotest
+, asn1-combinators
+, ppx_deriving_yojson
+, ppx_deriving
+, yojson
+, withFreestanding ? false
+, ocaml-freestanding
+}:
+
+buildDunePackage rec {
+  pname = "mirage-crypto-ec";
+
+  inherit (mirage-crypto)
+    minimumOCamlVersion
+    src
+    version
+    useDune2;
+
+  nativeBuildInputs = [ pkg-config ];
+  buildInputs = [
+    ocaml
+    dune-configurator
+  ];
+  propagatedBuildInputs = [
+    cstruct
+    mirage-crypto
+    mirage-crypto-rng
+  ] ++ lib.optionals withFreestanding [
+    ocaml-freestanding
+  ];
+
+  strictDeps = !doCheck;
+
+  doCheck = true;
+  checkInputs = [
+    hex
+    alcotest
+    asn1-combinators
+    ppx_deriving_yojson
+    ppx_deriving
+    yojson
+    mirage-crypto-pk
+  ];
+
+  meta = mirage-crypto.meta // {
+    description = "Elliptic Curve Cryptography with primitives taken from Fiat";
+  };
+}

pkgs/development/ocaml-modules/mirage-crypto/pk.nix

@@ -0,0 +1,21 @@
+{ buildDunePackage, ounit, randomconv, mirage-crypto, mirage-crypto-rng
+, cstruct, sexplib0, zarith, eqaf, gmp }:
+
+buildDunePackage rec {
+  pname = "mirage-crypto-pk";
+
+  inherit (mirage-crypto) version src useDune2 minimumOCamlVersion;
+
+  buildInputs = [ gmp ];
+  propagatedBuildInputs = [ cstruct mirage-crypto mirage-crypto-rng
+                            zarith eqaf sexplib0 ];
+
+  strictDeps = !doCheck;
+
+  doCheck = true;
+  checkInputs = [ ounit randomconv ];
+
+  meta = mirage-crypto.meta // {
+    description = "Simple public-key cryptography for the modern age";
+  };
+}

pkgs/development/ocaml-modules/mirage-crypto/rng-async.nix

@@ -0,0 +1,27 @@
+{ lib, buildDunePackage
+, mirage-crypto, mirage-crypto-rng
+, dune-configurator, async, logs
+}:
+
+buildDunePackage {
+  pname = "mirage-crypto-rng-async";
+
+  inherit (mirage-crypto) useDune2 version minimumOCamlVersion src;
+
+  buildInputs = [
+    dune-configurator
+  ];
+
+  propagatedBuildInputs = [
+    async
+    logs
+    mirage-crypto
+    mirage-crypto-rng
+  ];
+
+  strictDeps = true;
+
+  meta = mirage-crypto.meta // {
+    description = "Feed the entropy source in an Async-friendly way";
+  };
+}

pkgs/development/ocaml-modules/mirage-crypto/rng-mirage.nix

@@ -0,0 +1,22 @@
+{ buildDunePackage, mirage-crypto-rng, duration, cstruct, mirage-runtime
+, mirage-time, mirage-clock, mirage-unix, mirage-time-unix, mirage-clock-unix
+, logs, lwt
+}:
+
+buildDunePackage rec {
+  pname = "mirage-crypto-rng-mirage";
+
+  inherit (mirage-crypto-rng) version src useDune2 minimumOCamlVersion;
+
+  doCheck = true;
+  checkInputs = [ mirage-unix mirage-clock-unix mirage-time-unix ];
+
+  propagatedBuildInputs = [ duration cstruct mirage-crypto-rng mirage-runtime
+                            mirage-time mirage-clock logs lwt ];
+
+  strictDeps = !doCheck;
+
+  meta = mirage-crypto-rng.meta // {
+    description = "Entropy collection for a cryptographically secure PRNG";
+  };
+}

pkgs/development/ocaml-modules/mirage-crypto/rng.nix

@@ -0,0 +1,20 @@
+{ buildDunePackage, mirage-crypto, ounit, randomconv, dune-configurator
+, cstruct, duration, logs, mtime, ocaml_lwt }:
+
+buildDunePackage rec {
+  pname = "mirage-crypto-rng";
+
+  inherit (mirage-crypto) version src useDune2 minimumOCamlVersion;
+
+  doCheck = true;
+  checkInputs = [ ounit randomconv ];
+
+  buildInputs = [ dune-configurator ];
+  propagatedBuildInputs = [ cstruct mirage-crypto duration logs mtime ocaml_lwt ];
+
+  strictDeps = !doCheck;
+
+  meta = mirage-crypto.meta // {
+    description = "A cryptographically secure PRNG";
+  };
+}