uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/APScheduler/default.nix

@@ -0,0 +1,78 @@
+{ lib
+, stdenv
+, buildPythonPackage
+, fetchPypi
+, gevent
+, pytest-asyncio
+, pytest-tornado
+, pytestCheckHook
+, pythonOlder
+, pytz
+, setuptools
+, setuptools-scm
+, six
+, tornado
+, twisted
+, tzlocal
+}:
+
+buildPythonPackage rec {
+  pname = "apscheduler";
+  version = "3.9.1";
+  format = "setuptools";
+
+  disabled = pythonOlder "3.7";
+
+  src = fetchPypi {
+    pname = "APScheduler";
+    inherit version;
+    hash = "sha256-ZeZXS2OVSY03HQRfKop+T31Qxq0h73MT0VscfPIN8eM=";
+  };
+
+  buildInputs = [
+    setuptools-scm
+  ];
+
+  propagatedBuildInputs = [
+    pytz
+    setuptools
+    six
+    tzlocal
+  ];
+
+  checkInputs = [
+    gevent
+    pytest-asyncio
+    pytest-tornado
+    pytestCheckHook
+    tornado
+    twisted
+  ];
+
+  postPatch = ''
+    substituteInPlace setup.cfg \
+      --replace " --cov --tb=short" ""
+  '';
+
+  disabledTests = [
+    "test_broken_pool"
+    # gevent tests have issue on newer Python releases
+    "test_add_live_job"
+    "test_add_pending_job"
+    "test_shutdown"
+  ] ++ lib.optionals stdenv.isDarwin [
+    "test_submit_job"
+    "test_max_instances"
+  ];
+
+  pythonImportsCheck = [
+    "apscheduler"
+  ];
+
+  meta = with lib; {
+    description = "Library that lets you schedule your Python code to be executed";
+    homepage = "https://github.com/agronholm/apscheduler";
+    license = licenses.mit;
+    maintainers = with maintainers; [ ];
+  };
+}