uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/chainer/default.nix

@@ -0,0 +1,52 @@
+{ config, lib, buildPythonPackage, fetchFromGitHub, isPy3k
+, filelock, protobuf, numpy, pytestCheckHook, mock, typing-extensions
+, cupy, cudaSupport ? config.cudaSupport or false
+}:
+
+buildPythonPackage rec {
+  pname = "chainer";
+  version = "7.8.1";
+  disabled = !isPy3k; # python2.7 abandoned upstream
+
+  src = fetchFromGitHub {
+    owner = "chainer";
+    repo = "chainer";
+    rev = "v${version}";
+    sha256 = "1n07zjzc4g92m1sbgxvnansl0z00y4jnhma2mw06vnahs7s9nrf6";
+  };
+
+  propagatedBuildInputs = [
+    filelock
+    protobuf
+    numpy
+    typing-extensions
+  ] ++ lib.optionals cudaSupport [ cupy ];
+
+  checkInputs = [
+    pytestCheckHook
+    mock
+  ];
+
+  pytestFlagsArray = [ "tests/chainer_tests/utils_tests" ];
+
+  preCheck = ''
+    # cf. https://github.com/chainer/chainer/issues/8621
+    export CHAINER_WARN_VERSION_MISMATCH=0
+
+    # ignore pytest warnings not listed
+    rm setup.cfg
+  '';
+
+  disabledTests = [
+    "gpu"
+    "cupy"
+    "ideep"
+  ];
+
+  meta = with lib; {
+    description = "A flexible framework of neural networks for deep learning";
+    homepage = "https://chainer.org/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ hyphon81 ];
+  };
+}