uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/debugpy/default.nix

@@ -0,0 +1,111 @@
+{ lib
+, stdenv
+, buildPythonPackage
+, fetchFromGitHub
+, substituteAll
+, gdb
+, django
+, flask
+, gevent
+, psutil
+, pytest-timeout
+, pytest-xdist
+, pytestCheckHook
+, requests
+, isPy3k
+, pythonAtLeast
+}:
+
+buildPythonPackage rec {
+  pname = "debugpy";
+  version = "1.6.0";
+  format = "setuptools";
+
+  src = fetchFromGitHub {
+    owner = "Microsoft";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-WfZz2SimOTpG8CWNUic8NSp4Qd2JTXk+7JSUEPhuQ6Q=";
+  };
+
+  patches = [
+    # Hard code GDB path (used to attach to process)
+    (substituteAll {
+      src = ./hardcode-gdb.patch;
+      inherit gdb;
+    })
+
+    # Use nixpkgs version instead of versioneer
+    (substituteAll {
+      src = ./hardcode-version.patch;
+      inherit version;
+    })
+
+    # Fix importing debugpy in:
+    # - test_nodebug[module-launch(externalTerminal)]
+    # - test_nodebug[module-launch(integratedTerminal)]
+    #
+    # NOTE: The import failures seen in these tests without the patch
+    # will be seen if a user "installs" debugpy by adding it to PYTHONPATH.
+    # To avoid this issue, debugpy should be installed using python.withPackages:
+    # python.withPackages (ps: with ps; [ debugpy ])
+    ./fix-test-pythonpath.patch
+  ];
+
+  # Remove pre-compiled "attach" libraries and recompile for host platform
+  # Compile flags taken from linux_and_mac/compile_linux.sh & linux_and_mac/compile_mac.sh
+  preBuild = ''(
+    set -x
+    cd src/debugpy/_vendored/pydevd/pydevd_attach_to_process
+    rm *.so *.dylib *.dll *.exe *.pdb
+    ${stdenv.cc}/bin/c++ linux_and_mac/attach.cpp -Ilinux_and_mac -fPIC -nostartfiles ${{
+      "x86_64-linux"   = "-shared -m64 -o attach_linux_amd64.so";
+      "i686-linux"     = "-shared -m32 -o attach_linux_x86.so";
+      "aarch64-linux"  = "-shared -o attach_linux_arm64.so";
+      "x86_64-darwin"  = "-std=c++11 -lc -D_REENTRANT -dynamiclib -arch x86_64 -o attach_x86_64.dylib";
+      "i686-darwin"    = "-std=c++11 -lc -D_REENTRANT -dynamiclib -arch i386 -o attach_x86.dylib";
+      "aarch64-darwin" = "-std=c++11 -lc -D_REENTRANT -dynamiclib -arch arm64 -o attach_arm64.dylib";
+    }.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}")}
+  )'';
+
+  doCheck = isPy3k;
+
+  checkInputs = [
+    django
+    flask
+    gevent
+    psutil
+    pytest-timeout
+    pytest-xdist
+    pytestCheckHook
+    requests
+  ];
+
+  # Override default arguments in pytest.ini
+  pytestFlagsArray = [
+    "--timeout=0"
+  ];
+
+  disabledTests = lib.optionals (pythonAtLeast "3.10") [
+    "test_flask_breakpoint_multiproc"
+    "test_subprocess[program-launch-None]"
+    "test_systemexit[0-zero-uncaught-raised-launch(integratedTerminal)-module]"
+    "test_systemexit[0-zero-uncaught--attach_pid-program]"
+    "test_success_exitcodes[-break_on_system_exit_zero-0-attach_listen(cli)-module]"
+    "test_success_exitcodes[--0-attach_connect(api)-program]"
+    "test_run[code-attach_connect(api)]"
+    "test_subprocess[program-launch-None]"
+  ];
+
+  pythonImportsCheck = [
+    "debugpy"
+  ];
+
+  meta = with lib; {
+    description = "An implementation of the Debug Adapter Protocol for Python";
+    homepage = "https://github.com/microsoft/debugpy";
+    license = licenses.mit;
+    maintainers = with maintainers; [ kira-bruneau ];
+    platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "x86_64-darwin" "i686-darwin" "aarch64-darwin" ];
+  };
+}

pkgs/development/python-modules/debugpy/fix-test-pythonpath.patch

@@ -0,0 +1,12 @@
+diff --git a/tests/debug/session.py b/tests/debug/session.py
+index 101492fc..4ee7cfbe 100644
+--- a/tests/debug/session.py
++++ b/tests/debug/session.py
+@@ -630,6 +630,7 @@ class Session(object):
+         if "PYTHONPATH" in self.config.env:
+             # If specified, launcher will use it in lieu of PYTHONPATH it inherited
+             # from the adapter when spawning debuggee, so we need to adjust again.
++            self.config.env.prepend_to("PYTHONPATH", os.environ["PYTHONPATH"])
+             self.config.env.prepend_to("PYTHONPATH", DEBUGGEE_PYTHONPATH.strpath)
+         return self._request_start("launch")
+ 

pkgs/development/python-modules/debugpy/hardcode-gdb.patch

@@ -0,0 +1,13 @@
+diff --git a/src/debugpy/_vendored/pydevd/pydevd_attach_to_process/add_code_to_python_process.py b/src/debugpy/_vendored/pydevd/pydevd_attach_to_process/add_code_to_python_process.py
+index 3c0e1b94..e995a20f 100644
+--- a/src/debugpy/_vendored/pydevd/pydevd_attach_to_process/add_code_to_python_process.py
++++ b/src/debugpy/_vendored/pydevd/pydevd_attach_to_process/add_code_to_python_process.py
+@@ -399,7 +399,7 @@ def run_python_code_linux(pid, python_code, connect_debugger_tracing=False, show
+     is_debug = 0
+     # Note that the space in the beginning of each line in the multi-line is important!
+     cmd = [
+-        'gdb',
++        '@gdb@/bin/gdb',
+         '--nw',  # no gui interface
+         '--nh',  # no ~/.gdbinit
+         '--nx',  # no .gdbinit

pkgs/development/python-modules/debugpy/hardcode-version.patch

@@ -0,0 +1,49 @@
+diff --git a/setup.py b/setup.py
+index e7487100..10d36520 100644
+--- a/setup.py
++++ b/setup.py
+@@ -12,7 +12,6 @@ import sys
+ 
+ 
+ sys.path.insert(0, os.path.dirname(os.path.abspath(__file__)))
+-import versioneer  # noqa
+ 
+ del sys.path[0]
+ 
+@@ -141,13 +140,13 @@ if __name__ == "__main__":
+     if platforms is not None:
+         extras["platforms"] = platforms
+ 
+-    cmds = versioneer.get_cmdclass()
++    cmds = {}
+     override_build(cmds)
+     override_build_py(cmds)
+ 
+     setuptools.setup(
+         name="debugpy",
+-        version=versioneer.get_version(),
++        version="@version@",
+         description="An implementation of the Debug Adapter Protocol for Python",  # noqa
+         long_description=long_description,
+         long_description_content_type="text/markdown",
+diff --git a/src/debugpy/__init__.py b/src/debugpy/__init__.py
+index baa5a7c5..53553272 100644
+--- a/src/debugpy/__init__.py
++++ b/src/debugpy/__init__.py
+@@ -27,7 +27,6 @@ __all__ = [
+ import codecs
+ import os
+ 
+-from debugpy import _version
+ from debugpy.common import compat
+ 
+ 
+@@ -204,7 +203,7 @@ def trace_this_thread(should_trace):
+     return api.trace_this_thread(should_trace)
+ 
+ 
+-__version__ = _version.get_versions()["version"]
++__version__ = "@version@"
+ 
+ # Force absolute path on Python 2.
+ __file__ = os.path.abspath(__file__)