uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/json-schema-for-humans/default.nix

@@ -0,0 +1,79 @@
+{ lib
+, beautifulsoup4
+, buildPythonPackage
+, click
+, dataclasses
+, dataclasses-json
+, fetchFromGitHub
+, htmlmin
+, jinja2
+, markdown2
+, poetry-core
+, pygments
+, pytestCheckHook
+, pythonOlder
+, pytz
+, pyyaml
+, requests
+}:
+
+buildPythonPackage rec {
+  pname = "json-schema-for-humans";
+  version = "0.41.1";
+  format = "pyproject";
+
+  disabled = pythonOlder "3.6";
+
+  src = fetchFromGitHub {
+    owner = "coveooss";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-JQqoQiug4n1o4PbGT/Ry/Qib11KmaTmkhPtZjhwmpc4=";
+  };
+
+  postPatch = ''
+    substituteInPlace pyproject.toml \
+      --replace 'pytz = "^2021.1"' 'pytz = "*"'
+  '';
+
+  nativeBuildInputs = [
+    poetry-core
+  ];
+
+  propagatedBuildInputs = [
+    click
+    dataclasses-json
+    htmlmin
+    jinja2
+    markdown2
+    pygments
+    pytz
+    pyyaml
+    requests
+  ] ++ lib.optionals (pythonOlder "3.7") [
+    dataclasses
+  ];
+
+  checkInputs = [
+    beautifulsoup4
+    pytestCheckHook
+  ];
+
+  disabledTests = [
+    # Tests require network access
+    "test_references_url"
+    # Tests are failing
+    "TestMdGenerate"
+  ];
+
+  pythonImportsCheck = [
+    "json_schema_for_humans"
+  ];
+
+  meta = with lib; {
+    description = "Quickly generate HTML documentation from a JSON schema";
+    homepage = "https://github.com/coveooss/json-schema-for-humans";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ astro ];
+  };
+}