uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/jupytext/default.nix

@@ -0,0 +1,85 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, GitPython
+, isort
+, jupyter-client
+, jupyter-packaging
+, jupyterlab
+, markdown-it-py
+, mdit-py-plugins
+, nbformat
+, notebook
+, pytestCheckHook
+, pythonOlder
+, pyyaml
+, toml
+}:
+
+buildPythonPackage rec {
+  pname = "jupytext";
+  version = "1.13.8";
+  format = "pyproject";
+
+  disabled = pythonOlder "3.6";
+
+  src = fetchFromGitHub {
+    owner = "mwouts";
+    repo = pname;
+    rev = "refs/tags/v${version}";
+    sha256 = "sha256-ebe5sQJxA8QE6eJp6vPUyMaEvZUPqzCmQ6damzo1BVo=";
+  };
+
+  buildInputs = [
+    jupyter-packaging
+    jupyterlab
+  ];
+
+  propagatedBuildInputs = [
+    markdown-it-py
+    mdit-py-plugins
+    nbformat
+    pyyaml
+    toml
+  ];
+
+  checkInputs = [
+    GitPython
+    isort
+    jupyter-client
+    notebook
+    pytestCheckHook
+  ];
+
+  postPatch = ''
+    # https://github.com/mwouts/jupytext/pull/885
+    substituteInPlace setup.py \
+      --replace "markdown-it-py~=1.0" "markdown-it-py>=1.0.0,<3.0.0"
+  '';
+
+  preCheck = ''
+    # Tests that use a Jupyter notebook require $HOME to be writable
+    export HOME=$(mktemp -d);
+  '';
+
+  pytestFlagsArray = [
+    # Pre-commit tests expect the source directory to be a Git repository
+    "--ignore-glob='tests/test_pre_commit_*.py'"
+  ];
+
+  disabledTests = [
+    "test_apply_black_through_jupytext" # we can't do anything about ill-formatted notebooks
+  ];
+
+  pythonImportsCheck = [
+    "jupytext"
+    "jupytext.cli"
+  ];
+
+  meta = with lib; {
+    description = "Jupyter notebooks as Markdown documents, Julia, Python or R scripts";
+    homepage = "https://github.com/mwouts/jupytext";
+    license = licenses.mit;
+    maintainers = with maintainers; [ timokau ];
+  };
+}