uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/llvmlite/default.nix

@@ -0,0 +1,54 @@
+{ lib
+, stdenv
+, fetchPypi
+, buildPythonPackage
+, python
+, llvm
+, pythonOlder
+, isPyPy
+, enum34
+, isPy3k
+}:
+
+buildPythonPackage rec {
+  pname = "llvmlite";
+  version = "0.38.0";
+
+  disabled = isPyPy || !isPy3k;
+
+  src = fetchPypi {
+    inherit pname version;
+    sha256 = "a99d166ccf3b116f3b9ed23b9b70ba2415640a9c978f3aaa13fad49c58f4965c";
+  };
+
+  nativeBuildInputs = [ llvm ];
+  propagatedBuildInputs = lib.optional (pythonOlder "3.4") enum34;
+
+  # Disable static linking
+  # https://github.com/numba/llvmlite/issues/93
+  postPatch = ''
+    substituteInPlace ffi/Makefile.linux --replace "-static-libstdc++" ""
+
+    substituteInPlace llvmlite/tests/test_binding.py --replace "test_linux" "nope"
+  '';
+
+  # Set directory containing llvm-config binary
+  preConfigure = ''
+    export LLVM_CONFIG=${llvm.dev}/bin/llvm-config
+  '';
+
+  checkPhase = ''
+    ${python.executable} runtests.py
+  '';
+
+  __impureHostDeps = lib.optionals stdenv.isDarwin [ "/usr/lib/libm.dylib" ];
+
+  passthru.llvm = llvm;
+
+  meta = with lib; {
+    description = "A lightweight LLVM python binding for writing JIT compilers";
+    homepage = "http://llvmlite.pydata.org/";
+    license = licenses.bsd2;
+    maintainers = with maintainers; [ fridh ];
+  };
+}