uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/numpydoc/default.nix

@@ -0,0 +1,58 @@
+{ lib
+, buildPythonPackage
+, fetchPypi
+, isPy27
+, jinja2
+, sphinx
+, pytestCheckHook
+, matplotlib
+}:
+
+buildPythonPackage rec {
+  pname = "numpydoc";
+  version = "1.2.1";
+  format = "setuptools";
+
+  disabled = isPy27;
+
+  src = fetchPypi {
+    inherit pname;
+    inherit version;
+    sha256 = "sha256-fOgm7Q1Uw/3JCXmSqNc6TUWdxGhhE1HGjkRP7ESkWvY=";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "Jinja2>=2.10,<3.1" "Jinja2>=2.10,<3.2"
+    substituteInPlace setup.cfg \
+      --replace "--cov-report=" "" \
+      --replace "--cov=numpydoc" ""
+  '';
+
+  propagatedBuildInputs = [
+    jinja2
+    sphinx
+  ];
+
+  checkInputs = [
+    matplotlib
+    pytestCheckHook
+  ];
+
+  disabledTests = [
+    # https://github.com/numpy/numpydoc/issues/373
+    "test_MyClass"
+    "test_my_function"
+    "test_reference"
+  ];
+
+  pythonImportsCheck = [
+    "numpydoc"
+  ];
+
+  meta = {
+    description = "Sphinx extension to support docstrings in Numpy format";
+    homepage = "https://github.com/numpy/numpydoc";
+    license = lib.licenses.free;
+   };
+}