uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948 this can do it nicely. Signed-off-by: Anton Arapov <anton@deadbeef.mx>
2021-04-03 12:58:10 +02:00 · 2021-04-03 12:58:10 +02:00 · 56de2bcd43
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
--- a/pkgs/development/python-modules/openstacksdk/default.nix
+++ b/pkgs/development/python-modules/openstacksdk/default.nix
@ -0,0 +1,64 @@
+{ lib
+, buildPythonPackage
+, callPackage
+, fetchPypi
+, appdirs
+, cryptography
+, dogpile-cache
+, jmespath
+, jsonpatch
+, keystoneauth1
+, munch
+, netifaces
+, os-service-types
+, pbr
+, pythonOlder
+, pyyaml
+, requestsexceptions
+}:
+
+buildPythonPackage rec {
+  pname = "openstacksdk";
+  version = "0.99.0";
+  format = "setuptools";
+
+  disabled = pythonOlder "3.6";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-P3PDzCgInpOzQut/NIsoX1pl/+UFiYvhXbJQx1u4Ves=";
+  };
+
+  propagatedBuildInputs = [
+    appdirs
+    cryptography
+    dogpile-cache
+    jmespath
+    jsonpatch
+    keystoneauth1
+    munch
+    netifaces
+    os-service-types
+    pbr
+    requestsexceptions
+    pyyaml
+  ];
+
+  # Checks moved to 'passthru.tests' to workaround slowness
+  doCheck = false;
+
+  passthru.tests = {
+    tests = callPackage ./tests.nix { };
+  };
+
+  pythonImportsCheck = [
+    "openstack"
+  ];
+
+  meta = with lib; {
+    description = "An SDK for building applications to work with OpenStack";
+    homepage = "https://github.com/openstack/openstacksdk";
+    license = licenses.asl20;
+    maintainers = teams.openstack.members;
+  };
+}
--- a/pkgs/development/python-modules/openstacksdk/tests.nix
+++ b/pkgs/development/python-modules/openstacksdk/tests.nix
@ -0,0 +1,65 @@
+{ buildPythonPackage
+, ddt
+, hacking
+, jsonschema
+, lib
+, openstacksdk
+, oslo-config
+, oslotest
+, prometheus-client
+, requests-mock
+, stdenv
+, stestr
+, testscenarios
+}:
+
+buildPythonPackage rec {
+  pname = "openstacksdk-tests";
+  inherit (openstacksdk) version;
+
+  src = openstacksdk.src;
+
+  dontBuild = true;
+  dontInstall = true;
+
+  checkInputs = [
+    ddt
+    hacking
+    jsonschema
+    openstacksdk
+    oslo-config
+    oslotest
+    prometheus-client
+    requests-mock
+    stestr
+    testscenarios
+  ];
+
+  checkPhase =
+    let aarch64TestsExcluded = lib.optionalString stdenv.hostPlatform.isAarch64 ''
+      openstack.tests.unit.cloud.test_baremetal_node.TestBaremetalNode.test_node_set_provision_state_with_retries
+      openstack.tests.unit.cloud.test_role_assignment.TestRoleAssignment.test_grant_role_user_domain_exists
+      openstack.tests.unit.cloud.test_volume_backups.TestVolumeBackups.test_delete_volume_backup_force
+      openstack.tests.unit.object_store.v1.test_proxy.TestTempURLBytesPathAndKey.test_set_account_temp_url_key_second
+      openstack.tests.unit.cloud.test_security_groups.TestSecurityGroups.test_delete_security_group_neutron_not_found
+    ''; in
+    ''
+      stestr run -e <(echo "${aarch64TestsExcluded}
+      openstack.tests.unit.cloud.test_baremetal_node.TestBaremetalNode.test_wait_for_baremetal_node_lock_locked
+      openstack.tests.unit.cloud.test_baremetal_node.TestBaremetalNode.test_inspect_machine_inspect_failed
+      openstack.tests.unit.cloud.test_baremetal_node.TestBaremetalNode.test_inspect_machine_available_wait
+      openstack.tests.unit.cloud.test_baremetal_node.TestBaremetalNode.test_inspect_machine_wait
+      openstack.tests.unit.cloud.test_image.TestImage.test_create_image_task
+      openstack.tests.unit.image.v2.test_proxy.TestImageProxy.test_wait_for_task_error_396
+      openstack.tests.unit.image.v2.test_proxy.TestImageProxy.test_wait_for_task_wait
+      openstack.tests.unit.test_resource.TestWaitForStatus.test_status_fails
+      openstack.tests.unit.test_resource.TestWaitForStatus.test_status_fails_different_attribute
+      openstack.tests.unit.test_resource.TestWaitForStatus.test_status_match
+      openstack.tests.unit.test_resource.TestWaitForStatus.test_status_match_with_none
+      openstack.tests.unit.test_stats.TestStats.test_list_projects
+      openstack.tests.unit.test_stats.TestStats.test_projects
+      openstack.tests.unit.test_stats.TestStats.test_servers
+      openstack.tests.unit.test_stats.TestStats.test_servers_no_detail
+      ")
+    '';
+}