uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/uvicorn/default.nix

@@ -0,0 +1,76 @@
+{ lib
+, buildPythonPackage
+, callPackage
+, fetchFromGitHub
+, asgiref
+, click
+, colorama
+, h11
+, httptools
+, python-dotenv
+, pyyaml
+, typing-extensions
+, uvloop
+, watchgod
+, websockets
+, wsproto
+, pythonOlder
+}:
+
+buildPythonPackage rec {
+  pname = "uvicorn";
+  version = "0.17.6";
+  disabled = pythonOlder "3.6";
+
+  src = fetchFromGitHub {
+    owner = "encode";
+    repo = pname;
+    rev = version;
+    hash = "sha256-iJlAU7zZl9X3FcQlJoJ7KlETZOx6WsE9FcpCK4Cm/Fo=";
+  };
+
+  outputs = [
+    "out"
+    "testsout"
+  ];
+
+  propagatedBuildInputs = [
+    asgiref
+    click
+    colorama
+    h11
+    httptools
+    python-dotenv
+    pyyaml
+    uvloop
+    watchgod
+    websockets
+    wsproto
+  ] ++ lib.optionals (pythonOlder "3.8") [
+    typing-extensions
+  ];
+
+  postInstall = ''
+    mkdir $testsout
+    cp -R tests $testsout/tests
+  '';
+
+  pythonImportsCheck = [
+    "uvicorn"
+  ];
+
+  # check in passthru.tests.pytest to escape infinite recursion with httpx/httpcore
+  doCheck = false;
+
+  passthru.tests = {
+    pytest = callPackage ./tests.nix { };
+  };
+
+  meta = with lib; {
+    homepage = "https://www.uvicorn.org/";
+    changelog = "https://github.com/encode/uvicorn/blob/${src.rev}/CHANGELOG.md";
+    description = "The lightning-fast ASGI server";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [ wd15 ];
+  };
+}

pkgs/development/python-modules/uvicorn/tests.nix

@@ -0,0 +1,40 @@
+{ stdenv
+, buildPythonPackage
+, uvicorn
+, httpx
+, pytest-asyncio
+, pytestCheckHook
+, pytest-mock
+, requests
+, trustme
+}:
+
+buildPythonPackage rec {
+  pname = "uvicorn-tests";
+  inherit (uvicorn) version;
+
+  src = uvicorn.testsout;
+
+  dontBuild = true;
+  dontInstall = true;
+
+  checkInputs = [
+    uvicorn
+    httpx
+    pytestCheckHook
+    pytest-asyncio
+    pytest-mock
+    requests
+    trustme
+  ];
+
+  doCheck = !stdenv.isDarwin;
+
+  __darwinAllowLocalNetworking = true;
+
+  disabledTests = [
+    "test_supported_upgrade_request"
+    "test_invalid_upgrade"
+  ];
+}
+