uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/python-modules/vowpalwabbit/default.nix

@@ -0,0 +1,75 @@
+{ stdenv
+, lib
+, fetchPypi
+, buildPythonPackage
+, cmake
+, python
+, zlib
+, ncurses
+, docutils
+, pygments
+, numpy
+, scipy
+, scikit-learn
+, spdlog
+, fmt
+, rapidjson
+}:
+
+buildPythonPackage rec {
+  pname = "vowpalwabbit";
+  version = "9.0.1";
+
+  src = fetchPypi{
+    inherit pname version;
+    sha256 = "sha256-rDUgOjroY8S73+s+MWyBl86u+8XCH4O8KMCo9zUlqAs=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    docutils
+    ncurses
+    pygments
+    python.pkgs.boost
+    zlib.dev
+    spdlog
+    fmt
+    rapidjson
+  ];
+
+  # As we disable configure via cmake, pass explicit global options to enable
+  # spdlog and fmt packages
+  setupPyGlobalFlags = [ "--cmake-options=\"-DSPDLOG_SYS_DEP=ON;-DFMT_SYS_DEP=ON\"" ];
+
+  propagatedBuildInputs = [
+    numpy
+    scikit-learn
+    scipy
+  ];
+
+  # Python build script uses CMake, but we don't want CMake to do the
+  # configuration.
+  dontUseCmakeConfigure = true;
+
+  # Python ctypes.find_library uses DYLD_LIBRARY_PATH.
+  preConfigure = lib.optionalString stdenv.isDarwin ''
+    export DYLD_LIBRARY_PATH="${python.pkgs.boost}/lib"
+  '';
+
+  checkPhase = ''
+    # check-manifest requires a git clone, not a tarball
+    # check-manifest --ignore "Makefile,PACKAGE.rst,*.cc,tox.ini,tests*,examples*,src*"
+    ${python.interpreter} setup.py check -ms
+  '';
+
+  meta = with lib; {
+    description = "Vowpal Wabbit is a fast machine learning library for online learning, and this is the python wrapper for the project.";
+    homepage    = "https://github.com/JohnLangford/vowpal_wabbit";
+    license     = licenses.bsd3;
+    broken      = stdenv.isAarch64;
+    maintainers = with maintainers; [ teh ];
+  };
+}