aland/nixpkgs-odroid-hc4
1
0
Fork 0
Code Issues Pull requests Projects Releases Packages Wiki Activity Actions 2

uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

Browse source 
https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>
This commit is contained in:
Anton Arapov 2021-04-03 12:58:10 +02:00 • committed by Alan Daniels
commit 56de2bcd43
30691 changed files with 3076956 additions and 0 deletions
Download patch file Download diff file Expand all files Collapse all files

60
pkgs/development/tools/continuous-integration/gitlab-runner/default.nix Normal file
View file

@ -0,0 +1,60 @@
{ lib, buildGoModule, fetchFromGitLab, fetchurl }:
let
version = "15.0.0";
in
buildGoModule rec {
inherit version;
pname = "gitlab-runner";
commonPackagePath = "gitlab.com/gitlab-org/gitlab-runner/common";
ldflags = [
"-X ${commonPackagePath}.NAME=gitlab-runner"
"-X ${commonPackagePath}.VERSION=${version}"
"-X ${commonPackagePath}.REVISION=v${version}"
];
vendorSha256 = "0ag3pmcrxksgikdcvl9rv2s3kn7l0dj41pf2m9dq0g2a1j45nydn";
src = fetchFromGitLab {
owner = "gitlab-org";
repo = "gitlab-runner";
rev = "v${version}";
sha256 = "1s7jqhrwy5wl0db37d3pms499mmy7msx4ch46w5qa25nfbxcr07c";
};
patches = [
./fix-shell-path.patch
./remove-bash-test.patch
];
prePatch = ''
# Remove some tests that can't work during a nix build
# Requires to run in a git repo
sed -i "s/func TestCacheArchiverAddingUntrackedFiles/func OFF_TestCacheArchiverAddingUntrackedFiles/" commands/helpers/file_archiver_test.go
sed -i "s/func TestCacheArchiverAddingUntrackedUnicodeFiles/func OFF_TestCacheArchiverAddingUntrackedUnicodeFiles/" commands/helpers/file_archiver_test.go
# No writable developer environment
rm common/build_test.go
rm executors/custom/custom_test.go
# No docker during build
rm executors/docker/terminal_test.go
rm executors/docker/docker_test.go
rm helpers/docker/auth/auth_test.go
'';
preCheck = ''
# Make the tests pass outside of GitLab CI
export CI=0
'';
meta = with lib; {
description = "GitLab Runner the continuous integration executor of GitLab";
license = licenses.mit;
homepage = "https://about.gitlab.com/gitlab-ci/";
platforms = platforms.unix ++ platforms.darwin;
maintainers = with maintainers; [ bachp zimbatm globin yayayayaka ];
};
}