uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/tools/yq-go/default.nix

@@ -0,0 +1,39 @@
+{ lib, buildGoModule, fetchFromGitHub, installShellFiles, runCommand, yq-go }:
+
+buildGoModule rec {
+  pname = "yq-go";
+  version = "4.25.2";
+
+  src = fetchFromGitHub {
+    owner = "mikefarah";
+    repo = "yq";
+    rev = "v${version}";
+    sha256 = "sha256-yvFh1wPOsmQLGTLrMG7dwcEukFpelP183Xa2n2XiHlQ=";
+  };
+
+  vendorSha256 = "sha256-oUpHK6YKjKWTGL2yC1q2hK/K/gK8I+FwTVshTxHBOKI=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = ''
+    for shell in bash fish zsh; do
+      $out/bin/yq shell-completion $shell > yq.$shell
+      installShellCompletion yq.$shell
+    done
+  '';
+
+  passthru.tests = {
+    simple = runCommand "${pname}-test" {} ''
+      echo "test: 1" | ${yq-go}/bin/yq eval -j > $out
+      [ "$(cat $out | tr -d $'\n ')" = '{"test":1}' ]
+    '';
+  };
+
+  meta = with lib; {
+    description = "Portable command-line YAML processor";
+    homepage = "https://mikefarah.gitbook.io/yq/";
+    license = [ licenses.mit ];
+    maintainers = [ maintainers.lewo ];
+    mainProgram = "yq";
+  };
+}