uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/web/grails/default.nix

@@ -0,0 +1,52 @@
+{ lib, stdenv, fetchurl, unzip
+# If jdk is null, require JAVA_HOME in runtime environment, else store
+# JAVA_HOME=${jdk.home} into grails.
+, jdk ? null
+, coreutils, ncurses, gnused, gnugrep  # for purity
+}:
+
+let
+  binpath = lib.makeBinPath
+    ([ coreutils ncurses gnused gnugrep ] ++ lib.optional (jdk != null) jdk);
+in
+stdenv.mkDerivation rec {
+  pname = "grails";
+  version = "5.1.6";
+
+  src = fetchurl {
+    url = "https://github.com/grails/grails-core/releases/download/v${version}/grails-${version}.zip";
+    sha256 = "sha256-H4c/Nu6iOgaRLl/uV51nYnNQg5p9cjl/taexZnl4t+I=";
+  };
+
+  nativeBuildInputs = [ unzip ];
+
+  dontBuild = true;
+
+  installPhase = ''
+    mkdir -p "$out"
+    cp -vr . "$out"
+    # Remove (for now) uneeded Windows .bat files
+    rm -f "$out"/bin/*.bat
+    # Improve purity
+    sed -i -e '2iPATH=${binpath}:\$PATH' "$out"/bin/grails
+  '' + lib.optionalString (jdk != null) ''
+    # Inject JDK path into grails
+    sed -i -e '2iJAVA_HOME=${jdk.home}' "$out"/bin/grails
+  '';
+
+  preferLocalBuild = true;
+
+  meta = with lib; {
+    description = "Full stack, web application framework for the JVM";
+    longDescription = ''
+      Grails is an Open Source, full stack, web application framework for the
+      JVM. It takes advantage of the Groovy programming language and convention
+      over configuration to provide a productive and stream-lined development
+      experience.
+    '';
+    homepage = "https://grails.org/";
+    license = licenses.asl20;
+    platforms = platforms.linux;
+    maintainers = [ maintainers.bjornfor ];
+  };
+}