uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/development/web/protege-distribution/default.nix

@@ -0,0 +1,76 @@
+{ lib, stdenv, fetchurl, unzip, jre8
+, copyDesktopItems
+, makeDesktopItem
+, iconConvTools
+}:
+
+stdenv.mkDerivation rec {
+  pname = "protege-distribution";
+  version = "5.5.0";
+
+  src = fetchurl {
+    url = "https://github.com/protegeproject/protege-distribution/releases/download/v${version}/Protege-${version}-platform-independent.zip";
+    sha256 = "092x22wyisdnhccx817mqq15sxqdfc7iz4whr4mbvzrd9di6ipjq";
+  };
+
+  nativeBuildInputs = [ unzip copyDesktopItems iconConvTools ];
+
+  patches = [
+    # Replace logic for searching the install directory with a static cd into $out
+    ./static-path.patch
+    # Disable console logging, maintaining only file-based logging
+    ./disable-console-log.patch
+  ];
+
+  postPatch = ''
+    # Resolve @out@ (introduced by "static-path.patch") to $out, and set the
+    # correct Java executable (Protege is a JRE 8 application)
+    substituteInPlace run.sh \
+      --subst-var-by out $out \
+      --replace "java -X" "exec ${jre8.outPath}/bin/java -X"
+  '';
+
+  dontConfigure = true;
+  dontBuild = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir $out
+
+    # Delete non-Linux launch scripts
+    rm run.{bat,command}
+
+    # Move launch script into /bin, giving it a recognizable name
+    install -D run.sh $out/bin/run-protege
+
+    # Generate and copy icons to where they can be found
+    icoFileToHiColorTheme app/Protege.ico protege $out
+
+    # Move everything else under protege/
+    mkdir $out/protege
+    mv {bin,bundles,conf,plugins} $out/protege
+
+    runHook postInstall
+  '';
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "Protege";
+      desktopName = "Protege Desktop";
+      icon = "protege";
+      comment = "OWL2 ontology editor";
+      categories = [ "Development" ];
+      exec = "run-protege";
+    })
+  ];
+
+  meta = with lib; {
+    description = "The OWL2 ontology editor from Stanford, with third-party plugins included";
+    homepage = "https://protege.stanford.edu/";
+    downloadPage = "https://protege.stanford.edu/products.php#desktop-protege";
+    maintainers = with maintainers; [ nessdoor ];
+    license = with licenses; [ asl20 bsd2 epl10 lgpl3 ];
+    platforms = platforms.linux;
+  };
+}

pkgs/development/web/protege-distribution/disable-console-log.patch

@@ -0,0 +1,28 @@
+--- a/conf/logback.xml	2021-06-25 00:49:10.446416341 +0900
++++ b/conf/logback.xml	2021-06-25 00:50:32.889120465 +0900
+@@ -1,13 +1,6 @@
+ <?xml version="1.0" encoding="UTF-8"?>
+ <configuration scan="true" scanPeriod="10 seconds">
+ 
+-    <appender name="stdout" class="ch.qos.logback.core.ConsoleAppender">
+-        <encoder class="ch.qos.logback.classic.encoder.PatternLayoutEncoder">
+-            <Pattern>%highlight(%msg) %n</Pattern>
+-        </encoder>
+-    </appender>
+-
+-
+     <appender name="files" class="ch.qos.logback.core.FileAppender">
+         <file>${user.home}/.Protege/logs/protege.log</file>
+         <append>true</append>
+@@ -18,9 +11,8 @@
+ 
+ 
+     <root level="info">
+-        <appender-ref ref="stdout" />
+         <appender-ref ref="files"/>
+     </root>
+ 
+ 
+-</configuration>
+\ No newline at end of file
++</configuration>

pkgs/development/web/protege-distribution/static-path.patch

@@ -0,0 +1,16 @@
+--- a/run.sh	2021-06-24 22:30:20.764897745 +0900
++++ b/run.sh	2021-06-24 22:29:47.211210142 +0900
+@@ -1,12 +1,6 @@
+ #!/usr/bin/env bash
+ 
+-SOURCE="${BASH_SOURCE[0]}"
+-while [ -h "$SOURCE" ]; do # resolve $SOURCE until the file is no longer a symlink
+-  DIR="$( cd -P "$( dirname "$SOURCE" )" && pwd )"
+-  SOURCE="$(readlink "$SOURCE")"
+-  [[ $SOURCE != /* ]] && SOURCE="$DIR/$SOURCE" # if $SOURCE was a relative symlink, we need to resolve it relative to the path where the symlink file was located
+-done
+-cd "$( cd -P "$( dirname "$SOURCE" )" && pwd )"
++cd @out@/protege
+ 
+ java -Xmx500M -Xms200M \
+      -Xss16M \