uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/games/quake3/content/demo.nix

@@ -0,0 +1,29 @@
+{ lib, stdenv, fetchurl }:
+
+let
+  version = "1.11-6";
+in stdenv.mkDerivation {
+  pname = "quake3-demodata";
+  inherit version;
+
+  src = fetchurl {
+    url = "https://ftp.gwdg.de/pub/misc/ftp.idsoftware.com/idstuff/quake3/linux/linuxq3ademo-${version}.x86.gz.sh";
+    sha256 = "1v54a1hx1bczk9hgn9qhx8vixsy7xn7wj2pylhfjsybfkgvf7pk4";
+  };
+
+  buildCommand = ''
+    tail -n +165 $src | tar xfz -
+
+    mkdir -p $out/baseq3
+    cp demoq3/*.pk3 $out/baseq3
+  '';
+
+  preferLocalBuild = true;
+
+  meta = with lib; {
+    description = "Quake 3 Arena demo content";
+    license = licenses.unfreeRedistributable;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ abbradar ];
+  };
+}

pkgs/games/quake3/content/hires.nix

@@ -0,0 +1,26 @@
+{ stdenv, lib, fetchzip }:
+
+stdenv.mkDerivation {
+  pname = "quake3hires";
+  version = "2020-01-20"; # Unknown version, used the date of web.archive.org capture.
+
+  src = fetchzip {
+    url = "https://web.archive.org/web/20200120024216/http://ioquake3.org/files/xcsv_hires.zip";
+    sha256 = "09vhrray8mh1ic2qgcwv0zlmsnz789y32dkkvrz1vdki4yqkf717";
+    stripRoot = false;
+  };
+
+  buildCommand = ''
+    mkdir -p $out/baseq3
+    install -Dm444 $src/xcsv_bq3hi-res.pk3 $out/baseq3/xcsv_bq3hi-res.pk3
+  '';
+
+  preferLocalBuild = true;
+
+  meta = with lib; {
+    description = "Quake 3 high-resolution textures";
+    license = licenses.cc0;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ rvolosatovs ];
+  };
+}

pkgs/games/quake3/content/pointrelease.nix

@@ -0,0 +1,29 @@
+{ lib, stdenv, fetchurl }:
+
+let
+  version = "1.32b-3";
+in stdenv.mkDerivation {
+  pname = "quake3-pointrelease";
+  inherit version;
+
+  src = fetchurl {
+    url = "https://ftp.gwdg.de/pub/misc/ftp.idsoftware.com/idstuff/quake3/linux/linuxq3apoint-${version}.x86.run";
+    sha256 = "11piyksfqyxwl9mpgbc71w9sacsh4d3cdsgia0cy0dbbap2k4qf3";
+  };
+
+  buildCommand = ''
+    sh $src --tar xf
+
+    mkdir -p $out/baseq3
+    cp baseq3/*.pk3 $out/baseq3
+  '';
+
+  preferLocalBuild = true;
+
+  meta = with lib; {
+    description = "Quake 3 Arena point release";
+    license = licenses.unfreeRedistributable;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ abbradar ];
+  };
+}

pkgs/games/quake3/ioquake/default.nix

@@ -0,0 +1,66 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, which
+, pkg-config
+, SDL2
+, libGL
+, openalSoft
+, curl
+, speex
+, opusfile
+, libogg
+, libvorbis
+, libopus
+, libjpeg
+, mumble
+, freetype
+}:
+
+stdenv.mkDerivation {
+  pname = "ioquake3";
+  version = "unstable-2021-07-20";
+
+  src = fetchFromGitHub {
+    owner = "ioquake";
+    repo = "ioq3";
+    rev = "bc8737d707595aebd7cc11d6d5a5d65ede750f59";
+    sha256 = "1icrkaw6c5c5ndy886bn65lycwnxzxwvz0ndz4p9i6r716k11add";
+  };
+
+  nativeBuildInputs = [ which pkg-config ];
+  buildInputs = [
+    SDL2
+    libGL
+    openalSoft
+    curl
+    speex
+    opusfile
+    libogg
+    libvorbis
+    libopus
+    libjpeg
+    freetype
+    mumble
+  ];
+
+  enableParallelBuilding = true;
+
+  makeFlags = [ "USE_INTERNAL_LIBS=0" "USE_FREETYPE=1" "USE_OPENAL_DLOPEN=0" "USE_CURL_DLOPEN=0" ];
+
+  installTargets = [ "copyfiles" ];
+
+  installFlags = [ "COPYDIR=$(out)" ];
+
+  preInstall = ''
+    mkdir -p $out/baseq3
+  '';
+
+  meta = with lib; {
+    homepage = "https://ioquake3.org/";
+    description = "First person shooter engine based on the Quake 3: Arena and Quake 3: Team Arena";
+    license = licenses.gpl2Only;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ rvolosatovs eelco abbradar ];
+  };
+}

pkgs/games/quake3/quake3e/default.nix

@@ -0,0 +1,52 @@
+{ lib, stdenv, fetchFromGitHub, makeWrapper
+, curl, libGL, libX11, libXxf86dga, alsa-lib, libXrandr, libXxf86vm, libXext, SDL2, glibc
+}:
+
+stdenv.mkDerivation rec {
+  pname = "Quake3e";
+  version = "2022-04-01-dev";
+
+  src = fetchFromGitHub {
+    owner = "ec-";
+    repo = pname;
+    rev = "c6cec00b858aa5955eb1d6eb65b9bfd41fd869cb";
+    sha256 = "0qd13fndbhgkkmhxbprpzmj2l2v9ihacxagpdqi9sg9nrzvahr9h";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+  buildInputs = [ curl libGL libX11 libXxf86dga alsa-lib libXrandr libXxf86vm libXext SDL2 glibc ];
+  NIX_CFLAGS_COMPILE = "-I${SDL2.dev}/include/SDL2";
+  enableParallelBuilding = true;
+
+  postPatch = ''
+    sed -i -e 's#OpenGLLib = dlopen( dllname#OpenGLLib = dlopen( "${libGL}/lib/libGL.so"#' code/unix/linux_qgl.c
+    sed -i -e 's#Sys_LoadLibrary( "libpthread.so.0" )#Sys_LoadLibrary( "${glibc}/lib/libpthread.so.0" )#' code/unix/linux_snd.c
+    sed -i -e 's#Sys_LoadLibrary( "libasound.so.2" )#Sys_LoadLibrary( "${alsa-lib}/lib/libasound.so.2" )#' code/unix/linux_snd.c
+    sed -i -e 's#Sys_LoadLibrary( "libXxf86dga.so.1" )#Sys_LoadLibrary( "${libXxf86dga}/lib/libXxf86dga.so.1" )#' code/unix/x11_dga.c
+    sed -i -e 's#Sys_LoadLibrary( "libXrandr.so.2" )#Sys_LoadLibrary( "${libXrandr}/lib/libXrandr.so.2" )#' code/unix/x11_randr.c
+    sed -i -e 's#Sys_LoadLibrary( "libXxf86vm.so.1" )#Sys_LoadLibrary( "${libXxf86vm}/lib/libXxf86vm.so.1" )#' code/unix/x11_randr.c
+    sed -i -e 's#Sys_LoadLibrary( "libXxf86vm.so.1" )#Sys_LoadLibrary( "${libXxf86vm}/lib/libXxf86vm.so.1" )#' code/unix/x11_vidmode.c
+    sed -i -e 's#"libcurl.so.4"#"${curl.out}/lib/libcurl.so.4"#' code/client/cl_curl.h
+  '';
+
+  # Default value for `USE_SDL` changed (from 0 to 1) in 5f8ce6d (2020-12-26)
+  # Setting `USE_SDL=0` in `makeFlags` doesn't work
+  preConfigure = ''
+    sed -i 's/USE_SDL *= 1/USE_SDL = 0/' Makefile
+  '';
+
+  installPhase = ''
+    make install DESTDIR=$out/lib
+    makeWrapper $out/lib/quake3e.x64 $out/bin/quake3e
+    makeWrapper $out/lib/quake3e.ded.x64 $out/bin/quake3e.ded
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/ec-/Quake3e";
+    description = "Improved Quake III Arena engine";
+    license = licenses.gpl2;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ pmiddend ];
+    badPlatforms = [ platforms.aarch64 ];
+  };
+}

pkgs/games/quake3/wrapper/default.nix

@@ -0,0 +1,34 @@
+{ stdenv, buildEnv, lib, libGL, ioquake3, makeWrapper }:
+
+{ paks, name ? (lib.head paks).name, description ? "" }:
+
+let
+  libPath = lib.makeLibraryPath [ libGL stdenv.cc.cc ];
+  env = buildEnv {
+    name = "quake3-env";
+    paths = [ ioquake3 ] ++ paks;
+  };
+
+in stdenv.mkDerivation {
+  name = "${name}-${ioquake3.name}";
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  buildCommand = ''
+    mkdir -p $out/bin
+
+    # We add Mesa to the end of $LD_LIBRARY_PATH to provide fallback
+    # software rendering. GCC is needed so that libgcc_s.so can be found
+    # when Mesa is used.
+    makeWrapper ${env}/ioquake3.* $out/bin/quake3 \
+      --suffix-each LD_LIBRARY_PATH ':' "${libPath}" \
+      --add-flags "+set fs_basepath ${env} +set r_allowSoftwareGL 1"
+
+    makeWrapper ${env}/ioq3ded.* $out/bin/quake3-server \
+      --add-flags "+set fs_basepath ${env}"
+  '';
+
+  meta = {
+    inherit description;
+  };
+}