uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/games/spring/default.nix

@@ -0,0 +1,64 @@
+{ lib, stdenv, fetchFromGitHub, cmake, xz, boost, libdevil, zlib, p7zip
+, openal, libvorbis, glew, freetype, xorg, SDL2, libGLU, libGL
+, asciidoc, docbook_xsl, docbook_xsl_ns, curl, makeWrapper
+, jdk ? null, python ? null, systemd, libunwind, which, minizip
+, withAI ? true # support for AI Interfaces and Skirmish AIs
+}:
+
+stdenv.mkDerivation rec {
+  pname = "spring";
+  version = "105.0.1-${buildId}-g${shortRev}";
+  # usually the latest in https://github.com/spring/spring/commits/maintenance
+  rev = "8581792eac65e07cbed182ccb1e90424ce3bd8fc";
+  shortRev = builtins.substring 0 7 rev;
+  buildId = "1486";
+
+  # taken from https://github.com/spring/spring/commits/maintenance
+  src = fetchFromGitHub {
+    owner = "spring";
+    repo = pname;
+    inherit rev;
+    sha256 = "05lvd8grqmv7vl8rrx02rhl0qhmm58dyi6s78b64j3fkia4sfj1r";
+    fetchSubmodules = true;
+  };
+
+  # The cmake included module correcly finds nix's glew, however
+  # it has to be the bundled FindGLEW for headless or dedicated builds
+  prePatch = ''
+    substituteInPlace ./rts/build/cmake/FindAsciiDoc.cmake \
+      --replace "PATHS /usr /usr/share /usr/local /usr/local/share" "PATHS ${docbook_xsl}"\
+      --replace "xsl/docbook/manpages" "share/xml/docbook-xsl/manpages"
+    substituteInPlace ./rts/Rendering/GL/myGL.cpp \
+      --replace "static constexpr const GLubyte* qcriProcName" "static const GLubyte* qcriProcName"
+    patchShebangs .
+    rm rts/build/cmake/FindGLEW.cmake
+
+    echo "${version} maintenance" > VERSION
+  '';
+
+  cmakeFlags = ["-DCMAKE_BUILD_WITH_INSTALL_RPATH:BOOL=ON"
+                "-DCMAKE_INSTALL_RPATH_USE_LINK_PATH:BOOL=ON"
+                "-DPREFER_STATIC_LIBS:BOOL=OFF"];
+
+  nativeBuildInputs = [ cmake makeWrapper docbook_xsl docbook_xsl_ns asciidoc ];
+  buildInputs = [ xz boost libdevil zlib p7zip openal libvorbis freetype SDL2
+    xorg.libX11 xorg.libXcursor libGLU libGL glew curl
+    systemd libunwind which minizip ]
+    ++ lib.optional withAI jdk
+    ++ lib.optional withAI python;
+
+  NIX_CFLAGS_COMPILE = "-fpermissive"; # GL header minor incompatibility
+
+  postInstall = ''
+    wrapProgram "$out/bin/spring" \
+      --prefix LD_LIBRARY_PATH : "${lib.makeLibraryPath [ stdenv.cc.cc systemd ]}"
+  '';
+
+  meta = with lib; {
+    homepage = "https://springrts.com/";
+    description = "A powerful real-time strategy (RTS) game engine";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ qknight domenkozar sorki ];
+    platforms = platforms.linux;
+  };
+}

pkgs/games/spring/fix-certs.patch

@@ -0,0 +1,11 @@
+--- a/src/downloader/lib/src/Downloader/CurlWrapper.cpp
++++ b/src/downloader/lib/src/Downloader/CurlWrapper.cpp
+@@ -108,7 +108,6 @@
+ 		if (res != CURLE_OK) {
+ 			LOG_WARN("Error setting CURLOPT_CAPATH: %d", res);
+ 		}
+-		return;
+ 	}
+ 
+ 	const std::string cafile = GetCAFilePath();
+

pkgs/games/spring/revert_58b423e.patch

@@ -0,0 +1,16 @@
+--- a/src/utils/slpaths.cpp
++++ b/src/utils/slpaths.cpp
+@@ -165,13 +165,10 @@
+ 			usync_paths.push_back(bundle);
+ 		}
+ 		if (!SlPaths::IsPortableMode()) {
+-			/*
+-//FIXME: reenable when #707 is fixed / spring 102.0 is "established"
+ 			LSL::SpringBundle systembundle;
+ 			if (LSL::SpringBundle::LocateSystemInstalledSpring(systembundle)) {
+ 				usync_paths.push_back(systembundle);
+ 			}
+-*/
+ 
+ 			std::vector<std::string> paths;
+ 			PossibleEnginePaths(paths);

pkgs/games/spring/springlobby.nix

@@ -0,0 +1,42 @@
+{ lib, stdenv, fetchurl, fetchpatch, cmake, wxGTK30, openal, pkg-config, curl, libtorrent-rasterbar
+, libpng, libX11, gettext, boost, libnotify, gtk2, doxygen, spring
+, makeWrapper, glib, minizip, alure, pcre, jsoncpp }:
+
+stdenv.mkDerivation rec {
+  pname = "springlobby";
+  version = "0.270";
+
+  src = fetchurl {
+    url = "https://springlobby.springrts.com/dl/stable/springlobby-${version}.tar.bz2";
+    sha256 = "1r1g2hw9ipsmsmzbhsi7bxqra1za6x7j1kw12qzl5psqyq8rqbgs";
+  };
+
+  nativeBuildInputs = [ cmake pkg-config gettext doxygen makeWrapper ];
+  buildInputs = [
+    wxGTK30 openal curl libtorrent-rasterbar pcre jsoncpp
+    boost libpng libX11 libnotify gtk2 glib minizip alure
+  ];
+
+  patches = [
+    ./revert_58b423e.patch # Allows springLobby to continue using system installed spring until #707 is fixed
+    ./fix-certs.patch
+    (fetchpatch {
+      url = "https://github.com/springlobby/springlobby/commit/252c4cb156c1442ed9b4faec3f26265bc7c295ff.patch";
+      sha256 = "sha256-Nq1F5fRPnCkZwl9KgrfuUmpIMK3hUOyZQYIKElWpmzU=";
+    })
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/springlobby \
+      --prefix PATH : "${spring}/bin" \
+      --set SPRING_BUNDLE_DIR "${spring}/lib"
+  '';
+
+  meta = with lib; {
+    homepage = "https://springlobby.info/";
+    description = "Cross-platform lobby client for the Spring RTS project";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ qknight domenkozar ];
+    platforms = platforms.linux;
+  };
+}