uboot: (firmwareOdroidC2/C4) don't invoke patch tool, use patches = [] instead

https://github.com/NixOS/nixpkgs/blob/master/pkgs/stdenv/generic/setup.sh#L948
this can do it nicely.

Signed-off-by: Anton Arapov <anton@deadbeef.mx>

pkgs/games/ut2004/default.nix

@@ -0,0 +1,9 @@
+{ callPackage }:
+
+{
+  ut2004-demo = callPackage ./demo.nix { };
+
+  ut2004 = gamePacks: callPackage ./wrapper.nix {
+    inherit gamePacks;
+  };
+}

pkgs/games/ut2004/demo.nix

@@ -0,0 +1,40 @@
+{ lib, stdenv, fetchurl }:
+
+let
+  arch =
+    if stdenv.hostPlatform.system == "x86_64-linux" then "amd64"
+    else if stdenv.hostPlatform.system == "i686-linux" then "x86"
+    else throw "Unsupported architecture";
+
+in stdenv.mkDerivation rec {
+  pname = "ut2004-demo";
+  version = "3334";
+
+  src = fetchurl {
+    url = "http://ftp.snt.utwente.nl/pub/games/UT2004/demo/UT2004-LNX-Demo${version}.run.gz";
+    sha256 = "0d5f84qz8l1rg16yzx2k4ikr46n9iwj68na1bqi87wrww7ck6jh7";
+  };
+
+  buildCommand = ''
+    cat $src | gunzip > setup.run
+    chmod +x setup.run
+    ./setup.run --noexec --target .
+    mkdir $out
+    tar -xaf ut2004demo.tar.bz2 -C $out
+    tar -xaf linux-${arch}.tar.bz2 -C $out
+
+    rm $out/System/libSDL-1.2.so.0
+    rm $out/System/openal.so
+  '';
+
+  dontStrip = true;
+  dontPatchELF = true;
+
+  meta = with lib; {
+    description = "A first-person shooter video game developed by Epic Games and Digital Extreme -- demo version";
+    homepage = "http://www.unrealtournament2004.com";
+    license = licenses.unfree;
+    maintainers = with maintainers; [ abbradar ];
+    platforms = [ "x86_64-linux" "i686-linux" ];
+  };
+}

pkgs/games/ut2004/wrapper.nix

@@ -0,0 +1,46 @@
+{ stdenv, lib, runCommand, buildEnv, makeWrapper, makeDesktopItem, gamePacks, libstdcxx5, SDL, openal }:
+
+let
+  game = buildEnv {
+    name = "ut2004-game";
+    paths = gamePacks;
+    ignoreCollisions = true;
+    pathsToLink = [ "/" "/System" ];
+    postBuild = ''
+      ln -s ${lib.getLib SDL}/lib/libSDL-1.2.so.0 $out/System
+      ln -s ${lib.getLib openal}/lib/libopenal.so $out/System/openal.so
+      for i in $out/System/*-bin; do
+        path="$(readlink -f "$i")"
+        rm "$i"
+        cp "$path" "$i"
+        chmod +w "$i"
+        patchelf \
+          --set-interpreter $(cat ${stdenv.cc}/nix-support/dynamic-linker) \
+          --set-rpath "$out/System:${lib.makeLibraryPath [ libstdcxx5 ]}" \
+          "$i"
+      done
+    '';
+  };
+
+  desktop = makeDesktopItem {
+    name = "ut2004";
+    desktopName = "Unreal Tournament 2004";
+    comment = "A first-person shooter video game developed by Epic Games and Digital Extreme";
+    genericName = "First-person shooter";
+    categories = [ "Game" ];
+    exec = "ut2004";
+  };
+
+in runCommand "ut2004" {
+  nativeBuildInputs = [ makeWrapper ];
+} ''
+  mkdir -p $out/bin
+  for i in ${game}/System/*-bin; do
+    name="$(basename "$i")"
+    makeWrapper $i $out/bin/''${name%-bin} \
+      --chdir "${game}/System"
+  done
+
+  mkdir -p $out/share/applications
+  ln -s ${desktop}/share/applications/* $out/share/applications
+''